1*** Settings ***
2Documentation       Inventory of hardware FRUs under redfish.
3
4Resource            ../../lib/bmc_redfish_resource.robot
5Resource            ../../lib/bmc_redfish_utils.robot
6Resource            ../../lib/openbmc_ffdc.robot
7Library             ../../lib/gen_robot_valid.py
8
9Suite Setup         Suite Setup Execution
10Suite Teardown      Suite Teardown Execution
11Test Setup          Printn
12Test Teardown       Test Teardown Execution
13
14*** Variables ***
15
16# The passing criteria.  Must have at least this many.
17${min_num_dimms}   2
18${min_num_cpus}    1
19${min_num_cores}   18
20${min_num_power_supplies}  1
21
22
23*** Test Cases ***
24
25
26Verify CPU And Core Count
27    [Documentation]  Get the total number of CPUs and cores in the system.
28    ...              Verify counts are above minimums.
29    [Tags]  Verify_CPU_And_Core_Count
30
31    # Select only CPUs with Health = "OK".
32    ${cpus_ok}=  Filter Struct  ${cpu_info}  [('Health', 'OK')]
33    ${num_cpus}=   Get Length  ${cpus_ok}
34
35    Rprint Vars  num_cpus  min_num_cpus
36
37    # Assert that num_cpus is greater than or equal to min_num_cpus.
38    Valid Range  num_cpus  ${min_num_cpus}
39
40    # Get the number of cores.
41    ${total_num_cores}=  Set Variable  ${0}
42    FOR  ${cpu}  IN  @{cpus_ok}
43        ${cores}=   Get CPU TotalCores  ${cpu}
44        ${total_num_cores}=  Evaluate  $total_num_cores + ${cores}
45    END
46
47    Rprint Vars  total_num_cores  min_num_cores
48
49    # Assert that total_num_cores is greater than or equal to
50    # min_num_cores.
51    Valid Range  total_num_cores  ${min_num_cores}
52
53
54Get Memory Inventory Via Redfish And Verify
55    [Documentation]  Get the number of DIMMs that are functional and enabled.
56    [Tags]  Get_Memory_Inventory_Via_Redfish_And_Verify
57
58    Verify FRU Inventory Minimums  Memory  ${min_num_dimms}
59
60
61Get Memory Summary State And Verify Enabled
62    [Documentation]  Check that the state of the MemorySummary attribute
63    ...              under /redfish/v1/Systems/system is 'Enabled'.
64    [Tags]  Get_Memory_Summary_State_And_Verify_Enabled
65
66    ${status}=  Redfish.Get Attribute  ${SYSTEM_BASE_URI}  MemorySummary
67    ${memory_summary_state}=  Set Variable  ${status['Status']['State']}
68    Rprint Vars  memory_summary_state
69
70    Should Be Equal As Strings  Enabled  ${memory_summary_state}
71    ...  msg=MemorySummary State is not 'Enabled'.
72
73
74Get System Serial And Verify Populated
75    [Documentation]  Check that the System SerialNumber is non-blank.
76    [Tags]  Get_System_Serial_And_Verify_Populated
77
78    ${serial_number}=  Redfish.Get Attribute  ${SYSTEM_BASE_URI}  SerialNumber
79    Valid Value  serial_number
80    Rprint Vars  serial_number
81
82
83Get Model And Verify Populated
84    [Documentation]  Check that the Model is non-blank.
85    [Tags]  Get_Model_And_Verify_Populated
86
87    ${model}=  Redfish.Get Attribute  ${SYSTEM_BASE_URI}  Model
88    Valid Value  model
89    Rprint Vars  model
90
91
92Get Available Power Supplies And Verify
93    [Documentation]  Get the number of functional power supplies and
94    ...              verify that it is at or above the minimum.
95    [Tags]  Get_Available_Power_Supplies_And_Verify
96
97    # Select only power supplies with Health = "OK".
98    ${power_supplies_ok}=  Filter Struct  ${power_supplies}  [('Health', 'OK')]
99
100    # Count the power supplies that are Enabled or StandbyOffline.
101    ${total_num_supplies}=  Set Variable  ${0}
102    FOR  ${power_supply}  IN  @{power_supplies_ok}
103        # Example of power_supply:
104        # power_supply = {'@odata.id': '/redfish/v1/Chassis/chassis/Power#/PowerSupplies/0',
105        # 'Manufacturer': '', 'MemberId': 'powersupply0', 'Model': '2100', 'Name':
106        # 'powersupply0', 'PartNumber': 'PNPWR123', 'PowerInputWatts': 394.0,
107        # 'SerialNumber': '75B12W', 'Status': {'Health': 'OK', 'State': 'Enabled'}}
108        ${state}=  Set Variable  ${power_supply['Status']['State']}
109        ${good_state}=  Evaluate
110        ...  any(x in '${state}' for x in ('Enabled', 'StandbyOffline'))
111        Run Keyword If  not ${good_state}  Continue For Loop
112        ${total_num_supplies}=  Evaluate  $total_num_supplies + ${1}
113    END
114
115    Rprint Vars  total_num_supplies  min_num_power_supplies
116
117    Valid Range  total_num_supplies  ${min_num_power_supplies}
118
119
120Get Motherboard Serial And Verify Populated
121    [Documentation]  Check that the Motherboard SerialNumber is non-blank.
122    [Tags]  Get_Motherboard_Serial_And_Verify_Populated
123
124    ${serial_number}=  Redfish.Get Attribute  ${REDFISH_CHASSIS_URI}${CHASSIS_ID}  SerialNumber
125    Valid Value  serial_number
126    Rprint Vars  serial_number
127
128
129Verify Motherboard Manufacturer Field Value Populated
130    [Documentation]  Check that the Motherboard manufacturer is non-blank.
131    [Tags]  Verify_Motherboard_Manufacturer_Field_Value_Populated
132
133    ${motherboard_manufacturer}=  Redfish.Get Attribute  ${REDFISH_CHASSIS_URI}${CHASSIS_ID}  Manufacturer
134    Valid Value  motherboard_manufacturer
135    Rprint Vars  motherboard_manufacturer
136
137
138Verify Motherboard Partnumber Field Value Populated
139    [Documentation]  Check that the Motherboard partnumber is non-blank.
140    [Tags]  Verify_Motherboard_Partnumber_Field_Value_Populated
141
142    ${motherboard_part_number}=  Redfish.Get Attribute  ${REDFISH_CHASSIS_URI}${CHASSIS_ID}  PartNumber
143    Valid Value  motherboard_part_number
144    Rprint Vars  motherboard_part_number
145
146
147Check GPU States When Power On
148    [Documentation]  Check the State of each of the GPUs
149    ...              in the system.  A system may have 0-6 GPUs.
150    [Tags]  Check_GPU_States_When_Power_On
151
152    # System was powered-on in Suite Setup.
153    GPU State Check
154
155
156Check GPU States When Power Off
157    [Documentation]  Check the State of the GPUs when power is Off.
158    [Tags]  Check_GPU_States_When_Power_Off
159
160    Redfish Power Off
161    GPU State Check
162
163
164*** Keywords ***
165
166
167Get CPU TotalCores
168    [Documentation]  Return the TotalCores of a CPU.
169    ...              Return 0 if this attribute is missing or NONE.
170    [Arguments]      ${processor}
171
172    # Description of Argument(s):
173    # processor     The Redfish URI of a CPU (e.g.
174    #               "/redfish/v1/Systems/system/Processors/cpu0").
175
176    ${total_cores}=  Redfish.Get Attribute  ${processor}  TotalCores
177    Return From Keyword If  ${total_cores} is ${NONE}  ${0}
178    [Return]  ${total_cores}
179
180
181GPU State Check
182    [Documentation]  The state of every "OK" GPU should be
183    ...              "Absent", "Enabled", or "UnavailableOffline".
184
185    # Select only GPUs with Health = "OK".
186    ${gpus_ok}=  Filter Struct  ${gpu_info}  [('Health', 'OK')]
187
188    FOR  ${gpu}  IN  @{gpus_ok}
189        ${status}=  Redfish.Get Attribute  ${gpu}  Status
190        ${state}=  Set Variable  ${status['State']}
191        ${good_state}=  Evaluate
192        ...  any(x in '${state}' for x in ('Absent', 'Enabled', 'UnavailableOffline'))
193        Rprint Vars  gpu  state
194        Run Keyword If  not ${good_state}  Fail
195        ...  msg=GPU State is not Absent, Enabled, or UnavailableOffline.
196    END
197
198
199Get Inventory URIs
200    [Documentation]  Get and return a tuple of lists of URIs for CPU,
201    ...              GPU and PowerSupplies.
202
203    ${processor_info}=  Redfish_Utils.Enumerate Request
204    ...  ${SYSTEM_BASE_URI}Processors  return_json=0
205
206    ${cpu_info}=  Filter Struct  ${processor_info}
207    ...  [('ProcessorType', 'CPU')]  regex=1
208
209    ${gpu_info}=  Filter Struct  ${processor_info}
210    ...  [('ProcessorType', 'Accelerator')]  regex=1
211
212    ${power_supplies}=  Redfish.Get Attribute
213    ...  ${REDFISH_CHASSIS_POWER_URI}  PowerSupplies
214
215    [Return]  ${cpu_info}  ${gpu_info}  ${power_supplies}
216
217
218Verify FRU Inventory Minimums
219    [Documentation]  Verify a minimum number of FRUs.
220    [Arguments]  ${fru_type}  ${min_num_frus}
221
222    # Description of Argument(s):
223    # fru_type      The type of FRU (e.g. "Processors", "Memory", etc.).
224    # min_num_frus  The minimum acceptable number of FRUs found.
225
226    # A valid FRU  will have a "State" key of "Enabled" and a "Health" key
227    # of "OK".
228
229    ${status}  ${num_valid_frus}=  Run Key U  Get Num Valid FRUs \ ${fru_type}
230
231    Rprint Vars  fru_type  num_valid_frus  min_num_frus
232
233    Return From Keyword If  ${num_valid_frus} >= ${min_num_frus}
234    Fail  Too few "${fru_type}" FRUs found, found only ${num_valid_frus}.
235
236
237Suite Teardown Execution
238    [Documentation]  Do the post suite teardown.
239
240    Redfish.Logout
241
242
243Suite Setup Execution
244    [Documentation]  Do test case setup tasks.
245
246    Redfish.Login
247    Redfish Power On  stack_mode=skip
248
249    ${cpu_info}  ${gpu_info}  ${power_supplies}=  Get Inventory URIs
250
251    Set Suite Variable  ${cpu_info}
252    Set Suite Variable  ${gpu_info}
253    Set Suite Variable  ${power_supplies}
254
255
256Test Teardown Execution
257    [Documentation]  Do the post test teardown.
258
259    FFDC On Test Case Fail
260