1require u-boot-common-aspeed-sdk_${PV}.inc
2
3SUMMARY = "U-Boot bootloader fw_printenv/setenv utilities"
4DEPENDS += "mtd-utils"
5
6PROVIDES += "u-boot-fw-utils"
7
8SRC_URI += "file://fw_env_ast2600_nor.config"
9SRC_URI += "file://fw_env_ast2600_mmc.config"
10
11ENV_CONFIG_FILE = "fw_env_ast2600_nor.config"
12ENV_CONFIG_FILE:df-phosphor-mmc = "fw_env_ast2600_mmc.config"
13
14INSANE_SKIP:${PN} = "already-stripped"
15EXTRA_OEMAKE:class-target = 'CROSS_COMPILE=${TARGET_PREFIX} CC="${CC} ${CFLAGS} ${LDFLAGS}" HOSTCC="${BUILD_CC} ${BUILD_CFLAGS} ${BUILD_LDFLAGS}" V=1'
16EXTRA_OEMAKE:class-cross = 'HOSTCC="${CC} ${CFLAGS} ${LDFLAGS}" V=1'
17
18inherit uboot-config
19
20do_compile () {
21	oe_runmake ${UBOOT_MACHINE}
22	oe_runmake envtools
23}
24
25do_install () {
26	install -d ${D}${base_sbindir}
27	install -d ${D}${sysconfdir}
28	install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_printenv
29	install -m 755 ${S}/tools/env/fw_printenv ${D}${base_sbindir}/fw_setenv
30
31	install -m 644 ${WORKDIR}/${ENV_CONFIG_FILE} ${D}${sysconfdir}/fw_env.config
32}
33
34do_install:class-cross () {
35	install -d ${D}${bindir_cross}
36	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_printenv
37	install -m 755 ${S}/tools/env/fw_printenv ${D}${bindir_cross}/fw_setenv
38}
39
40SYSROOT_DIRS:append:class-cross = " ${bindir_cross}"
41
42PACKAGE_ARCH = "${MACHINE_ARCH}"
43BBCLASSEXTEND = "cross"
44