1SUMMARY = "lm_sensors configuration files"
2DESCRIPTION = "Hardware health monitoring configuration files"
3HOMEPAGE = "http://www.lm-sensors.org/"
4LICENSE = "MIT"
5LIC_FILES_CHKSUM = "file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
6
7PACKAGE_ARCH = "${MACHINE_ARCH}"
8
9SRC_URI = "file://fancontrol \
10           file://sensord.cgi \
11           file://sensord.conf \
12           file://sensors.conf \
13           file://sensord \
14"
15S = "${WORKDIR}"
16
17PACKAGECONFIG ??= "sensord"
18PACKAGECONFIG[sensord] = ",,"
19
20RDEPENDS:${PN}-dev = ""
21
22do_install() {
23    # Install fancontrol configuration file
24    install -d ${D}${sysconfdir}/sysconfig
25    install -m 0644 ${WORKDIR}/fancontrol ${D}${sysconfdir}
26    install -m 0644 ${WORKDIR}/sensord ${D}${sysconfdir}/sysconfig
27    # Install libsensors configuration file
28    install -d ${D}${sysconfdir}/sensors.d
29    install -m 0644 ${WORKDIR}/sensors.conf ${D}${sysconfdir}/sensors.d
30
31    if ${@bb.utils.contains('PACKAGECONFIG', 'sensord', 'true', 'false', d)}; then
32        # Install sensord configuration file
33        install -m 0644 ${WORKDIR}/sensord.conf ${D}${sysconfdir}
34
35        # Install sensord.cgi script and create world-writable
36        # web-accessible sensord directory
37        install -d ${D}/www/pages/cgi-bin
38        install -m 0755 ${WORKDIR}/sensord.cgi ${D}/www/pages/cgi-bin
39        install -d -m a=rwxs ${D}/www/pages/sensord
40    fi
41}
42
43# libsensors configuration
44PACKAGES =+ "${PN}-libsensors"
45
46# sensord logging daemon configuration
47PACKAGES =+ "${@bb.utils.contains('PACKAGECONFIG', 'sensord', '${PN}-sensord', '', d)}"
48
49# fancontrol script configuration
50PACKAGES =+ "${PN}-fancontrol"
51
52# sensord web cgi support
53PACKAGES =+ "${@bb.utils.contains('PACKAGECONFIG', 'sensord', '${PN}-cgi', '', d)}"
54RRECOMMENDS:${PN}-cgi = "lighttpd lighttpd-module-cgi"
55RDEPENDS:${PN}-cgi = "${PN}-sensord rrdtool"
56FILES:${PN}-cgi = "/www/*"
57
58# libsensors configuration file
59FILES:${PN}-libsensors = "${sysconfdir}/sensors.d/sensors.conf"
60
61# sensord logging daemon configuration files
62FILES:${PN}-sensord = "\
63    ${sysconfdir}/sensord.conf \
64    ${sysconfdir}/sysconfig/sensord \
65"
66
67# fancontrol script configuration file
68FILES:${PN}-fancontrol = "${sysconfdir}/fancontrol"
69