1SUMMARY = "Configures systemd settings for gBMC"
2PR = "r1"
3LICENSE = "Apache-2.0"
4LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/Apache-2.0;md5=89aea4e17d99a7cacdbeed46a0096b10"
5
6inherit systemd
7
8S = "${WORKDIR}"
9
10SRC_URI_append = " \
11  file://firmware-updates.target \
12  file://firmware-updates-pre.target \
13  "
14
15FILES_${PN}_append = " \
16  ${systemd_unitdir}/coredump.conf.d/40-gbmc-coredump.conf \
17  ${systemd_unitdir}/resolved.conf.d/40-gbmc-nomdns.conf \
18  "
19
20FILES_${PN}_append_dev = " \
21  ${libdir}/sysctl.d/40-gbmc-debug.conf \
22  "
23
24SYSTEMD_SERVICE_${PN}_append = " \
25  firmware-updates.target \
26  firmware-updates-pre.target \
27  "
28
29# Put coredumps in the journal to ensure they stay in ram
30do_install() {
31    install -d -m 0755 ${D}${systemd_unitdir}/coredump.conf.d
32    printf "[Coredump]\nStorage=journal\n" \
33        >${D}${systemd_unitdir}/coredump.conf.d/40-gbmc-coredump.conf
34
35    install -d -m 0755 ${D}${systemd_unitdir}/resolved.conf.d
36    printf "[Resolve]\nLLMNR=no\nMulticastDNS=resolve\n" \
37        >${D}${systemd_unitdir}/resolved.conf.d/40-gbmc-nomdns.conf
38
39    install -d -m 0755 ${D}${systemd_system_unitdir}
40    install -m 0644 ${WORKDIR}/firmware-updates.target ${D}${systemd_system_unitdir}/
41    install -m 0644 ${WORKDIR}/firmware-updates-pre.target ${D}${systemd_system_unitdir}/
42}
43
44do_install_append_dev() {
45    install -d -m 0755 ${D}${libdir}/sysctl.d
46    printf "kernel.sysrq = 1\n" \
47        >${D}${libdir}/sysctl.d/40-gbmc-debug.conf
48
49}
50