1SUMMARY = "Javascript bindings for GNOME"
2LICENSE = "MIT & LGPL-2.0-or-later"
3LIC_FILES_CHKSUM = "file://COPYING;md5=8dcea832f6acf45d856abfeb2d51ec48"
4
5
6DEPENDS = "mozjs-115 cairo"
7
8inherit gnomebase gsettings gobject-introspection gettext features_check upstream-version-is-even pkgconfig
9
10SRC_URI[archive.sha256sum] = "135e39c5ac591096233e557cfe577d64093f5054411d47cb2e214bad7d4199bd"
11SRC_URI += " \
12    file://0001-Support-cross-builds-a-bit-better.patch \
13    file://0002-meson.build-Do-not-add-dir-installed-tests-when-inst.patch \
14"
15
16# gobject-introspection is mandatory and cannot be configured
17REQUIRED_DISTRO_FEATURES = "gobject-introspection-data"
18GIR_MESON_OPTION = ""
19
20EXTRA_OEMESON = " \
21    -Dinstalled_tests=false \
22    -Dskip_dbus_tests=true \
23    -Dskip_gtk_tests=true \
24"
25
26LDFLAGS:append:mipsarch = " -latomic"
27LDFLAGS:append:powerpc = " -latomic"
28LDFLAGS:append:powerpc64 = " -latomic"
29LDFLAGS:append:riscv32 = " -latomic"
30
31FILES:${PN} += "${datadir}/gjs-1.0/lsan"
32
33PACKAGES =+ "${PN}-valgrind"
34FILES:${PN}-valgrind = "${datadir}/gjs-1.0/valgrind"
35RDEPENDS:${PN}-valgrind += "valgrind"
36
37# Valgrind not yet available on rv32/rv64
38RDEPENDS:${PN}-valgrind:remove:riscv32 = "valgrind"
39RDEPENDS:${PN}-valgrind:remove:riscv64 = "valgrind"
40