1SUMMARY        = "Client for the Trivial File Transfer Protocol"
2DESCRIPTION    = \
3"The Trivial File Transfer Protocol (TFTP) is normally used only for \
4booting diskless workstations.  The tftp package provides the user   \
5interface for TFTP, which allows users to transfer files to and from a \
6remote machine.  This program and TFTP provide very little security, \
7and should not be enabled unless it is expressly needed."
8DEPENDS = "tcp-wrappers readline"
9SECTION = "net"
10HOMEPAGE = "http://freecode.com/projects/tftp-hpa"
11LICENSE = "BSD-4-Clause"
12LIC_FILES_CHKSUM = "file://MCONFIG.in;beginline=1;endline=9;md5=c28ba5adb43041fae4629db05c83cbdd \
13                    file://tftp/tftp.c;beginline=1;endline=32;md5=988c1cba99d70858a26cd877209857f4"
14
15
16SRC_URI = "http://kernel.org/pub/software/network/tftp/tftp-hpa/tftp-hpa-${PV}.tar.bz2 \
17           file://tftp-0.40-remap.patch \
18           file://tftp-0.42-tftpboot.patch \
19           file://tftp-0.49-chk_retcodes.patch \
20           file://tftp-0.49-cmd_arg.patch \
21           file://tftp-hpa-0.39-tzfix.patch \
22           file://tftp-hpa-0.49-fortify-strcpy-crash.patch \
23           file://tftp-hpa-0.49-stats.patch \
24           file://tftp-hpa-5.2-pktinfo.patch \
25           file://default \
26           file://init \
27           file://add-error-check-for-disk-filled-up.patch \
28           file://tftp-hpa-bug-fix-on-separated-CR-and-LF.patch \
29           file://fix-writing-emtpy-file.patch \
30           file://0001-__progname-is-provided-by-libc.patch \
31           file://0001-tftp-Mark-toplevel-definition-as-external.patch \
32           file://tftpd-hpa.socket \
33           file://tftpd-hpa.service \
34"
35
36SRC_URI[md5sum] = "46c9bd20bbffa62f79c958c7b99aac21"
37SRC_URI[sha256sum] = "0a9f88d4c1c02687b4853b02ab5dd8779d4de4ffdb9b2e5c9332841304d1a269"
38
39inherit autotools-brokensep update-rc.d update-alternatives systemd
40
41export AR = "${HOST_PREFIX}ar cq"
42
43EXTRA_OECONF += "--disable-option-checking"
44
45PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"
46PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,"
47
48# configure.in has errors
49do_configure() {
50    oe_runconf
51}
52
53do_install() {
54    oe_runmake install INSTALLROOT=${D}
55    mv ${D}${bindir}/tftp ${D}${bindir}/tftp-hpa
56    mv ${D}${sbindir}/in.tftpd ${D}${sbindir}/in.tftpd-hpa
57
58    install -m 755 -d ${D}${localstatedir}/lib/tftpboot/
59    install -d ${D}${sysconfdir}/init.d
60    install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/tftpd-hpa
61    sed -i 's!/usr/sbin/!${sbindir}/!g' ${D}${sysconfdir}/init.d/tftpd-hpa
62    sed -i 's!/etc/!${sysconfdir}/!g' ${D}${sysconfdir}/init.d/tftpd-hpa
63    sed -i 's!/var/!${localstatedir}/!g' ${D}${sysconfdir}/init.d/tftpd-hpa
64    sed -i 's!^PATH=.*!PATH=${base_sbindir}:${base_bindir}:${sbindir}:${bindir}!' ${D}${sysconfdir}/init.d/tftpd-hpa
65
66    install -d ${D}${sysconfdir}/default
67    install -m 0644 ${WORKDIR}/default ${D}${sysconfdir}/default/tftpd-hpa
68
69    install -d ${D}${systemd_unitdir}/system
70    install -m 0644 ${WORKDIR}/tftpd-hpa.socket ${D}${systemd_unitdir}/system
71    install -m 0644 ${WORKDIR}/tftpd-hpa.service ${D}${systemd_unitdir}/system
72    sed -i -e 's,@SBINDIR@,${sbindir},g' ${D}${systemd_unitdir}/system/tftpd-hpa.service
73}
74
75FILES_${PN} = "${bindir}"
76
77PACKAGES += "tftp-hpa-server"
78SUMMARY_tftp-hpa-server = "Server for the Trivial File Transfer Protocol"
79FILES_tftp-hpa-server = "${sbindir} ${sysconfdir} ${localstatedir}"
80CONFFILES_tftp-hpa-server = "${sysconfdir}/default/tftpd-hpa"
81
82INITSCRIPT_PACKAGES = "tftp-hpa-server"
83INITSCRIPT_NAME = "tftpd-hpa"
84INITSCRIPT_PARAMS = "start 20 2 3 4 5 . stop 20 1 ."
85
86ALTERNATIVE_${PN}-doc = "tftpd.8 tftp.1"
87ALTERNATIVE_LINK_NAME[tftpd.8] = "${mandir}/man8/tftpd.8"
88ALTERNATIVE_LINK_NAME[tftp.1] = "${mandir}/man1/tftp.1"
89
90ALTERNATIVE_${PN} = "tftp"
91ALTERNATIVE_TARGET[tftp] = "${bindir}/tftp-hpa"
92ALTERNATIVE_PRIORITY = "100"
93
94
95SYSTEMD_PACKAGES = "tftp-hpa-server"
96SYSTEMD_SERVICE_tftp-hpa-server = "tftpd-hpa.socket tftpd-hpa.service"
97SYSTEMD_AUTO_ENABLE_tftp-hpa-server = "enable"
98