1*** Settings ***
2Documentation    Test Redfish to verify responses for SessionService and Hypermedia.
3
4Resource         ../../lib/resource.robot
5Resource         ../../lib/bmc_redfish_resource.robot
6Resource         ../../lib/openbmc_ffdc.robot
7
8
9Test Teardown    FFDC On Test Case Fail
10Test Setup       Printn
11
12*** Test Cases ***
13
14Redfish Login And Logout
15    [Documentation]  Login to BMCweb and then logout.
16    [Tags]  Redfish_Login_And_Logout
17
18    Redfish.Login
19    Redfish.Logout
20
21
22GET Redfish Hypermedia Without Login
23    [Documentation]  GET hypermedia URL without login.
24    [Tags]  GET_Redfish_Hypermedia_Without_Login
25    [Setup]  Redfish.Logout
26    [Template]  GET And Verify Redfish Response
27
28    # Expect status      Resource URL Path
29    ${HTTP_OK}           /redfish
30    ${HTTP_OK}           /redfish/v1
31
32
33GET Redfish SessionService Without Login
34    [Documentation]  Get /redfish/v1/SessionService without login
35    [Tags]  GET_Redfish_SessionService_Without_Login
36    [Setup]  Redfish.Logout
37
38    ${resp}=  Redfish.Get  /redfish/v1/SessionService
39    ...  valid_status_codes=[${HTTP_UNAUTHORIZED}]
40
41
42GET Redfish Resources With Login
43    [Documentation]  Login to BMCweb and GET valid resource.
44    [Tags]  GET_Redfish_Resources_With_Login
45    [Setup]  Redfish.Login
46    [Template]  GET And Verify Redfish Response
47
48    # Expect status      Resource URL Path
49    ${HTTP_OK}           /redfish/v1/SessionService
50    ${HTTP_OK}           /redfish/v1/AccountService
51    ${HTTP_OK}           /redfish/v1/Systems/system
52    ${HTTP_OK}           /redfish/v1/Chassis/${CHASSIS_ID}
53    ${HTTP_OK}           /redfish/v1/Managers/bmc
54    ${HTTP_OK}           /redfish/v1/UpdateService
55
56
57Redfish Login Using Invalid Token
58    [Documentation]  Login to BMCweb with invalid token.
59    [Tags]  Redfish_Login_Using_Invalid_Token
60
61    Create Session  openbmc  ${AUTH_URI}
62
63    # Example: "X-Auth-Token: 3la1JUf1vY4yN2dNOwun"
64    ${headers}=  Create Dictionary  Content-Type=application/json
65    ...  X-Auth-Token=deadbeef
66
67    ${resp}=  GET On Session
68    ...  openbmc  /redfish/v1/SessionService/Sessions  headers=${headers}
69    ...  expected_status=${HTTP_UNAUTHORIZED}
70
71    Should Be Equal As Strings  ${resp.status_code}  ${HTTP_UNAUTHORIZED}
72
73
74Verify Redfish Invalid URL Response Code
75    [Documentation]  Login to BMCweb and verify error response code.
76    [Tags]  Verify_Redfish_Invalid_URL_Response_Code
77
78    Redfish.Login
79    Redfish.Get  /redfish/v1/idontexist  valid_status_codes=[${HTTP_NOT_FOUND}]
80    Redfish.Logout
81
82
83Delete Redfish Session Using Valid Login
84    [Documentation]  Delete a session using valid login.
85    [Tags]  Delete_Redfish_Session_Using_Valid_Login
86
87    Redfish.Login
88    ${session_info}=  Get Redfish Session Info
89
90    Redfish.Login
91
92    # Example o/p:
93    # [{'@odata.id': '/redfish/v1/SessionService/Sessions/bOol3WlCI8'},
94    #  {'@odata.id': '/redfish/v1/SessionService/Sessions/Yu3xFqjZr1'}]
95    ${resp_list}=  Redfish_Utils.List Request
96    ...  /redfish/v1/SessionService/Sessions
97
98    Redfish.Delete  ${session_info["location"]}
99
100    ${resp}=  Redfish_Utils.List Request  /redfish/v1/SessionService/Sessions
101    List Should Not Contain Value  ${resp}  ${session_info["location"]}
102
103
104Redfish Login Via SessionService
105    [Documentation]  Login to BMC via redfish session service.
106    [Tags]   Redfish_Login_Via_SessionService
107
108    Create Session  openbmc  https://${OPENBMC_HOST}
109    ${headers}=  Create Dictionary  Content-Type=application/json
110    ${data}=  Set Variable  {"UserName":"${OPENBMC_USERNAME}", "Password":"${OPENBMC_PASSWORD}"}
111
112    ${resp}=  POST On Session  openbmc  /redfish/v1/SessionService/Sessions  data=${data}  headers=${headers}
113    Should Be Equal As Strings  ${resp.status_code}  ${HTTP_CREATED}
114
115    ${headers}=  Create Dictionary   Content-Type=application/json
116    ...  X-Auth-Token=${resp.headers["X-Auth-Token"]}
117    ${resp}=  DELETE On Session  openbmc  ${REDFISH_SESSION}${/}${resp.json()["Id"]}  headers=${headers}
118    Should Be Equal As Strings  ${resp.status_code}  ${HTTP_OK}
119
120
121Verify Redfish Unresponsive URL paths
122    [Documentation]  Verify that all URLs in /redfish/v1 respond.
123    [Tags]   Verify_Redfish_Unresponsive_URL_paths
124
125    Redfish.Login
126    ${resource_list}  ${dead_resources}=  Enumerate Request  /redfish/v1  include_dead_resources=True
127    Redfish.Logout
128    Valid Length  dead_resources  max_length=0
129
130
131*** Keywords ***
132
133GET And Verify Redfish Response
134    [Documentation]  GET given resource and verfiy response.
135    [Arguments]  ${valid_status_codes}  ${resource_path}
136
137    # Description of argument(s):
138    # valid_status_codes            A comma-separated list of acceptable
139    #                               status codes (e.g. 200).
140    # resource_path                 Redfish resource URL path.
141
142    ${resp}=  Redfish.Get  ${resource_path}
143    ...  valid_status_codes=[${valid_status_codes}]
144