xref: /openbmc/openbmc-test-automation/redfish/dmtf_tools/Redfish_Usecase_Checkers.robot (revision 44421de6af40b3e57ee59a89e44a53205b42a158) 
1*** Settings ***
2Documentation             Test BMC using https://github.com/DMTF/Redfish-Usecase-Checkers
3...                       DMTF tool.
4
5Resource                  ../../lib/resource.robot
6Resource                  ../../lib/dmtf_tools_utils.robot
7Resource                  ../../lib/openbmc_ffdc.robot
8Library                   OperatingSystem
9Library                   ../../lib/state.py
10
11Test Setup                Test Setup Execution
12Test Teardown             Test Teardown Execution
13
14Test Tags                 Redfish_Usecase_Checkers
15
16*** Variables ***
17
18${DEFAULT_PYTHON}         python3
19
20${rsv_github_url}         https://github.com/DMTF/Redfish-Usecase-Checkers.git
21${rsv_dir_path}           Redfish-Usecase-Checkers
22
23${command_account}        ${DEFAULT_PYTHON} ${rsv_dir_path}${/}rf_use_case_checkers.py
24...                       -r https://${OPENBMC_HOST} -u ${OPENBMC_USERNAME}
25...                       -p ${OPENBMC_PASSWORD} --test-list AccountManagement
26
27${command_power_control}  ${DEFAULT_PYTHON} ${rsv_dir_path}${/}rf_use_case_checkers.py
28...                       -r https://${OPENBMC_HOST} -u ${OPENBMC_USERNAME}
29...                       -p ${OPENBMC_PASSWORD} --test-list PowerControl
30
31${power_on_timeout}       15 mins
32${power_off_timeout}      15 mins
33${state_change_timeout}   3 mins
34${branch_name}            main
35
36*** Test Cases ***
37
38Test BMC Redfish Account Management
39    [Documentation]  Check Account Management with a Redfish interface.
40    [Tags]  Test_BMC_Redfish_Account_Management
41
42    ${rc}  ${output}=  Run DMTF Tool  ${rsv_dir_path}  ${command_account}  check_error=1
43
44    Should Be Equal        ${rc}  ${0}
45    Should Match Regexp    ${output}  Summary - PASS: \\d+, WARN: \\d+, FAIL: 0, NOT TESTED: \\d+
46
47
48Test BMC Redfish Power Control Usecase
49    [Documentation]  Power Control Usecase Test.
50    [Tags]  Test_BMC_Redfish_Power_Control_Usecase
51
52    DMTF Power
53
54
55*** Keywords ***
56
57Test Setup Execution
58    [Documentation]  Do test case setup tasks.
59
60    Printn
61    Download DMTF Tool  ${rsv_dir_path}  ${rsv_github_url}  ${branch_name}
62
63
64Test Teardown Execution
65    [Documentation]  Do the post-test teardown.
66
67    Printn
68    FFDC On Test Case Fail
69
70
71DMTF Power
72    [Documentation]  Power the BMC machine on via DMTF tools.
73
74    ${rc}  ${output}=  Run DMTF Tool  ${rsv_dir_path}  ${command_power_control}  check_error=1
75    Log  ${rc}
76    Log  ${output}
77
78    Should Be Equal        ${rc}  ${0}
79    Should Match Regexp    ${output}    Summary - PASS: \\d+, WARN: \\d+, FAIL: 0, NOT TESTED: \\d+
80