1SUMMARY = "Geary is an email application built around conversations, for the GNOME 3 desktop."
2SECTION = "network"
3LICENSE = "LGPL-2.1-only"
4LIC_FILES_CHKSUM = "file://COPYING;md5=2a2244d5a13871ad950c55877546a6a2"
5
6DEPENDS = " \
7    appstream-glib \
8    cairo \
9    desktop-file-utils-native \
10    enchant2 \
11    evolution-data-server \
12    folks \
13    gcr3 \
14    gmime \
15    gnome-online-accounts \
16    gsound \
17    gspell \
18    gtk+3 \
19    icu \
20    iso-codes \
21    json-glib \
22    libhandy \
23    libical \
24    libpeas \
25    libsecret \
26    libstemmer \
27    libxml2 \
28    sqlite3 \
29    webkitgtk3 \
30"
31
32RDEPENDS:${PN} = "gnome-keyring"
33
34inherit meson pkgconfig mime-xdg gtk-icon-cache gobject-introspection vala features_check
35
36SRC_URI = " \
37	git://github.com/GNOME/geary.git;nobranch=1;protocol=https \
38	file://0001-meson-Use-PKG_CONFIG_SYSROOT_DIR-when-using-pkg-conf.patch \
39"
40
41S = "${WORKDIR}/git"
42SRCREV = "37c378a563d5b1c269d57c34671edc940d1cd180"
43
44ANY_OF_DISTRO_FEATURES = "${GTK3DISTROFEATURES}"
45REQUIRED_DISTRO_FEATURES = "gobject-introspection-data opengl"
46
47GIR_MESON_OPTION = ""
48EXTRA_OEMESON = "-Dprofile=release"
49
50PACKAGECONFIG[libunwind] = "-Dlibunwind=enabled,-Dlibunwind=disabled,libunwind"
51PACKAGECONFIG[tnef] = "-Dtnef=enabled,-Dtnef=disabled,libytnef"
52PACKAGECONFIG[valadoc] = "-Dvaladoc=enabled,-Dvaladoc=disabled"
53
54PACKAGECONFIG ??= ""
55# rfc822/rfc822-message.c:2097:12: error: incompatible pointer to integer conversion returning 'void *' from a function with result type 'gboolean' (aka 'int') [-Wint-conversion]
56#|                                 return NULL;
57#|                                        ^~~~
58CFLAGS:append:toolchain-clang = " -Wno-error=int-conversion"
59
60FILES:${PN} += "${datadir}"
61
62