1SUMMARY = "Tools for managing AUFS mounts"
2SECTION = "base"
3HOMEPAGE = "http://aufs.sourceforge.net/"
4LICENSE = "GPLv2"
5LIC_FILES_CHKSUM = "file://COPYING;md5=892f569a555ba9c07a568a7c0c4fa63a"
6
7DEPENDS = "coreutils-native aufs-util-native"
8DEPENDS_class-native = ""
9
10SRCREV = "8f35db59ef83078f87879ec2828e0bb45719e0ef"
11SRC_URI = "git://git.code.sf.net/p/aufs/aufs-util;protocol=git;branch=aufs4.9 \
12           https://raw.githubusercontent.com/sfjro/aufs4-linux/aufs4.9/include/uapi/linux/aufs_type.h;name=aufs_type \
13           file://aufs-util-don-t-strip-executables.patch \
14           file://aufs-util-add-tool-concept-to-Makefile-for-cross-com.patch \
15"
16SRC_URI[aufs_type.md5sum] = "b37129ef0703de72a852db7e48bdedc6"
17SRC_URI[aufs_type.sha256sum] = "7ff6566adb9c7a3b6862cdc85a690ab546f1d0bc81ddd595fd663c0a69031683"
18
19UPSTREAM_CHECK_COMMITS = "1"
20
21PV = "4.9+git${SRCPV}"
22
23S = "${WORKDIR}/git"
24
25export HOSTCC = "${BUILD_CC}"
26do_configure_prepend() {
27   # Replace sbin,bin paths with bitbake environment
28   sed -i -e 's;install_sbin: Tgt = ${DESTDIR}/sbin;install_sbin: Tgt = ${DESTDIR}/${base_sbindir};' \
29          -e 's;install_ubin: Tgt = ${DESTDIR}/usr/sbin;install_sbin: Tgt = ${DESTDIR}/${bindir};' \
30	  ${S}/Makefile
31}
32
33do_configure_append () {
34    install -d ${S}/include/linux/
35    cp ${WORKDIR}/aufs_type.h ${S}/include/linux/
36    sed -i -e 's;__user;;' ${S}/include/linux/aufs_type.h
37}
38
39do_configure_append_class-target () {
40    for i in ver c2sh c2tmac; do
41        cp ${STAGING_BINDIR_NATIVE}/aufs-util-${PV}/$i ${B}
42    done
43}
44
45do_compile () {
46    oe_runmake CPPFLAGS="-I${S}/include -I${S}/libau"
47}
48
49do_compile_class-native () {
50    oe_runmake tools CPPFLAGS="-I${S}/include -I${S}/libau" CC="${BUILD_CC}"
51}
52
53do_install () {
54    oe_runmake 'DESTDIR=${D}' install_sbin install_ubin install_etc
55}
56
57do_install_class-native () {
58    install -d ${D}${bindir}/aufs-util-${PV}
59    for i in ver c2sh c2tmac; do
60        install -m 755 $i ${D}${bindir}/aufs-util-${PV}/$i
61    done
62}
63
64RRECOMMENDS_${PN}_class-target += "kernel-module-aufs"
65
66BBCLASSEXTEND = "native"
67