1DESCRIPTION = "Devilspie2 is a window matching utility, allowing the user to perform scripted actions on windows as they are created"
2HOMEPAGE = "http://www.gusnan.se/devilspie2"
3LICENSE = "GPL-3.0-only"
4LIC_FILES_CHKSUM = "file://COPYING;md5=00aefaa50aad75c21367df66102d542c \
5                    file://GPL3.txt;md5=d32239bcb673463ab874e80d47fae504"
6
7DEPENDS = "gtk+ glib-2.0 libwnck libxinerama lua virtual/libx11"
8
9PV .= "+git${SRCPV}"
10
11SRCREV = "b9d7ad9c09a5fb17a1562ee1d892798c646e9ec9"
12
13SRC_URI = "git://github.com/dsalt/devilspie2;branch=master;protocol=https \
14    file://default.lua \
15    file://devilspie2.desktop \
16"
17
18S = "${WORKDIR}/git"
19
20inherit features_check pkgconfig gettext
21
22REQUIRED_DISTRO_FEATURES = "x11"
23
24do_compile() {
25    export GTK2=1
26    oe_runmake CC="${CC}" CPPFLAGS="${CPPFLAGS}" LDFLAGS=" -ldl -lm ${LDFLAGS}"
27}
28
29do_install() {
30    oe_runmake DESTDIR="${D}" PREFIX="${prefix}" install
31    install -d ${D}/${sysconfdir}/devilspie2
32    install -m 644 ${WORKDIR}/default.lua ${D}/${sysconfdir}/devilspie2
33    install -d ${D}/${sysconfdir}/xdg/autostart
34    install -m 644 ${WORKDIR}/devilspie2.desktop ${D}/${sysconfdir}/xdg/autostart
35}
36