1SUMMARY = "UW c-client library for mail protocols"
2SECTION = "devel"
3
4LICENSE = "Apache-2.0"
5LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=a6a4ddbb7cd2999f6827ee143f6fcd97"
6
7DEPENDS = "openssl virtual/crypt"
8
9SRC_URI = "https://fossies.org/linux/misc/old/imap-${PV}.tar.gz \
10           file://quote_cctype.patch \
11           file://imap-2007e-shared.patch \
12           file://imap-2007f-format-security.patch \
13           file://0001-Support-OpenSSL-1.1.patch \
14           file://0001-Define-prototype-for-safe_flock.patch \
15           file://0001-Do-not-build-mtest.patch \
16           file://0002-tmail-Include-ctype.h-for-isdigit.patch \
17           file://0001-Fix-Wincompatible-function-pointer-types.patch \
18           "
19
20SRC_URI[md5sum] = "2126fd125ea26b73b20f01fcd5940369"
21SRC_URI[sha256sum] = "53e15a2b5c1bc80161d42e9f69792a3fa18332b7b771910131004eb520004a28"
22
23S = "${WORKDIR}/imap-${PV}"
24
25CVE_CHECK_IGNORE += "\
26    CVE-2005-0198 \
27"
28
29PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}"
30PACKAGECONFIG[pam] = ",,libpam"
31
32EXTRA_OEMAKE = "CC='${CC} -std=c99 -D_GNU_SOURCE' ARRC='${AR} -rc' RANLIB='${RANLIB}'"
33
34HEADERS = "src/c-client/*.h src/osdep/unix/*.h c-client/auths.c c-client/linkage.c c-client/linkage.h c-client/osdep.h"
35
36do_compile() {
37    echo "SSLINCLUDE=${STAGING_INCDIR} SSLLIB=${STAGING_LIBDIR}" > ${S}/SPECIALS
38    oe_runmake ${@bb.utils.contains('PACKAGECONFIG', 'pam', 'lnp', 'slx', d)}
39}
40
41do_install() {
42    install -d ${D}${includedir}/c-client
43    install ${HEADERS} ${D}${includedir}/c-client
44    install -d ${D}${libdir}
45    install c-client/c-client.a ${D}${libdir}/libc-client.a
46}
47
48RPROVIDES:${PN} = "libc-client"
49RREPLACES:${PN} = "libc-client"
50RCONFLICTS:${PN} = "libc-client"
51
52ALLOW_EMPTY:${PN} = "1"
53
54PARALLEL_MAKE = ""
55
56