1SUMMARY = "XFS Filesystem Dump Utility"
2DESCRIPTION = "The xfsdump package contains xfsdump, xfsrestore and a \
3               number of other utilities for administering XFS filesystems.\
4               xfsdump examines files in a filesystem, determines which \
5               need to be backed up, and copies those files to a \
6               specified disk, tape or other storage medium."
7HOMEPAGE = "http://oss.sgi.com/projects/xfs"
8SECTION = "base"
9LICENSE = "GPL-2.0-only"
10LIC_FILES_CHKSUM = "file://doc/COPYING;md5=15c832894d10ddd00dfcf57bee490ecc"
11DEPENDS = "xfsprogs attr"
12
13SRC_URI = "https://www.kernel.org/pub/linux/utils/fs/xfs/xfsdump/${BP}.tar.xz \
14           file://remove-install-as-user.patch \
15           file://0001-include-libgen.h-for-basename-API-prototype.patch \
16           ${@bb.utils.contains('DISTRO_FEATURES','usrmerge','file://0001-xfsdump-support-usrmerge.patch','',d)} \
17           "
18SRC_URI[sha256sum] = "f39c4c1b306b2dd7ec979c0e94d60fe69083d2ecf9af051cac5ef3bed772c74a"
19
20inherit autotools-brokensep
21
22PARALLEL_MAKE = ""
23PACKAGECONFIG ??= ""
24PACKAGECONFIG[gettext] = "--enable-gettext=yes,--enable-gettext=no,gettext"
25
26CFLAGS += "-D_FILE_OFFSET_BITS=64"
27TARGET_CC_ARCH:append:libc-musl = " -D_LARGEFILE64_SOURCE"
28
29do_configure () {
30    export DEBUG="-DNDEBUG"
31    install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}
32    install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}
33    oe_runconf
34}
35
36do_install () {
37    export DIST_ROOT=${D}
38    oe_runmake install
39    oe_runmake install-dev
40}
41