1SUMMARY = "Tracker is a file search engine"
2LICENSE = "GPL-2.0-only & LGPL-2.1-only"
3LIC_FILES_CHKSUM = " \
4    file://COPYING.GPL;md5=ee31012bf90e7b8c108c69f197f3e3a4 \
5    file://COPYING.LGPL;md5=2d5025d4aa3495befef8f17206a5b0a1 \
6"
7
8DEPENDS = " \
9    dbus-native \
10    python3-pygobject-native \
11    glib-2.0 \
12    sqlite3 \
13    libarchive \
14    dbus \
15    icu \
16    json-glib \
17    libsoup-3.0 \
18    libstemmer \
19"
20
21
22inherit gettext gnomebase gobject-introspection vala gtk-doc bash-completion python3native
23
24SRC_URI += "file://0001-fix-reproducibility.patch"
25SRC_URI[archive.sha256sum] = "cd91b885ee9839cde5387f8e05ed24a7108d1627629cb6b1b2aa51a9603e130a"
26
27# text search is not an option anymore and requires sqlite3 build with
28# PACKAGECONFIG[fts5] set (default)
29
30# set required cross property sqlite3_has_fts5
31do_write_config[vardeps] += "PACKAGECONFIG"
32do_write_config:append() {
33    echo "[properties]" > ${WORKDIR}/meson-tracker.cross
34    echo "sqlite3_has_fts5 = 'true'" >> ${WORKDIR}/meson-tracker.cross
35}
36
37EXTRA_OEMESON = " \
38    --cross-file ${WORKDIR}/meson-tracker.cross \
39    -Dman=false \
40    -Dsystemd_user_services=${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)} \
41    -Dsystemd_user_services_dir=${systemd_user_unitdir} \
42    -Dsoup=soup3 \
43    ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-Dvapi=enabled', '-Dvapi=disabled', d)} \
44"
45
46do_install:prepend() {
47    sed -i -e 's|${B}/../${PN}-${PV}|${TARGET_DBGSRC_DIR}|g' ${B}/src/libtracker-sparql/tracker-sparql-enum-types.c
48    sed -i -e 's|${B}/../${PN}-${PV}|${TARGET_DBGSRC_DIR}|g' ${B}/src/libtracker-sparql/core/tracker-data-enum-types.c
49}
50
51GIR_MESON_ENABLE_FLAG = 'enabled'
52GIR_MESON_DISABLE_FLAG = 'disabled'
53
54FILES:${PN} += " \
55    ${datadir}/dbus-1 \
56    ${datadir}/tracker3 \
57    ${libdir}/tracker-3.0 \
58    ${systemd_user_unitdir} \
59"
60