1DESCRIPTION = "Library for password quality checking and generating random passwords"
2HOMEPAGE = "https://github.com/libpwquality/libpwquality"
3SECTION = "devel/lib"
4
5LICENSE = "GPL-2.0-or-later"
6LIC_FILES_CHKSUM = "file://COPYING;md5=6bd2f1386df813a459a0c34fde676fc2"
7
8DEPENDS = "cracklib python3-setuptools-native"
9
10SRC_URI = "git://github.com/libpwquality/libpwquality;branch=master;protocol=https \
11    file://0001-Use-setuptools-instead-of-distutils.patch \
12    file://0002-Makefile.am-respect-PYTHONSITEDIR.patch \
13"
14SRCREV = "5490e96a3dd6ed7371435ca5b3ccef98bdb48b5a"
15
16S = "${WORKDIR}/git"
17
18inherit autotools-brokensep gettext setuptools3-base
19
20do_configure:prepend() {
21    cp ${STAGING_DATADIR_NATIVE}/gettext/ABOUT-NLS ${AUTOTOOLS_AUXDIR}/
22}
23
24export PYTHON_DIR
25export BUILD_SYS
26export HOST_SYS
27
28EXTRA_OECONF += "--with-python-rev=${PYTHON_BASEVERSION} \
29                 --with-python-binary=${STAGING_BINDIR_NATIVE}/python3-native/python3 \
30                 --with-pythonsitedir=${PYTHON_SITEPACKAGES_DIR} \
31                 --libdir=${libdir} \
32                 --with-securedir=${base_libdir}/security \
33"
34
35PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'pam', '', d)}"
36PACKAGECONFIG[pam] = "--enable-pam,--disable-pam,libpam"
37
38FILES:${PN} += "${base_libdir}/security/pam_pwquality.so"
39FILES:${PN}-dbg += "${base_libdir}/security/.debug"
40FILES:${PN}-staticdev += "${base_libdir}/security/pam_pwquality.a"
41FILES:${PN}-dev += "${base_libdir}/security/pam_pwquality.la"
42