1DESCRIPTION = "klibc is intended to be a minimalistic libc subset for \
2use with initramfs.  It is deliberately written for small size, \
3minimal entaglement, and portability, not speed."
4SECTION = "libs"
5LICENSE = "BSD-3-Clause & GPL-2.0 & MIT & Zlib"
6LIC_FILES_CHKSUM = "file://usr/klibc/LICENSE;md5=d75181f10e998c21eb147f6d2e43ce8b"
7DEPENDS = "linux-libc-headers perl-native"
8
9SRC_URI = "${KERNELORG_MIRROR}/linux/libs/klibc/2.0/klibc-${PV}.tar.xz \
10           ${ARMPATCHES} \
11           file://klcc-consider-sysroot.patch \
12           file://klcc-cross-accept-clang-options.patch \
13           file://0001-dash-Specify-format-string-in-fmtstr.patch \
14           file://0001-Define-in_-structs-for-non-glibc-system-libs.patch \
15           file://0001-include-linux-sysinfo.h-directly.patch \
16           file://0001-mkfifo-Implement-mkfifo.patch \
17           file://0001-always-use-bfd-linker.patch \
18           file://0001-arm-Do-not-set-a-fallback-march-and-mtune.patch \
19           file://0001-klibc_2.0.4-add-kexec_file_load-syscall.patch \
20           file://0001-klibc-add-getrandom-syscall.patch \
21           file://0001-klibc-Kbuild-Accept-EXTRA_KLIBCAFLAGS.patch \
22           file://cross-clang.patch \
23           file://0001-workaround-for-overlapping-sections-in-binary.patch \
24           "
25
26ARMPATCHES ?= ""
27
28ARMPATCHES:arm = " \
29                  file://armv4-fix-v4bx.patch \
30                 "
31SRC_URI[sha256sum] = "4e48f1398cfe3ce0b6df55ce6e70acf54fc8488e3aea3fb3610ee1622d9cb436"
32
33S = "${WORKDIR}/klibc-${PV}"
34
35OPTFLAGS = "${TUNE_CCARGS} -Os -fcommon"
36OPTFLAGS:append:toolchain-clang = " -fno-builtin-bcmp"
37OPTFLAGS:append:toolchain-clang:mipsarch = " -no-integrated-as"
38
39PARALLEL_MAKE = ""
40EXTRA_OEMAKE = "'KLIBCARCH=${KLIBC_ARCH}' \
41                'CROSS_COMPILE=${TARGET_PREFIX}' \
42                'KLIBCKERNELSRC=${STAGING_DIR_TARGET}${exec_prefix}' \
43                'KLIBCLIBGCC=${STAGING_DIR_TARGET}${libdir}/${TARGET_SYS}/*/libgcc.a' \
44                'prefix=${exec_prefix}' \
45                'INSTALLROOT=${D}' \
46                'INSTALLDIR=${libdir}/klibc' \
47                'SHLIBDIR=${libdir}' \
48                '${KLIBCTHUMB}' \
49                'KLIBCOPTFLAGS=${OPTFLAGS}' \
50                 V=1 \
51                "
52
53export FIX_ARMV4_EABI_BX = "${FIX_V4BX}"
54KLIBCTHUMB = "${@['CONFIG_KLIBC_THUMB=n', 'CONFIG_KLIBC_THUMB=y'][(d.getVar('ARM_INSTRUCTION_SET') == 'thumb')]}"
55
56do_configure () {
57    ln -sf "${STAGING_DIR_TARGET}${exec_prefix}" linux
58}
59
60do_compile:prepend:toolchain-clang() {
61    sed -i -e 's#$(KLIBCROSS)gcc#$(KLIBCROSS)clang#g' ${S}/Makefile
62}
63
64INHIBIT_PACKAGE_STRIP = "1"
65INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
66INSANE_SKIP:${PN} = "already-stripped"
67INSANE_SKIP:libklibc-dev = "dev-elf"
68KLIBC_ARCH = "${TARGET_ARCH}"
69KLIBC_ARCH:aarch64 = "arm64"
70KLIBC_ARCH:armeb = "arm"
71KLIBC_ARCH:mipsel = "mips"
72KLIBC_ARCH:mips64el = "mips64"
73KLIBC_ARCH:x86 = "i386"
74KLIBC_ARCH:x86-64 = "x86_64"
75KLIBC_ARCH:powerpc = "ppc"
76KLIBC_ARCH:powerpc64 = "ppc64"
77KLIBC_ARCH:powerpc64le = "ppc64"
78THIS_LIBKLIBC = "libklibc (= ${PV}-${PR})"
79