1SUMMARY = "A library which provides easy access to huge pages of memory"
2HOMEPAGE = "https://github.com/libhugetlbfs/libhugetlbfs"
3LICENSE = "LGPL-2.1-only"
4LIC_FILES_CHKSUM = "file://LGPL-2.1;md5=2d5025d4aa3495befef8f17206a5b0a1"
5
6DEPENDS = "sysfsutils"
7RDEPENDS:${PN} += "bash python3-core"
8RDEPENDS:${PN}-tests += "bash python3-core"
9
10PV = "2.23"
11PE = "1"
12
13SRCREV = "6b126a4d7da9490fa40fe7e1b962edcb939feddc"
14SRC_URI = " \
15    git://github.com/libhugetlbfs/libhugetlbfs.git;protocol=https;branch=master \
16    file://skip-checking-LIB32-and-LIB64-if-they-point-to-the-s.patch \
17    file://libhugetlbfs-avoid-search-host-library-path-for-cros.patch \
18    file://tests-Makefile-install-static-4G-edge-testcases.patch \
19    file://0001-run_test.py-not-use-hard-coded-path-.-obj-hugeadm.patch \
20    file://libhugetlbfs-elf_i386-avoid-search-host-library-path.patch \
21    file://0001-include-stddef.h-for-ptrdiff_t.patch \
22    file://0002-Mark-glibc-specific-code-so.patch \
23    file://0003-alloc.c-Avoid-sysconf-_SC_LEVEL2_CACHE_LINESIZE-on-l.patch \
24    file://0004-shm.c-Mark-glibc-specific-changes-so.patch \
25    file://0005-Include-dirent.h-for-ino_t.patch \
26    file://0006-include-limits.h-for-PATH_MAX.patch \
27    file://0001-huge_page_setup_helper-use-python3-interpreter.patch \
28    file://0001-Revert-ld.hugetlbfs-fix-Ttext-segment-argument-on-AA.patch \
29    file://0001-tests-makefile-Append-CPPFLAGS-rather-then-override.patch \
30"
31
32UPSTREAM_CHECK_GITTAGREGEX = "(?P<pver>\d+(\.\d+)+)"
33
34S = "${WORKDIR}/git"
35
36COMPATIBLE_HOST = "(i.86|x86_64|powerpc|powerpc64|aarch64|arm).*-linux*"
37
38LIBARGS = "LIB32=${baselib} LIB64=${baselib}"
39LIBHUGETLBFS_ARCH = "${TARGET_ARCH}"
40LIBHUGETLBFS_ARCH:powerpc = "ppc"
41LIBHUGETLBFS_ARCH:powerpc64 = "ppc64"
42LIBHUGETLBFS_ARCH:powerpc64le = "ppc64le"
43EXTRA_OEMAKE = "'ARCH=${LIBHUGETLBFS_ARCH}' 'OPT=${CFLAGS}' 'CC=${CC}' ${LIBARGS} BUILDTYPE=NATIVEONLY V=2"
44PARALLEL_MAKE = ""
45CFLAGS += "-fexpensive-optimizations -frename-registers -fomit-frame-pointer -g0"
46
47export HUGETLB_LDSCRIPT_PATH="${S}/ldscripts"
48
49TARGET_CC_ARCH += "${LDFLAGS}"
50
51#The CUSTOM_LDSCRIPTS doesn't work with the gold linker
52inherit cpan-base
53do_configure() {
54    if [ "${@bb.utils.filter('DISTRO_FEATURES', 'ld-is-gold', d)}" ]; then
55      sed -i 's/CUSTOM_LDSCRIPTS = yes/CUSTOM_LDSCRIPTS = no/'  Makefile
56    fi
57}
58
59do_install() {
60        oe_runmake PREFIX=${prefix} DESTDIR=${D}  \
61          INST_TESTSDIR32=${libdir}/libhugetlbfs/tests \
62          INST_TESTSDIR64=${libdir}/libhugetlbfs/tests \
63          install-tests
64}
65
66
67PACKAGES =+ "${PN}-tests "
68FILES:${PN} += "${libdir}/*.so"
69FILES:${PN}-dev = "${includedir}"
70FILES:${PN}-dbg += "${libdir}/libhugetlbfs/tests/obj32/.debug ${libdir}/libhugetlbfs/tests/obj64/.debug"
71FILES:${PN}-tests += "${libdir}/libhugetlbfs/tests"
72
73INSANE_SKIP:${PN} = "dev-so"
74
75INHIBIT_PACKAGE_STRIP = "1"
76INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
77
78# see https://github.com/libhugetlbfs/libhugetlbfs/issues/52
79SKIP_RECIPE[libhugetlbfs] ?= "Needs porting to glibc 2.34+"
80