1*** Settings ***
2Documentation            Update the BMC code on a target BMC via Redifsh.
3
4# Test Parameters:
5# IMAGE_FILE_PATH        The path to the BMC image file.
6#
7# Firmware update states:
8#     Enabled            Image is installed and either functional or active.
9#     Disabled           Image installation failed or ready for activation.
10#     Updating           Image installation currently in progress.
11
12Resource                 ../../lib/resource.robot
13Resource                 ../../lib/bmc_redfish_resource.robot
14Resource                 ../../lib/openbmc_ffdc.robot
15Resource                 ../../lib/common_utils.robot
16Resource                 ../../lib/code_update_utils.robot
17Resource                 ../../lib/redfish_code_update_utils.robot
18Resource                 ../../lib/utils.robot
19Library                  ../../lib/gen_robot_valid.py
20Library                  ../../lib/var_funcs.py
21Library                  ../../lib/gen_robot_keyword.py
22Library                  ../../lib/code_update_utils.py
23
24Suite Setup              Suite Setup Execution
25Suite Teardown           Redfish.Logout
26Test Setup               Printn
27Test Teardown            FFDC On Test Case Fail
28
29# Force the test to timedout to prevent test hanging.
30Test Timeout             45 minutes
31
32Force Tags               Bmc_Code_Update
33
34*** Variables ***
35
36${FORCE_UPDATE}             ${0}
37${LOOP_COUNT}               ${2}
38${DELETE_ERRLOGS}           ${1}
39# Refer: https://github.com/open-power/guard
40${DELETE_OLD_GUARD_FILE}    ${0}
41
42${ACTIVATION_WAIT_TIMEOUT}     8 min
43
44# New code update path.
45${REDFISH_UPDATE_URI}    /redfish/v1/UpdateService/update
46
47*** Test Cases ***
48
49Redfish BMC Code Update
50    [Documentation]  Update the firmware image.
51    [Tags]  Redfish_BMC_Code_Update
52
53    # Python module:  get_version_tar(tar_file_path)
54    ${image_version}=  code_update_utils.Get Version Tar  ${IMAGE_FILE_PATH}
55    Rprint Vars  image_version
56
57    # Python module: get_bmc_release_info()
58    ${bmc_release_info}=  utils.Get BMC Release Info
59    ${functional_version}=  Set Variable  ${bmc_release_info['version_id']}
60    Rprint Vars  functional_version
61
62    ${post_code_update_actions}=  Get Post Boot Action
63    ${state}=  Get Pre Reboot State
64    Rprint Vars  state
65
66    # Check if the existing firmware is functional.
67    Pass Execution If  '${functional_version}' == '${image_version}'
68    ...  The existing ${image_version} firmware is already functional.
69
70    ${sw_inv}=  Get Functional Firmware  BMC image
71    ${nonfunctional_sw_inv}=  Get Non Functional Firmware  ${sw_inv}  False
72
73    # Redfish active software image API.
74    Run Keyword If  ${num_records} > 0
75    ...  Run Keyword If  '${nonfunctional_sw_inv['version']}' == '${image_version}'
76    ...  Set Backup Firmware To Functional  ${image_version}  ${state}
77
78    Print Timen  Performing firmware update ${image_version}.
79
80    Redfish Update Firmware
81
82
83Redfish BMC Code Update Running And Backup Image With Same Firmware
84    [Documentation]  Perform the firmware update with same image back to back, so that
85    ...              the running (functional Image) and backup image (alternate image)
86    ...              with same firmware.
87    [Tags]  Redfish_BMC_Code_Update_Running_And_Backup_Image_With_Same_Firmware
88
89    # Python module:  get_version_tar(tar_file_path)
90    ${image_version}=  code_update_utils.Get Version Tar  ${IMAGE_FILE_PATH}
91    Rprint Vars  image_version
92
93    # Python module: get_bmc_release_info()
94    ${bmc_release_info}=  utils.Get BMC Release Info
95    ${functional_version}=  Set Variable  ${bmc_release_info['version_id']}
96    Rprint Vars  functional_version
97
98    # First update.
99    Print Timen  Performing firmware update ${image_version}.
100    Redfish Update Firmware
101
102    # Second update.
103    Print Timen  Performing firmware update ${image_version}.
104    Redfish Update Firmware
105
106
107Redfish Firmware Update Loop
108    [Documentation]  Update the same firmware image in loop.
109    [Tags]  Redfish_Firmware_Update_Loop
110    [Template]  Redfish Firmware Update In Loop
111    [Timeout]    NONE
112    # Override default 30 minutes, Disabling timeout with NONE explicitly
113    # else this test will fail for longer loop runs.
114
115    ${LOOP_COUNT}
116
117
118*** Keywords ***
119
120Suite Setup Execution
121    [Documentation]  Do the suite setup.
122
123    Redfish.Login
124    # Delete BMC dump and Error logs.
125    Run Keyword And Ignore Error  Redfish Delete All BMC Dumps
126    Run Keyword If  ${DELETE_ERRLOGS} == ${1}
127    ...   Run Keyword And Ignore Error  Redfish Purge Event Log
128    # To invalidate all the guard records.
129    Run Keyword If  '${DELETE_OLD_GUARD_FILE}' == '${1}'
130    ...  BMC Execute Command  guard -I
131
132    # Checking for file existence.
133    Valid File Path  IMAGE_FILE_PATH
134
135    # Check and set the update path.
136    # Old - /redfish/v1/UpdateService/
137    # New - /redfish/v1/UpdateService/update
138    ${resp}=  Redfish.Get  /redfish/v1/UpdateService/update
139    ...  valid_status_codes=[${HTTP_OK},${HTTP_NOT_FOUND},${HTTP_METHOD_NOT_ALLOWED}]
140
141    # If the method is not found, set update URI to old method.
142    Run Keyword If  ${resp.status} == ${HTTP_NOT_FOUND}
143    ...  Set Suite Variable  ${REDFISH_UPDATE_URI}  /redfish/v1/UpdateService
144
145    Log To Console  Update URI: ${REDFISH_UPDATE_URI}
146
147    Redfish Power Off  stack_mode=skip
148
149
150Redfish Firmware Update In Loop
151    [Documentation]  Update the firmware in loop.
152    [Arguments]  ${update_loop_count}
153
154    # Description of argument(s):
155    # update_loop_count    This value is used to run the firmware update in loop.
156
157    # Python module:  get_version_tar(tar_file_path)
158    ${image_version}=  code_update_utils.Get Version Tar  ${IMAGE_FILE_PATH}
159    Rprint Vars  image_version
160
161    # Python module: get_bmc_release_info()
162    ${bmc_release_info}=  utils.Get BMC Release Info
163    ${functional_version}=  Set Variable  ${bmc_release_info['version_id']}
164    Print Timen  Starting firmware information:
165    Rprint Vars  functional_version
166
167    ${temp_update_loop_count}=  Evaluate  ${update_loop_count} + 1
168
169    FOR  ${count}  IN RANGE  1  ${temp_update_loop_count}
170       Print Timen  **************************************
171       Print Timen  * The Current Loop Count is ${count} of ${update_loop_count} *
172       Print Timen  **************************************
173       Print Timen  Performing firmware update ${image_version}.
174       Redfish Update Firmware
175    END
176
177
178Delete BMC Image
179    [Documentation]  Delete a BMC image from the BMC flash chip.
180
181    ${software_object}=  Get Non Running BMC Software Object
182    Delete Image And Verify  ${software_object}  ${VERSION_PURPOSE_BMC}
183
184
185Activate Existing Firmware
186    [Documentation]  Set firmware image to lower priority.
187    [Arguments]  ${image_version}
188
189    # Description of argument(s):
190    # image_version     Version of image.
191
192    ${software_inventory_record}=  Get Software Inventory State By Version
193    ...  ${image_version}
194    ${num_keys}=  Get Length  ${software_inventory_record}
195
196    Rprint Vars  software_inventory_record
197
198    # If no software inventory record was found, there is no existing
199    # firmware for the given version and therefore no action to be taken.
200    Return From Keyword If  not ${num_keys}
201
202    # Check if the existing firmware is functional.
203    Pass Execution If  ${software_inventory_record['functional']}
204    ...  The existing ${image_version} firmware is already functional.
205
206    # If existing firmware is not functional, then set the priority to least.
207    Print Timen  The existing ${image_version} firmware is not yet functional.
208    Set BMC Image Priority To Least  ${image_version}  ${software_inventory_record}
209
210    Pass Execution  The existing ${image_version} firmware is now functional.
211
212
213Get Image Priority
214    [Documentation]  Get Current Image Priority.
215    [Arguments]  ${image_version}
216
217    # Description of argument(s):
218    # image_version       The Firmware image version (e.g. 2.8.0-dev-1107-g512028d95).
219
220    ${software_info}=  Read Properties
221    ...  ${SOFTWARE_VERSION_URI}/enumerate  quiet=1
222    # Get only the record associated with our image_version.
223
224    ${software_info}=  Filter Struct
225    ...  ${software_info}  [('Version', '${image_version}')]
226    # Convert from dict to list.
227    ${software_info}=  Get Dictionary Values  ${software_info}
228
229    [Return]  ${software_info[0]['Priority']}
230
231
232Set BMC Image Priority To Least
233    [Documentation]  Set BMC image priority to least value.
234    [Arguments]  ${image_version}  ${software_inventory}
235
236    # Description of argument(s):
237    # image_version       The Firmware image version (e.g. 2.8.0-dev-1107-g512028d95).
238    # software_inventory  Software inventory details.
239
240    ${least_priority}=  Get Least Value Priority Image  ${VERSION_PURPOSE_BMC}
241    ${cur_priority}=  Get Image Priority  ${image_version}
242    Rprint Vars  least_priority  cur_priority
243
244    Return From Keyword If  '${least_priority}' == ${cur_priority}
245    Set Host Software Property
246    ...  ${SOFTWARE_VERSION_URI}${software_inventory['image_id']}
247    ...  Priority  ${least_priority}
248
249    Redfish OBMC Reboot (off)
250
251
252Set Backup Firmware To Functional
253    [Documentation]  Set the backup firmware to functional.
254    [Arguments]  ${image_version}  ${state}
255
256    # Description of argument(s):
257    # image_version     Version of image.
258    # state             Pre reboot state.
259
260    Print Timen  Switch to back up and rebooting.
261    Switch Backup Firmware Image To Functional
262    Wait For Reboot  start_boot_seconds=${state['epoch_seconds']}
263    Redfish Verify BMC Version  ${IMAGE_FILE_PATH}
264    Pass Execution  The backup firmware image ${image_version} is now functional.
265
266
267Redfish Update Firmware
268    [Documentation]  Update the BMC firmware via redfish interface.
269
270    ${post_code_update_actions}=  Get Post Boot Action
271    ${state}=  Get Pre Reboot State
272    Rprint Vars  state
273    Run Keyword And Ignore Error  Set ApplyTime  policy=OnReset
274
275    # Python module:  get_member_list(resource_path)
276    ${before_inv_list}=  redfish_utils.Get Member List  /redfish/v1/UpdateService/FirmwareInventory
277    Log To Console   Current images on the BMC before upload: ${before_inv_list}
278
279    Print Timen  Start uploading image to BMC.
280    Redfish Upload Image  ${REDFISH_UPDATE_URI}  ${IMAGE_FILE_PATH}
281    Print Timen  Completed image upload to BMC.
282
283    # Python module:  get_member_list(resource_path)
284    ${after_inv_list}=  redfish_utils.Get Member List  /redfish/v1/UpdateService/FirmwareInventory
285    Log To Console  Current images on the BMC after upload: ${after_inv_list}
286
287    ${image_id}=  Evaluate  set(${after_inv_list}) - set(${before_inv_list})
288    Should Not Be Empty    ${image_id}
289    ${image_id}=  Evaluate  list(${image_id})[0].split('/')[-1]
290    Log To Console  Firmware installation in progress with image id:: ${image_id}
291
292    Wait Until Keyword Succeeds  ${ACTIVATION_WAIT_TIMEOUT}  10 sec
293    ...  Check Image Update Progress State  match_state='Enabled'  image_id=${image_id}
294
295    # Python module:  get_version_tar(tar_file_path)
296    ${tar_version}=  code_update_utils.Get Version Tar  ${IMAGE_FILE_PATH}
297    ${image_info}=  Get Software Inventory State By Version  ${tar_version}
298
299    Run Key  ${post_code_update_actions['${image_info["image_type"]}']['OnReset']}
300    Redfish.Login
301    Redfish Verify BMC Version  ${IMAGE_FILE_PATH}
302
303