1SUMMARY = "Multimedia processing server for Linux"
2AUTHOR = "Wim Taymans <wtaymans@redhat.com>"
3HOMEPAGE = "https://pipewire.org"
4SECTION = "multimedia"
5LICENSE = "LGPL-2.1-only"
6LIC_FILES_CHKSUM = " \
7    file://LICENSE;md5=d8153c6e65986f862a0550ca74a3ed73 \
8    file://LGPL;md5=2d5025d4aa3495befef8f17206a5b0a1 \
9"
10DEPENDS = "alsa-lib dbus udev"
11SRCREV = "14c11c0fe4d366bad4cfecdee97b6652ff9ed63d"
12PV = "0.2.7"
13
14SRC_URI = "git://github.com/PipeWire/pipewire;branch=master;protocol=https"
15
16S = "${WORKDIR}/git"
17
18inherit meson pkgconfig systemd manpages
19
20PACKAGECONFIG ??= "\
21    ${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
22    gstreamer \
23"
24
25PACKAGECONFIG[systemd] = "-Dsystemd=true,-Dsystemd=false,systemd"
26PACKAGECONFIG[gstreamer] = "-Dgstreamer=enabled,-Dgstreamer=disabled,glib-2.0 gstreamer1.0 gstreamer1.0-plugins-base"
27PACKAGECONFIG[manpages] = "-Dman=true,-Dman=false,libxml-parser-perl-native"
28
29PACKAGES =+ "\
30    ${PN}-spa-plugins \
31    ${PN}-alsa \
32    ${PN}-config \
33    gstreamer1.0-${PN} \
34    lib${PN} \
35    lib${PN}-modules \
36"
37
38RDEPENDS:lib${PN} += "lib${PN}-modules ${PN}-spa-plugins"
39
40FILES:${PN} = "\
41    ${sysconfdir}/pipewire/pipewire.conf \
42    ${bindir}/pipewire* \
43    ${systemd_user_unitdir}/* \
44"
45FILES:lib${PN} = "\
46    ${libdir}/libpipewire-*.so.* \
47"
48FILES:lib${PN}-modules = "\
49    ${libdir}/pipewire-*/* \
50"
51FILES:${PN}-spa-plugins = "\
52    ${bindir}/spa-* \
53    ${libdir}/spa/* \
54"
55FILES:${PN}-alsa = "\
56    ${libdir}/alsa-lib/* \
57    ${datadir}/alsa/alsa.conf.d/50-pipewire.conf \
58"
59FILES:gstreamer1.0-${PN} = "\
60    ${libdir}/gstreamer-1.0/* \
61"
62
63CONFFILES:${PN} = "\
64    ${sysconfdir}/pipewire/pipewire.conf \
65"
66