1require ${BPN}.inc
2
3DEPENDS = " \
4    ${BPN}-native intltool-native gperf-native \
5    glib-2.0 gtk+3 libgdata libxml2 icu \
6    dbus db virtual/libiconv zlib libsoup-2.4 libical nss libsecret \
7"
8
9inherit pkgconfig gsettings gobject-introspection features_check cmake gtk-doc gettext perlnative vala
10
11REQUIRED_DISTRO_FEATURES = "x11"
12
13SRC_URI += " \
14    file://0001-CMakeLists.txt-Remove-TRY_RUN-for-iconv.patch \
15    file://0002-CMakeLists.txt-remove-CHECK_C_SOURCE_RUNS-check.patch \
16    file://0003-contact-Replace-the-Novell-sample-contact-with-somet.patch \
17    file://0004-call-native-helpers.patch \
18    file://iconv-detect.h \
19"
20
21LKSTRFTIME = "HAVE_LKSTRFTIME=ON"
22LKSTRFTIME:libc-musl = "HAVE_LKSTRFTIME=OFF"
23
24EXTRA_OECMAKE = " \
25    -DSYSCONF_INSTALL_DIR=${sysconfdir} \
26    -DWITH_KRB5=OFF \
27    -DENABLE_UOA=OFF \
28    -DENABLE_GOOGLE_AUTH=OFF \
29    -DENABLE_WEATHER=OFF \
30    -DG_IR_COMPILER=${STAGING_BINDIR}/g-ir-compiler-wrapper \
31    -DG_IR_SCANNER=${STAGING_BINDIR}/g-ir-scanner-wrapper \
32    -DVAPIGEN=${STAGING_BINDIR_NATIVE}/vapigen \
33    ${@bb.utils.contains('GI_DATA_ENABLED', 'True', '-DENABLE_INTROSPECTION=ON -DENABLE_VALA_BINDINGS=ON', '-DENABLE_INTROSPECTION=OFF', d)} \
34    -D${LKSTRFTIME} \
35    -DLIB_SUFFIX=${@d.getVar('baselib').replace('lib', '')} \
36"
37
38PACKAGECONFIG[canberra] = "-DENABLE_CANBERRA=ON,-DENABLE_CANBERRA=OFF,libcanberra"
39PACKAGECONFIG[oauth]    = "-DENABLE_OAUTH2=ON,-DENABLE_OAUTH2=OFF,webkitgtk json-glib"
40PACKAGECONFIG[goa]    = "-DENABLE_GOA=ON,-DENABLE_GOA=OFF,gnome-online-accounts"
41
42# BROKEN: due missing pkg-config in openldap eds' cmake finds host-libs when
43# searching for openldap-libs
44PACKAGECONFIG[openldap] = "-DWITH_OPENLDAP=ON,-DWITH_OPENLDAP=OFF,openldap"
45
46# -ldb needs this on some platforms
47LDFLAGS += "-lpthread -lgmodule-2.0 -lgthread-2.0"
48
49do_configure:append () {
50    cp ${WORKDIR}/iconv-detect.h ${S}/src
51    # avoid writing perl-native path into csv2vcard shebang
52    sed -i "s|@PERL@|${bindir}/perl|" ${S}/src/tools/addressbook-export/csv2vcard.in
53}
54
55FILES:${PN} =+ " \
56    ${datadir}/dbus-1 \
57    ${datadir}/evolution-data-server-*/ui/ \
58    ${systemd_user_unitdir} \
59"
60
61RDEPENDS:${PN} += "perl"
62