1SUMMARY = "extremely simple MTA to get mail off the system to a mail hub"
2HOMEPAGE = "http://packages.qa.debian.org/s/ssmtp.html"
3LICENSE = "GPL-2.0-only"
4LIC_FILES_CHKSUM = "file://COPYING;md5=0c56db0143f4f80c369ee3af7425af6e"
5
6SRC_URI = "${DEBIAN_MIRROR}/main/s/${BPN}/${BPN}_${PV}.orig.tar.bz2 \
7           file://ssmtp-bug584162-fix.patch \
8           file://build-ouside_srcdir.patch \
9           file://use-DESTDIR.patch \
10           file://0001-ssmtp-Correct-the-null-pointer-assignment-to-char-po.patch \
11           file://0001-include-libgen.h-for-basename.patch \
12           "
13
14SRC_URI[md5sum] = "65b4e0df4934a6cd08c506cabcbe584f"
15SRC_URI[sha256sum] = "22c37dc90c871e8e052b2cab0ad219d010fa938608cd66b21c8f3c759046fa36"
16
17inherit autotools update-alternatives
18
19PACKAGECONFIG ?= "ssl ${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"
20
21PACKAGECONFIG[ssl] = "--enable-ssl,--disable-ssl,openssl"
22PACKAGECONFIG[ipv6] = "--enable-inet6,--disable-inet6"
23
24EXTRA_OECONF += "--mandir=${mandir}"
25
26EXTRA_OEMAKE = "GEN_CONFIG='/bin/true'"
27
28LDFLAGS += "${@bb.utils.contains('PACKAGECONFIG', 'ssl', '-lssl -lcrypto', '', d)}"
29
30do_install:append () {
31    install -d ${D}${mandir}/
32    mv ${D}${exec_prefix}/man/* ${D}${mandir}/
33    rmdir ${D}${exec_prefix}/man
34    ln -s ssmtp ${D}${sbindir}/sendmail
35    ln -s ssmtp ${D}${sbindir}/newaliases
36    ln -s ssmtp ${D}${sbindir}/mailq
37}
38
39ALTERNATIVE_PRIORITY_${PN} = "100"
40
41ALTERNATIVE:${PN} = "mailq newaliases sendmail"
42ALTERNATIVE_LINK_NAME[sendmail] = "${sbindir}/sendmail"
43ALTERNATIVE_LINK_NAME[newaliases] = "${sbindir}/newaliases"
44ALTERNATIVE_LINK_NAME[mailq] = "${sbindir}/mailq"
45