1require u-boot-common-aspeed_${PV}.inc
2
3SRC_URI += "file://default-gcc.patch"
4SRC_URI += "file://fw_env.config"
5SRC_URI += "file://alt_fw_env.config"
6
7SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
8DEPENDS += "mtd-utils"
9
10PROVIDES += "u-boot-fw-utils"
11
12INSANE_SKIP_${PN} = "already-stripped"
13EXTRA_OEMAKE_class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" V=1'
14EXTRA_OEMAKE_class-cross = 'ARCH=${TARGET_ARCH} CC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
15
16inherit uboot-config
17
18do_compile () {
19	oe_runmake ${UBOOT_MACHINE}
20	oe_runmake env
21}
22
23do_install () {
24	install -d ${D}${base_sbindir}
25	install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
26	install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
27
28	install -d ${D}${sysconfdir}
29	install -m 644 ${WORKDIR}/fw_env.config ${D}${sysconfdir}/fw_env.config
30	install -m 644 ${WORKDIR}/alt_fw_env.config ${D}${sysconfdir}/alt_fw_env.config
31}
32
33do_install_class-cross () {
34	install -d ${D}${bindir_cross}
35	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
36	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
37}
38
39SYSROOT_DIRS_append_class-cross = " ${bindir_cross}"
40
41PACKAGE_ARCH = "${MACHINE_ARCH}"
42BBCLASSEXTEND = "cross"
43
44RDEPENDS_${PN} = "udev-aspeed-mtd-partitions"
45