1SUMMARY = "GEGL (Generic Graphics Library) is a graph based image processing framework"
2LICENSE = "GPL-3.0-only"
3LIC_FILES_CHKSUM = "file://COPYING;md5=f1a8bfcbc85304df454b65d378b299c7"
4
5DEPENDS = " \
6    intltool-native \
7    babl \
8    glib-2.0 \
9    cairo \
10    expat \
11    zlib \
12    \
13    json-glib \
14"
15
16DEPENDS:append:toolchain-clang  = " openmp"
17DEPENDS:remove:toolchain-clang:riscv32  = "openmp"
18DEPENDS:remove:toolchain-clang:powerpc  = "openmp"
19
20VALA_MESON_OPTION = ""
21
22inherit features_check gnomebase gobject-introspection vala
23
24ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
25
26SHPV = "${@gnome_verdir("${PV}")}"
27
28SRC_URI = "https://download.gimp.org/pub/${BPN}/${SHPV}/${BP}.tar.xz"
29SRC_URI[sha256sum] = "418c26d94be8805d7d98f6de0c6825ca26bd74fcacb6c188da47533d9ee28247"
30
31PACKAGECONFIG ??= "gexiv2 jpeg libpng libraw librsvg pango poppler sdl2"
32PACKAGECONFIG:class-native = "libpng librsvg"
33
34PACKAGECONFIG[jasper] = "-Djasper=enabled,-Djasper=disabled,jasper"
35PACKAGECONFIG[gexiv2] = "-Dgexiv2=enabled,-Dgexiv2=disabled,gexiv2"
36PACKAGECONFIG[graphviz] = "-Dgraphviz=enabled,-Dgraphviz=disabled,graphviz"
37PACKAGECONFIG[jpeg] = "-Dlibjpeg=enabled,-Dlibjpeg=disabled,jpeg"
38PACKAGECONFIG[lcms] = "-Dlcms=enabled,-Dlcms=disabled,lcms"
39PACKAGECONFIG[libav] = "-Dlibav=enabled,-Dlibav=disabled,libav"
40PACKAGECONFIG[libpng] = "-Dlibpng=enabled,-Dlibpng=disabled,libpng"
41PACKAGECONFIG[libraw] = "-Dlibraw=enabled,-Dlibraw=disabled,libraw"
42PACKAGECONFIG[librsvg] = "-Dlibrsvg=enabled,-Dlibrsvg=disabled,librsvg"
43PACKAGECONFIG[pango] = "-Dpango=enabled -Dpangocairo=enabled,-Dpango=disabled -Dpangocairo=disabled,pango"
44PACKAGECONFIG[poppler] = "-Dpoppler=enabled,-Dpoppler=disabled,poppler"
45PACKAGECONFIG[sdl] = "-Dsdl1=enabled,-Dsdl1=disabled,libsdl"
46PACKAGECONFIG[sdl2] = "-Dsdl2=enabled,-Dsdl2=disabled,libsdl2"
47PACKAGECONFIG[tiff] = "-Dlibtiff=enabled,-Dlibtiff=disabled,tiff"
48PACKAGECONFIG[webp] = "-Dwebp=enabled,-Dwebp=disabled,webp"
49
50# There are a couple of non-symlink .so files installed into libdir, which need to go into main package
51FILES:${PN} += " \
52    ${libdir}/*.so \
53    ${libdir}/gegl-${SHPV}/*.json \
54    ${libdir}/gegl-${SHPV}/*.so \
55"
56FILES_SOLIBSDEV = "${libdir}/libgegl-${SHPV}${SOLIBSDEV}"
57
58# Fails to build with thumb-1 (qemuarm)
59# gegl-0.2.0/operations/common/matting-global.c: In function 'matting_process':
60# gegl-0.2.0/operations/common/matting-global.c:463:1: internal compiler error: in patch_jump_insn, at cfgrtl.c:1275
61ARM_INSTRUCTION_SET = "arm"
62
63BBCLASSEXTEND = "native"
64