1DESCRIPTION = "klibc is intended to be a minimalistic libc subset for \
2use with initramfs.  It is deliberately written for small size, \
3minimal entaglement, and portability, not speed."
4SECTION = "libs"
5LICENSE = "BSD-3-Clause & GPL-2.0 & MIT & Zlib"
6LIC_FILES_CHKSUM = "file://usr/klibc/LICENSE;md5=d75181f10e998c21eb147f6d2e43ce8b"
7DEPENDS = "linux-libc-headers perl-native"
8
9SRC_URI = "${KERNELORG_MIRROR}/linux/libs/klibc/2.0/klibc-${PV}.tar.xz \
10           ${ARMPATCHES} \
11           file://klcc-consider-sysroot.patch \
12           file://klcc-cross-accept-clang-options.patch \
13           file://0001-dash-Specify-format-string-in-fmtstr.patch \
14           file://0001-Define-in_-structs-for-non-glibc-system-libs.patch \
15           file://0001-include-linux-sysinfo.h-directly.patch \
16           file://0001-mkfifo-Implement-mkfifo.patch \
17           file://0001-always-use-bfd-linker.patch \
18           file://0001-Kbuild.klibc-Use-print-libgcc-file-name-instead-of-p.patch \
19           file://0001-Kbuild.klibc-Add-path-to-compiler-headers-via-isyste.patch \
20           file://0001-arm-Do-not-set-a-fallback-march-and-mtune.patch \
21           file://0001-klibc_2.0.4-add-kexec_file_load-syscall.patch \
22           file://0001-klibc-add-getrandom-syscall.patch \
23           file://0001-klibc-Kbuild-Accept-EXTRA_KLIBCAFLAGS.patch \
24           file://0001-Define-ulocked_-fgets-fread-fwrite-aliases.patch \
25           "
26
27ARMPATCHES ?= ""
28
29ARMPATCHES_arm = " \
30                  file://armv4-fix-v4bx.patch \
31                 "
32
33SRC_URI[md5sum] = "712f8bc1a069e03d92584b7f5380c521"
34SRC_URI[sha256sum] = "abef2637ca823485d9c90ce9512e2b08a65047ec4da204635eeaef95a41a9122"
35
36S = "${WORKDIR}/klibc-${PV}"
37
38OPTFLAGS = "${TUNE_CCARGS} -Os"
39OPTFLAGS_append_toolchain-clang = " -fno-builtin-bcmp"
40OPTFLAGS_append_toolchain-clang_mipsarch = " -no-integrated-as"
41
42PARALLEL_MAKE = ""
43EXTRA_OEMAKE = "'KLIBCARCH=${KLIBC_ARCH}' \
44                'CROSS_COMPILE=${TARGET_PREFIX}' \
45                'KLIBCKERNELSRC=${STAGING_DIR_TARGET}${exec_prefix}' \
46                'KLIBCLIBGCC=${STAGING_DIR_TARGET}${libdir}/${TARGET_SYS}/*/libgcc.a' \
47                'prefix=${exec_prefix}' \
48                'INSTALLROOT=${D}' \
49                'INSTALLDIR=${libdir}/klibc' \
50                'SHLIBDIR=${libdir}' \
51                '${KLIBCTHUMB}' \
52                'KLIBCOPTFLAGS=${OPTFLAGS}' \
53                 V=1 \
54                "
55
56export FIX_ARMV4_EABI_BX = "${FIX_V4BX}"
57KLIBCTHUMB = "${@['CONFIG_KLIBC_THUMB=n', 'CONFIG_KLIBC_THUMB=y'][(d.getVar('ARM_INSTRUCTION_SET') == 'thumb')]}"
58
59do_configure () {
60    ln -sf "${STAGING_DIR_TARGET}${exec_prefix}" linux
61}
62
63do_compile_prepend_toolchain-clang() {
64    sed -i -e 's#$(KLIBCROSS)gcc#$(KLIBCROSS)clang#g' ${S}/Makefile
65}
66
67INHIBIT_PACKAGE_STRIP = "1"
68INHIBIT_PACKAGE_DEBUG_SPLIT = "1"
69INSANE_SKIP_${PN} = "already-stripped"
70INSANE_SKIP_libklibc-dev = "dev-elf"
71KLIBC_ARCH = "${TARGET_ARCH}"
72KLIBC_ARCH_aarch64 = "arm64"
73KLIBC_ARCH_armeb = "arm"
74KLIBC_ARCH_mipsel = "mips"
75KLIBC_ARCH_mips64el = "mips64"
76KLIBC_ARCH_x86 = "i386"
77KLIBC_ARCH_x86-64 = "x86_64"
78KLIBC_ARCH_powerpc = "ppc"
79KLIBC_ARCH_powerpc64 = "ppc64"
80KLIBC_ARCH_powerpc64le = "ppc64"
81THIS_LIBKLIBC = "libklibc (= ${PV}-${PR})"
82