1SUMMARY = "RADIUS protocol client library"
2DESCRIPTION = "Portable, easy-to-use and standard compliant library suitable \
3for developing free and commercial software that need support for a RADIUS \
4protocol (RFCs 2128 and 2139)."
5HOMEPAGE = "http://sourceforge.net/projects/radiusclient-ng.berlios/"
6SECTION = "net"
7
8SRC_URI = "${DEBIAN_MIRROR}/main/r/${BPN}/${BPN}_${PV}.orig.tar.gz \
9   file://Modify-configure.in-and-etc-Makefile.am.patch \
10   file://config-site.radiusclient-ng-${PV}"
11
12SRC_URI[md5sum] = "6fb7d4d0aefafaee7385831ac46a8e9c"
13SRC_URI[sha256sum] = "282a9f1355f190efbb06c0d7c4e062eaa652caf342ed3ad361ac595f72f09f14"
14
15LICENSE = "BSD-3-Clause & BSD-2-Clause & HPND"
16LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=3e47566c9271b786693d8a08792dbf41"
17
18inherit autotools-brokensep
19
20DEPENDS += "virtual/crypt"
21
22EXTRA_OECONF += "--disable-static"
23
24do_configure_prepend () {
25    export CONFIG_SITE=./config-site.${P}
26}
27
28do_compile_prepend() {
29    for m in `find . -name "Makefile"` ; do
30        sed -i -e 's:^program_transform_name =.*:program_transform_name =:g' ${m}
31    done
32}
33
34do_install() {
35    oe_runmake DESTDIR=${D} install
36    rm -f ${D}${libdir}/*.la
37    rm -f ${D}${sbindir}/radexample
38}
39