1SUMMARY = "Diagnostic Log and Trace"
2DESCRIPTION = "This component provides a standardised log and trace interface, \
3based on the standardised protocol specified in the AUTOSAR standard 4.0 DLT. \
4This component can be used by COVESA components and other applications as \
5logging facility providing: \
6- the DLT shared library \
7- the DLT daemon, including startup scripts \
8- the DLT daemon adaptors- the DLT client console utilities \
9- the DLT test applications"
10HOMEPAGE = "https://www.covesa.global/"
11SECTION = "console/utils"
12LICENSE = "MPL-2.0"
13LIC_FILES_CHKSUM = "file://LICENSE;md5=8184208060df880fe3137b93eb88aeea"
14
15DEPENDS = "zlib gzip-native json-c"
16
17SRC_URI = "git://github.com/COVESA/${BPN}.git;protocol=https;branch=master \
18           file://0002-Don-t-execute-processes-as-a-specific-user.patch \
19           file://0004-Modify-systemd-config-directory.patch \
20           file://544.patch \
21           file://567.patch \
22           "
23SRCREV = "0f2d4cfffada6f8448a2cb27995b38eb4271044f"
24
25S = "${WORKDIR}/git"
26
27PACKAGECONFIG ?= "${@bb.utils.contains('DISTRO_FEATURES', 'systemd', ' systemd systemd-watchdog systemd-journal ', '', d)} \
28 dlt-examples dlt-adaptor dlt-adaptor-stdin dlt-adaptor-udp dlt-console \
29 udp-connection dlt-system dlt-filetransfer "
30# dlt-dbus
31
32# General options
33PACKAGECONFIG[dlt-examples] = "-DWITH_DLT_EXAMPLES=ON,-DWITH_DLT_EXAMPLES=OFF"
34
35# Linux options
36PACKAGECONFIG[systemd] = "-DWITH_SYSTEMD=ON,-DWITH_SYSTEMD=OFF -DWITH_DLT_SYSTEM=OFF,systemd"
37PACKAGECONFIG[systemd-watchdog] = "-DWITH_SYSTEMD_WATCHDOG=ON,-DWITH_SYSTEMD_WATCHDOG=OFF,systemd,libsystemd"
38PACKAGECONFIG[systemd-journal] = "-DWITH_SYSTEMD_JOURNAL=ON,-DWITH_SYSTEMD_JOURNAL=OFF,systemd,libsystemd"
39PACKAGECONFIG[dlt-dbus] = "-DWITH_DLT_DBUS=ON,-DWITH_DLT_DBUS=OFF,dbus,dbus-lib"
40PACKAGECONFIG[udp-connection] = "-DWITH_UDP_CONNECTION=ON,-DWITH_UDP_CONNECTION=OFF"
41
42# Command line options
43PACKAGECONFIG[dlt-system] = "-DWITH_DLT_SYSTEM=ON,-DWITH_DLT_SYSTEM=OFF"
44PACKAGECONFIG[dlt-adaptor] = "-DWITH_DLT_ADAPTOR=ON,-DWITH_DLT_ADAPTOR=OFF"
45PACKAGECONFIG[dlt-adaptor-stdin] = "-DWITH_DLT_ADAPTOR_STDIN=ON,-DWITH_DLT_ADAPTOR_STDIN=OFF"
46PACKAGECONFIG[dlt-adaptor-udp] = "-DWITH_DLT_ADAPTOR_UDP=ON,-DWITH_DLT_ADAPTOR_UDP=OFF"
47PACKAGECONFIG[dlt-filetransfer] = "-DWITH_DLT_FILETRANSFER=ON,-DWITH_DLT_FILETRANSFER=OFF"
48PACKAGECONFIG[dlt-console] = "-DWITH_DLT_CONSOLE=ON,-DWITH_DLT_CONSOLE=OFF"
49
50inherit autotools gettext cmake pkgconfig systemd
51
52# -DWITH_DLT_COREDUMPHANDLER=ON this feature is too experimental, disable for now
53#FILES:${PN} += "${libdir}/sysctl.d"
54EXTRA_OECMAKE += "-DWITH_DLT_LOGSTORAGE_GZIP=ON -DWITH_EXTENDED_FILTERING=ON -DSYSTEMD_UNITDIR=${systemd_system_unitdir}"
55
56PACKAGES += "${PN}-systemd"
57SYSTEMD_PACKAGES = "${PN} ${PN}-systemd"
58SYSTEMD_SERVICE:${PN} = " ${@bb.utils.contains('PACKAGECONFIG', 'systemd', 'dlt.service', '', d)} \
59                          ${@bb.utils.contains('PACKAGECONFIG', 'systemd dlt-system', 'dlt-system.service', '', d)} \
60                          ${@bb.utils.contains('PACKAGECONFIG', 'systemd dlt-dbus', 'dlt-dbus.service', '', d)}"
61SYSTEMD_AUTO_ENABLE:${PN} = "enable"
62SYSTEMD_SERVICE:${PN}-systemd = " \
63    ${@bb.utils.contains('PACKAGECONFIG', 'systemd dlt-adaptor-udp', 'dlt-adaptor-udp.service', '', d)} \
64    ${@bb.utils.contains('PACKAGECONFIG', 'systemd dlt-examples', 'dlt-example-user.service', '', d)} \
65    ${@bb.utils.contains('PACKAGECONFIG', 'systemd dlt-examples dlt-console', 'dlt-receive.service', '', d)} \
66"
67SYSTEMD_AUTO_ENABLE:${PN}-systemd = "disable"
68
69FILES:${PN}-doc += "${datadir}/dlt-filetransfer"
70
71do_install:append() {
72    rm -f ${D}${bindir}/dlt-test-*
73}
74