1SUMMARY = "JUCE's Projucer"
2DESCRIPTION = "Projucer is used to build and generate support files and build infrastructure for all \
3JUCE supported platforms, including Linux and Embedded Linux."
4SECTION = "utils"
5HOMEPAGE = "http://juce.com/"
6LICENSE = "GPLv3"
7LIC_FILES_CHKSUM = "file://README.md;md5=65c50b4ff3522b99436da100536ccd1c"
8
9inherit pkgconfig
10
11DEPENDS = "libx11 libxext libxinerama libxrandr libxcursor freetype alsa-lib curl"
12
13SRCREV = "4f41f28b47d01b939559123d145b4e5860528bb7"
14BRANCH = "master"
15SRC_URI = "git://github.com/WeAreROLI/JUCE.git;protocol=https;branch=${BRANCH}"
16
17S = "${WORKDIR}/git"
18PV = "5.0.1"
19
20JUCE_PROJUCER_BUILD_PATH = "${B}/extras/Projucer/Builds"
21JUCE_PROJUCER_MAKEFILE_PATH = "${JUCE_PROJUCER_BUILD_PATH}/LinuxMakefile"
22JUCE_PROJUCER = "${JUCE_PROJUCER_MAKEFILE_PATH}/build/Projucer"
23
24do_configure() {
25  cd ${JUCE_PROJUCER_MAKEFILE_PATH}
26  CONFIG=Release oe_runmake clean
27}
28
29do_compile() {
30  cd ${JUCE_PROJUCER_MAKEFILE_PATH}
31  CONFIG=Release oe_runmake
32}
33
34do_install() {
35  install -d ${D}${bindir}
36  install -m 0755 ${JUCE_PROJUCER} ${D}${bindir}
37}
38