1DESCRIPTION = "LCDproc is a client/server suite to drive all kinds of LCD (-like) devices. The client \
2shipped with this package can be used to acquire various kinds of system stats."
3SUMMARY = "Drivers for character-based LCD displays"
4HOMEPAGE = "http://lcdproc.org"
5SECTION = "utils"
6LICENSE = "GPL-2.0-or-later"
7DEPENDS = "ncurses lirc"
8
9LIC_FILES_CHKSUM = "file://COPYING;md5=18810669f13b87348459e611d31ab760 \
10                    file://README.md;beginline=107;md5=5db392f043253a2d64b1737068ce6b58"
11
12PV = "0.5.9+git"
13SRCREV = "0e2ce9b9c46c47363436f9ee730f7c71bf455f0f"
14SRC_URI = "git://github.com/lcdproc/lcdproc;branch=master;protocol=https"
15
16S = "${WORKDIR}/git"
17
18inherit autotools pkgconfig update-rc.d
19
20LCD_DRIVERS ?= "all,!irman,!svga${SERIALVFD}"
21SERIALVFD ?= ""
22SERIALVFD:libc-musl = ",!serialVFD"
23SERIALVFD:libc-musl:x86 = ""
24SERIALVFD:libc-musl:x86-64 = ""
25
26LCD_DEFAULT_DRIVER ?= "curses"
27
28PACKAGECONFIG ??= "usb"
29PACKAGECONFIG[usb] = "--enable-libusb,--disable-libusb,virtual/libusb0"
30PACKAGECONFIG[ftdi] = "--enable-libftdi,--disable-libftdi,libftdi"
31PACKAGECONFIG[g15] = ",,libg15 g15daemon libg15render,"
32PACKAGECONFIG[hid] = "--enable-libhid,--disable-libhid,libhid"
33PACKAGECONFIG[png] = "--enable-libpng,--disable-libpng,libpng"
34
35LCD_DRIVERS:append = "${@bb.utils.contains('PACKAGECONFIG', 'g15', '', ',!g15', d)}"
36
37EXTRA_OECONF = "--enable-drivers='${LCD_DRIVERS}'"
38
39do_install () {
40    # binaries
41    install -D -m 0755 server/LCDd ${D}${sbindir}/LCDd
42    install -D -m 0755 clients/lcdproc/lcdproc ${D}${bindir}/lcdproc
43
44    # init scripts
45    install -d ${D}${sysconfdir}/init.d
46    # so far, not fixed :-( and now even uglier :-((
47    cat scripts/init-LCDd.debian | sed -e s'/--oknodo//' -e 's/ -s -f / -s 1 -f 1 /' -e 's/force-reload/force-restart/' -e 's/sleep 1/sleep 4/' > ${D}${sysconfdir}/init.d/lcdd
48    chmod 0755 ${D}${sysconfdir}/init.d/lcdd
49    install -m 0755 scripts/init-lcdproc.debian ${D}${sysconfdir}/init.d/lcdproc
50    sed -i s'/--oknodo//' ${D}${sysconfdir}/init.d/lcdproc
51
52    # configuration files
53    install -m 0644 ${S}/LCDd.conf ${D}${sysconfdir}/LCDd.conf
54    sed -i 's!^DriverPath=.*!DriverPath=${libdir}/lcdproc/!' ${D}${sysconfdir}/LCDd.conf
55    sed -i 's!^Driver=.*!Driver=${LCD_DEFAULT_DRIVER}!' ${D}${sysconfdir}/LCDd.conf
56    install -m 0644 ${S}/clients/lcdproc/lcdproc.conf ${D}${sysconfdir}/lcdproc.conf
57
58    # driver library files
59    install -d ${D}${libdir}/lcdproc
60    for i in server/drivers/*.so; do
61        install -m 0644 $i ${D}${libdir}/lcdproc/
62    done
63    # binaries
64    install -D -m 0755 clients/lcdvc/lcdvc ${D}${sbindir}/lcdvc
65
66    # configuration files
67    install -D -m 0644 ${S}/clients/lcdvc/lcdvc.conf ${D}${sysconfdir}/lcdvc.conf
68}
69
70PACKAGES =+ "lcdd lcdvc"
71
72RRECOMMENDS:${PN} = "lcdd"
73
74FILES:lcdd = "${sysconfdir}/LCDd.conf \
75    ${sbindir}/LCDd \
76    ${sysconfdir}/init.d/lcdd"
77
78CONFFILES:lcdd = "${sysconfdir}/LCDd.conf"
79CONFFILES:${PN} = "${sysconfdir}/lcdproc.conf"
80CONFFILES:lcdvc = "${sysconfdir}/lcdvc.conf"
81FILES:lcdvc = "${sysconfdir}/lcdvc.conf ${sbindir}/lcdvc"
82
83# Driver packages
84
85# USB / no USB trickery
86
87RCONFLICTS:lcdd-driver-hd47780nousb = "lcdd-driver-hd44780"
88RCONFLICTS:lcdd-driver-hd47780 = "lcdd-driver-hd44780nousb"
89
90INITSCRIPT_PACKAGES = "lcdd lcdproc"
91INITSCRIPT_NAME:lcdd = "lcdd"
92INITSCRIPT_NAME:lcdproc = "lcdproc"
93INITSCRIPT_PARAMS:lcdd = "defaults 70 21"
94INITSCRIPT_PARAMS:lcdproc = "defaults 71 20"
95
96python populate_packages:prepend() {
97    plugindir = d.expand('${libdir}/lcdproc')
98    do_split_packages(d, plugindir, r'(.*)\.so$', 'lcdd-driver-%s', 'LCDd driver for %s', prepend=True)
99}
100
101PACKAGES_DYNAMIC += "^lcdd-driver-.*"
102