1require ${BPN}.inc
2
3DEPENDS = " \
4    ${BPN}-native intltool-native gperf-native \
5    glib-2.0 gtk+3 libgdata \
6    dbus db virtual/libiconv zlib libsoup-2.4 libical nss libsecret \
7"
8
9inherit gsettings gobject-introspection features_check cmake gtk-doc gettext perlnative
10
11REQUIRED_DISTRO_FEATURES = "x11"
12
13SRC_URI += " \
14    file://0001-CMakeLists.txt-Remove-TRY_RUN-for-iconv.patch \
15    file://0002-CMakeLists.txt-remove-CHECK_C_SOURCE_RUNS-check.patch \
16    file://0003-contact-Replace-the-Novell-sample-contact-with-somet.patch \
17    file://0004-call-native-helpers.patch \
18    file://iconv-detect.h \
19"
20
21LKSTRFTIME = "HAVE_LKSTRFTIME=ON"
22LKSTRFTIME_libc-musl = "HAVE_LKSTRFTIME=OFF"
23
24# For arm qemu-arm runs at 100% CPU load and never returns - so disable introspection for now
25GI_DATA_ENABLED="False"
26
27EXTRA_OECMAKE = " \
28    -DSYSCONF_INSTALL_DIR=${sysconfdir} \
29    -DWITH_KRB5=OFF \
30    -DENABLE_GOA=OFF \
31    -DENABLE_UOA=OFF \
32    -DENABLE_GOOGLE_AUTH=OFF \
33    -DENABLE_WEATHER=OFF \
34    -DENABLE_INTROSPECTION=${@bb.utils.contains('GI_DATA_ENABLED', 'True', 'ON', 'OFF', d)} \
35    -D${LKSTRFTIME} \
36    -DLIB_SUFFIX=${@d.getVar('baselib').replace('lib', '')} \
37"
38
39PACKAGECONFIG[canberra] = "-DENABLE_CANBERRA=ON,-DENABLE_CANBERRA=OFF,libcanberra"
40PACKAGECONFIG[oauth]    = "-DENABLE_OAUTH2=ON,-DENABLE_OAUTH2=OFF,webkitgtk json-glib"
41
42# BROKEN: due missing pkg-config in openldap eds' cmake finds host-libs when
43# searching for openldap-libs
44PACKAGECONFIG[openldap] = "-DWITH_OPENLDAP=ON,-DWITH_OPENLDAP=OFF,openldap"
45
46# -ldb needs this on some platforms
47LDFLAGS += "-lpthread -lgmodule-2.0 -lgthread-2.0"
48
49do_configure_append () {
50    cp ${WORKDIR}/iconv-detect.h ${S}/src
51
52    # fix native perl shebang
53    sed -i 's:${STAGING_BINDIR_NATIVE}/perl-native:${bindir}:' ${B}/src/tools/addressbook-export/csv2vcard
54
55    # fix abs path for g-ir-scanner-wrapper
56    sed  -i ${B}/build.ninja \
57        -e 's: ${bindir}/g-ir-scanner-wrapper: ${STAGING_BINDIR}/g-ir-scanner-wrapper:g'
58}
59
60do_compile_prepend() {
61    export GIR_EXTRA_LIBS_PATH="${B}/camel/.libs:${B}/libedataserver/.libs"
62}
63
64FILES_${PN} =+ " \
65    ${datadir}/dbus-1 \
66    ${datadir}/evolution-data-server-*/ui/ \
67    ${systemd_user_unitdir} \
68"
69
70RDEPENDS_${PN} += "perl"
71