1SUMMARY = "JUCE's Projucer"
2DESCRIPTION = "Projucer is used to build and generate support files and build infrastructure for all \
3JUCE supported platforms, including Linux and Embedded Linux."
4SECTION = "utils"
5HOMEPAGE = "http://juce.com/"
6LICENSE = "GPLv3"
7LIC_FILES_CHKSUM = "file://LICENSE.md;md5=12e9c2db7897c0349a4cc1c6d2a8c5d5"
8
9inherit pkgconfig features_check
10
11REQUIRED_DISTRO_FEATURES = "x11"
12
13DEPENDS = "libx11 libxext libxinerama libxrandr libxcursor freetype alsa-lib curl bzip2 libpng harfbuzz glib-2.0 libpcre"
14DEPENDS:append:libc-musl = " libexecinfo"
15
16SRCREV = "90e8da0cfb54ac593cdbed74c3d0c9b09bad3a9f"
17BRANCH = "master"
18SRC_URI = "git://github.com/WeAreROLI/JUCE.git;protocol=https;branch=${BRANCH} \
19"
20
21S = "${WORKDIR}/git"
22PV = "6.0.8"
23
24JUCE_PROJUCER_BUILD_PATH = "${B}/extras/Projucer/Builds"
25JUCE_PROJUCER_MAKEFILE_PATH = "${JUCE_PROJUCER_BUILD_PATH}/LinuxMakefile"
26JUCE_PROJUCER = "${JUCE_PROJUCER_MAKEFILE_PATH}/build/Projucer"
27
28# export dummy TARGET_ARCH that doesn't do much,
29# but disables "-march=native" optimization which does
30# not work on cross builds
31EXTRA_OEMAKE = "V=1 JUCE_ARCH_LABEL=${TARGET_ARCH} TARGET_ARCH='-g'"
32
33LDFLAGS:append:mipsarcho32 = " -latomic"
34LDFLAGS:append:powerpc = " -latomic"
35LDFLAGS:append:riscv64 = " -latomic"
36LDFLAGS:append:riscv32 = " -latomic"
37LDFLAGS:append:armv5 = " -latomic"
38
39do_configure() {
40  cd ${JUCE_PROJUCER_MAKEFILE_PATH}
41  CONFIG=Release oe_runmake clean
42}
43
44do_compile() {
45  cd ${JUCE_PROJUCER_MAKEFILE_PATH}
46  CONFIG=Release oe_runmake
47}
48
49do_install() {
50  install -d ${D}${bindir}
51  install -m 0755 ${JUCE_PROJUCER} ${D}${bindir}
52}
53# error: '_NL_IDENTIFICATION_LANGUAGE' was not declared in this scope
54COMPATIBLE_HOST:libc-musl = "null"
55