1*** Settings ***
2
3Documentation       Test BMC dump functionality of OpenBMC.
4
5Resource            ../../lib/bmc_redfish_resource.robot
6Resource            ../../lib/boot_utils.robot
7Resource            ../../lib/dump_utils.robot
8Resource            ../../lib/openbmc_ffdc.robot
9
10Suite Setup         Redfish.Login
11Test Setup          Redfish Delete All BMC Dumps
12Test Teardown       Test Teardown Execution
13
14*** Variables ***
15
16# Total size of the dump in kilo bytes
17${BMC_DUMP_TOTAL_SIZE}       ${1024}
18
19# Minimum space required for one bmc dump in kilo bytes
20${BMC_DUMP_MIN_SPACE_REQD}   ${20}
21${MAX_DUMP_COUNT}            ${20}
22
23*** Test Cases ***
24
25Verify Error Response For Already Deleted Dump Id
26    [Documentation]  Delete non existing BMC dump and expect an error.
27    [Tags]  Verify_Error_Response_For_Already_Deleted_Dump_Id
28
29    ${dump_id}=  Create User Initiated BMC Dump Via Redfish
30    Redfish Delete BMC Dump  ${dump_id}
31    Run Keyword And Expect Error  ValueError: *  Redfish Delete BMC Dump  ${dump_id}
32
33
34Verify User Initiated BMC Dump When Host Powered Off
35    [Documentation]  Create user initiated BMC dump at host off state and
36    ...  verify dump entry for it.
37    [Tags]  Verify_User_Initiated_BMC_Dump_When_Host_Powered_Off
38
39    Redfish Power Off  stack_mode=skip
40    ${dump_id}=  Create User Initiated BMC Dump Via Redfish
41    ${dump_entries}=  Get BMC Dump Entries
42    Length Should Be  ${dump_entries}  1
43    List Should Contain Value  ${dump_entries}  ${dump_id}
44
45
46Verify User Initiated BMC Dump Size
47    [Documentation]  Verify user initiated BMC dump size is under 20 MB.
48    [Tags]  Verify_User_Initiated_BMC_Dump_Size
49
50    ${dump_id}=  Create User Initiated BMC Dump Via Redfish
51    ${resp}=  Redfish.Get Properties  /redfish/v1/Managers/bmc/LogServices/Dump/Entries/${dump_id}
52
53    # Example of response from above Redfish GET request.
54    # "@odata.type": "#LogEntry.v1_7_0.LogEntry",
55    # "AdditionalDataSizeBytes": 31644,
56    # "AdditionalDataURI": "/redfish/v1/Managers/bmc/LogServices/Dump/attachment/9",
57    # "Created": "2020-10-23T06:32:53+00:00",
58    # "DiagnosticDataType": "Manager",
59    # "EntryType": "Event",
60    # "Id": "9",
61    # "Name": "BMC Dump Entry"
62
63    # Max size for dump is 20 MB = 20x1024x1024 Byte.
64    Should Be True  0 < ${resp["AdditionalDataSizeBytes"]} < 20971520
65
66
67Verify User Initiated BMC Dump When Host Booted
68    [Documentation]  Create user initiated BMC dump at host booted state and
69    ...  verify dump entry for it.
70    [Tags]  Verify_User_Initiated_BMC_Dump_When_Host_Booted
71
72    Redfish Power On  stack_mode=skip
73    ${dump_id}=  Create User Initiated BMC Dump Via Redfish
74    ${dump_entries}=  Get BMC Dump Entries
75    Length Should Be  ${dump_entries}  1
76    List Should Contain Value  ${dump_entries}  ${dump_id}
77
78
79Verify Dump Persistency On Dump Service Restart
80    [Documentation]  Create user dump, restart dump manager service and verify dump
81    ...  persistency.
82    [Tags]  Verify_Dump_Persistency_On_Dump_Service_Restart
83
84    Create User Initiated BMC Dump Via Redfish
85    ${dump_entries_before}=  redfish_utils.get_member_list  /redfish/v1/Managers/bmc/LogServices/Dump/Entries
86
87    # Restart dump service.
88    BMC Execute Command  systemctl restart xyz.openbmc_project.Dump.Manager.service
89    Sleep  10s  reason=Wait for BMC dump service to restart properly
90
91    ${dump_entries_after}=  redfish_utils.get_member_list  /redfish/v1/Managers/bmc/LogServices/Dump/Entries
92    Lists Should Be Equal  ${dump_entries_before}  ${dump_entries_after}
93
94
95Verify Dump Persistency On BMC Reset
96    [Documentation]  Create user dump, reset BMC and verify dump persistency.
97    [Tags]  Verify_Dump_Persistency_On_BMC_Reset
98
99    # Power off host so that dump is not offloaded to host OS.
100    Redfish Power Off  stack_mode=skip
101
102    Create User Initiated BMC Dump Via Redfish
103    ${dump_entries_before}=  redfish_utils.get_member_list  /redfish/v1/Managers/bmc/LogServices/Dump/Entries
104
105    # Reset BMC.
106    OBMC Reboot (off)  stack_mode=skip
107
108    ${dump_entries_after}=  redfish_utils.get_member_list  /redfish/v1/Managers/bmc/LogServices/Dump/Entries
109    Lists Should Be Equal  ${dump_entries_before}  ${dump_entries_after}
110
111
112Delete User Initiated BMC Dump And Verify
113    [Documentation]  Delete user initiated BMC dump and verify.
114    [Tags]  Delete_User_Initiated_BMC_Dump_And_Verify
115
116    ${dump_id}=  Create User Initiated BMC Dump Via Redfish
117    Redfish Delete BMC Dump  ${dump_id}
118
119    ${dump_entries}=  Get BMC Dump Entries
120    Should Be Empty  ${dump_entries}
121
122
123Delete All User Initiated BMC Dumps And Verify
124    [Documentation]  Delete all user initiated BMC dumps and verify.
125    [Tags]  Delete_All_User_Initiated_BMC_Dumps_And_Verify
126
127    # Power off host so that dump is not offloaded to host OS.
128    Redfish Power Off  stack_mode=skip
129
130    # Create some BMC dump.
131    Create User Initiated BMC Dump Via Redfish
132    Create User Initiated BMC Dump Via Redfish
133
134    Redfish Delete All BMC Dumps
135    ${dump_entries}=  Get BMC Dump Entries
136    Should Be Empty  ${dump_entries}
137
138
139Create Two User Initiated BMC Dumps
140    [Documentation]  Create two user initiated BMC dumps.
141    [Tags]  Create_Two_User_Initiated_BMC_Dumps
142
143    ${dump_id1}=  Create User Initiated BMC Dump Via Redfish
144    ${dump_id2}=  Create User Initiated BMC Dump Via Redfish
145
146    ${dump_entries}=  Get BMC Dump Entries
147    Length Should Be  ${dump_entries}  2
148    Should Contain  ${dump_entries}  ${dump_id1}
149    Should Contain  ${dump_entries}  ${dump_id2}
150
151
152Create Two User Initiated BMC Dumps And Delete One
153    [Documentation]  Create two dumps and delete the first.
154    [Tags]  Create_Two_User_Initiated_BMC_Dumps_And_Delete_One
155
156    ${dump_id1}=  Create User Initiated BMC Dump Via Redfish
157    ${dump_id2}=  Create User Initiated BMC Dump Via Redfish
158
159    Redfish Delete BMC Dump  ${dump_id1}
160
161    ${dump_entries}=  Get BMC Dump Entries
162    Length Should Be  ${dump_entries}  1
163    List Should Contain Value  ${dump_entries}  ${dump_id2}
164
165
166Create And Delete User Initiated BMC Dump Multiple Times
167    [Documentation]  Create and delete user initiated BMC dump multiple times.
168    [Tags]  Create_And_Delete_User_Initiated_BMC_Dump_Multiple_Times
169
170    FOR  ${INDEX}  IN  1  10
171      ${dump_id}=  Create User Initiated BMC Dump Via Redfish
172      Redfish Delete BMC Dump  ${dump_id}
173    END
174
175
176Verify Maximum BMC Dump Creation
177    [Documentation]  Create maximum BMC dump and verify error when dump runs out of space.
178    [Tags]  Verify_Maximum_BMC_Dump_Creation
179    [Teardown]  Redfish Delete All BMC Dumps
180
181    # Maximum allowed space for dump is 1024 KB. BMC typically hold 8-14 dumps
182    # before running out of this dump space. So trying to create dumps in 20
183    # iterations to run out of space.
184    # User can key in the Maximum allowed space for bmc dump and how many iteration.
185    FOR  ${n}  IN RANGE  0  ${MAX_DUMP_COUNT}
186      Create User Initiated BMC Dump Via Redfish
187      ${dump_space}=  Get Disk Usage For Dumps
188      Exit For Loop If  ${dump_space} >= (${BMC_DUMP_TOTAL_SIZE} - ${BMC_DUMP_MIN_SPACE_REQD})
189    END
190
191    # Check error while creating dump when dump size is full.
192    ${payload}=  Create Dictionary  DiagnosticDataType=Manager
193    Redfish.Post  /redfish/v1/Managers/bmc/LogServices/Dump/Actions/LogService.CollectDiagnosticData
194    ...  body=${payload}  valid_status_codes=[${HTTP_INTERNAL_SERVER_ERROR}]
195
196
197*** Keywords ***
198
199Get BMC Dump Entries
200    [Documentation]  Return BMC dump ids list.
201
202    ${dump_uris}=  redfish_utils.get_member_list  /redfish/v1/Managers/bmc/LogServices/Dump/Entries
203    ${dump_ids}=  Create List
204
205    FOR  ${dump_uri}  IN  @{dump_uris}
206      ${dump_id}=  Fetch From Right  ${dump_uri}  /
207      Append To List  ${dump_ids}  ${dump_id}
208    END
209
210    [Return]  ${dump_ids}
211
212
213Get Disk Usage For Dumps
214    [Documentation]  Return disk usage in kilobyte for BMC dumps.
215
216    ${usage_output}  ${stderr}  ${rc}=  BMC Execute Command  du -s /var/lib/phosphor-debug-collector/dumps
217
218    # Example of output from above BMC cli command.
219    # $ du -s /var/lib/phosphor-debug-collector/dumps
220    # 516    /var/lib/phosphor-debug-collector/dumps
221
222    ${usage_output}=  Fetch From Left  ${usage_output}  /
223    ${usage_output}=  Convert To Integer  ${usage_output}
224
225    [return]  ${usage_output}
226
227
228Test Teardown Execution
229    [Documentation]  Do test teardown operation.
230
231    FFDC On Test Case Fail
232    Close All Connections
233