1DESCRIPTION = "Tools to provide a way to get Platform Reliability, Availability and Serviceability (RAS) reports made via the Kernel tracing events"
2HOMEPAGE = "http://git.infradead.org/users/mchehab/rasdaemon.git"
3LICENSE = "GPL-2.0-only"
4LIC_FILES_CHKSUM = "file://COPYING;md5=d3070efe0afa3dc41608bd82c00bb0dc"
5
6SRC_URI = "git://github.com/mchehab/rasdaemon.git;branch=master;protocol=https \
7           file://rasdaemon.service \
8           file://init"
9
10SRCREV = "4e83b848e7961af25028f3a2cecf37a63279a2bf"
11
12S = "${WORKDIR}/git"
13
14DEPENDS = "libtraceevent"
15RDEPENDS:${BPN} = "perl perl-module-file-basename perl-module-file-find perl-module-file-spec perl-module-getopt-long \
16	perl-module-posix perl-module-file-glob libdbi-perl libdbd-sqlite-perl"
17
18inherit autotools pkgconfig update-rc.d systemd
19
20PACKAGECONFIG ??= "sqlite3 mce aer extlog devlink diskerror"
21PACKAGECONFIG[sqlite3] = "--enable-sqlite3,--disable-sqlite3,sqlite3"
22PACKAGECONFIG[mce] = "--enable-mce,--disable-mce"
23PACKAGECONFIG[aer] = "--enable-aer,--disable-aer"
24PACKAGECONFIG[extlog] = "--enable-extlog,--disable-extlog"
25PACKAGECONFIG[devlink] = "--enable-devlink,--disable-devlink"
26PACKAGECONFIG[diskerror] = "--enable-diskerror,--disable-diskerror"
27PACKAGECONFIG[arm] = "--enable-arm,--disable-arm"
28PACKAGECONFIG[hisi-ns-decode] = "--enable-hisi-ns-decode,--disable-hisi-ns-decode"
29PACKAGECONFIG[non-standard] = "--enable-non-standard,--disable-non-standard"
30PACKAGECONFIG[abrt-report] = "--enable-abrt-report,--disable-abrt-report"
31
32DEPENDS:append:libc-musl = " argp-standalone"
33LDFLAGS:append:libc-musl = " -largp"
34
35do_install:append() {
36	install -d ${D}${sysconfdir}/init.d
37	install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/rasdaemon
38	install -d ${D}${systemd_unitdir}/system
39	install -m 0644 ${WORKDIR}/rasdaemon.service ${D}${systemd_unitdir}/system
40}
41
42FILES:${PN} += "${sbindir}/rasdaemon \
43		${sysconfdir}/init.d \
44		${systemd_unitdir}/system/rasdaemon.service"
45
46SYSTEMD_SERVICE:${PN} = "rasdaemon.service"
47SYSTEMD_AUTO_ENABLE = "enable"
48
49INITSCRIPT_PACKAGES = "${PN}"
50INITSCRIPT_NAME:${PN} = "rasdaemon"
51INITSCRIPT_PARAMS:${PN} = "defaults 89"
52