1SUMMARY = "Adapter to write and run CMPI-type CIM providers"
2DESCRIPTION = "CMPI-compliant provider interface for various languages via SWIG"
3HOMEPAGE = "http://github.com/kkaempf/cmpi-bindings"
4LICENSE = "BSD-3-Clause"
5LIC_FILES_CHKSUM = "file://COPYING;md5=b19ee058d2d5f69af45da98051d91064"
6SECTION = "Development/Libraries"
7DEPENDS = "swig-native sblim-cmpi-devel python3-setuptools-native"
8
9SRC_URI = "git://github.com/kkaempf/cmpi-bindings.git;protocol=https;branch=master \
10           file://cmpi-bindings-0.4.17-no-ruby-perl.patch \
11           file://cmpi-bindings-0.4.17-sblim-sigsegv.patch \
12           file://0001-Fix-error.patch \
13           file://0001-cmpi-bindings-Fix-build-error-with-gcc14.patch \
14           "
15
16SRCREV = "69077ee4d249816ed428155fc933dca424167e77"
17S = "${WORKDIR}/git"
18
19inherit cmake python3targetconfig
20
21EXTRA_OECMAKE = "-DLIB='${baselib}' \
22                 -DPYTHON_INCLUDE_PATH=${STAGING_INCDIR}/python${PYTHON_BASEVERSION} \
23                 -DPYTHON_ABI=${PYTHON_ABI} \
24                 -DBUILD_PYTHON3=NO \
25                 -DPython3_SITE_DIR=${PYTHON_SITEPACKAGES_DIR} \
26                 "
27
28# With Ninja it fails with:
29# ninja: error: build.ninja:282: bad $-escape (literal $ must be written as $$)
30OECMAKE_GENERATOR = "Unix Makefiles"
31
32FILES:${PN} =+"${libdir}/cmpi/libpy3CmpiProvider.so ${PYTHON_SITEPACKAGES_DIR}/*"
33FILES:${PN}-dbg =+ "${libdir}/cmpi/.debug/libpyCmpiProvider.so"
34
35BBCLASSEXTEND = "native"
36
37# http://errors.yoctoproject.org/Errors/Details/766910/
38# cmpi-bindings/1.0.4/git/swig/python/../../src/target_python.c:168:21: error: passing argument 1 of 'Py_SetProgramName' from incompatible pointer type [-Wincompatible-pointer-types]
39CFLAGS += "-Wno-error=incompatible-pointer-types"
40