1SUMMARY = "The PTP daemon (PTPd)"
2DESCRIPTION = "The PTP daemon (PTPd) implements the Precision Time protocol (PTP) as \
3defined by the relevant IEEE 1588 standard. PTP Version 1 implements IEEE-1588-2002, \
4and PTP Version 2 implements IEEE-1588-2008. PTP was developed to provide very precise \
5time coordination of LAN connected computers."
6HOMEPAGE = "http://sourceforge.net/projects/ptpd"
7SECTION = "net"
8LICENSE = "BSD-2-Clause"
9LIC_FILES_CHKSUM = "file://README;md5=0733e1b3788ab2ebbc63bf33a020da1d"
10
11DEPENDS = "libpcap"
12
13inherit autotools pkgconfig systemd
14
15# return something like '1.2.3' or '1.2.3/rc1'
16#
17def get_sub(d):
18    parts = d.getVar('PV').split('-')
19    try:
20        return parts[0] + '/' + parts[1]
21    except:
22        return parts[0]
23
24SRC_URI = "http://downloads.sourceforge.net/project/ptpd/ptpd/${@get_sub(d)}/ptpd-${PV}.tar.gz \
25           file://ptpd-use-pkgconfig.patch \
26           file://Fixed-100-CPU-using-issue-by-adding-minimum-POSIX-ti.patch \
27           file://0001-ptpd-Solve-memory-leak-for-function-NTPDCrequest.patch \
28           file://ptpd.service \
29           file://ptpd.conf \
30"
31
32SRC_URI[md5sum] = "253bab7ab51d969616ea811be1f132f3"
33SRC_URI[sha256sum] = "0dbf54dd2c178bd9fe62481d2c37513ee36636d8bf137cfdad96891490cdbf93"
34
35UPSTREAM_CHECK_URI = "http://sourceforge.net/projects/ptpd/files/releases"
36
37S = "${WORKDIR}/ptpd-${PV}"
38
39EXTRA_OEMAKE = ""
40
41EXTRA_OECONF += "--disable-snmp --with-pcap-config=pkg-config"
42
43do_install() {
44    install -d ${D}${bindir} ${D}${mandir}/man8
45    install -m 0755 ${B}/src/ptpd2 ${D}${bindir}
46    install -m 0644 ${B}/src/ptpd2.8 ${D}${mandir}/man8
47
48    if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
49        install -d ${D}${systemd_unitdir}/system
50        install -m 0644 ${WORKDIR}/ptpd.service ${D}${systemd_unitdir}/system
51
52        sed -i -e 's#@SYSCONFDIR@#${sysconfdir}#g' ${D}${systemd_unitdir}/system/ptpd.service
53        sed -i -e 's#@BINDIR@#${bindir}#g' ${D}${systemd_unitdir}/system/ptpd.service
54
55        install -d ${D}${sysconfdir}/default/
56        install -m 0644 ${WORKDIR}/ptpd.conf ${D}${sysconfdir}/default/ptpd
57    fi
58}
59
60SYSTEMD_PACKAGES = "${PN}"
61SYSTEMD_SERVICE:${PN} = "ptpd.service"
62SYSTEMD_AUTO_ENABLE = "disable"
63