1*** Settings ***
2Documentation  This module provides general keywords for dump.
3
4Library         bmc_ssh_utils.py
5
6*** Variables ***
7
8*** Keywords ***
9
10Create User Initiated Dump
11    [Documentation]  Generate user initiated dump and return
12    ...  the dump id number (e.g., "5").  Optionally return EMPTY
13    ...  if out of dump space.
14    [Arguments]   ${check_out_of_space}=${False}
15
16    # Description of Argument(s):
17    # check_out_of_space   If ${False}, a dump will be created and
18    #                      its dump_id will be returned.
19    #                      If ${True}, either the dump_id will be
20    #                      returned, or the value ${EMPTY} will be
21    #                      returned if out of dump space was
22    #                      detected when creating the dump.
23
24    ${resp}=  OpenBMC Get Request  ${DUMP_URI}
25    Run Keyword If  '${resp.status_code}' == '${HTTP_NOT_FOUND}'
26    ...  Set Global Variable  ${DUMP_URI}  /xyz/openbmc_project/dump/
27
28    ${data}=  Create Dictionary  data=@{EMPTY}
29    ${resp}=  OpenBMC Post Request
30    ...  ${DUMP_URI}action/CreateDump  data=${data}  quiet=${1}
31
32    Run Keyword If  '${check_out_of_space}' == '${False}'
33    ...      Run Keyword And Return  Get The Dump Id  ${resp}
34    ...  ELSE
35    ...      Run Keyword And Return  Check For Too Many Dumps  ${resp}
36
37
38Get The Dump Id
39    [Documentation]  Wait for the dump to be created. Return the
40    ...  dump id number (e.g., "5").
41    [Arguments]  ${resp}
42
43    # Description of Argument(s):
44    # resp   Response object from action/Create Dump attempt.
45    #        Example object:
46    #        {
47    #           "data": 5,
48    #           "message": "200 OK",
49    #           "status": "ok"
50    #        },
51    #        The "data" field conveys the id number of the created dump.
52
53    Should Be Equal As Strings  ${resp.status_code}  ${HTTP_OK}
54    ${json}=  To JSON  ${resp.content}
55
56    Run Keyword If  ${json["data"]} == ${None}
57    ...  Fail  Dump id returned null.
58
59    ${dump_id}=  Set Variable  ${json["data"]}
60
61    Wait Until Keyword Succeeds  3 min  15 sec  Check Dump Existence
62    ...  ${dump_id}
63
64    [Return]  ${dump_id}
65
66
67Check For Too Many Dumps
68    [Documentation]  Return the dump_id number, or return ${EMPTY} if dump
69    ...  creation failed due to too many dumps.
70    [Arguments]  ${resp}
71
72    # Description of Argument(s):
73    # resp   Response object from action/Create Dump attempt.
74    #        Example object if there are too many dumps:
75    #       {
76    #           "data": {
77    #               "description": "xyz.openbmc_project.Dump.Create.Error.QuotaExceeded"
78    #           },
79    #           "message": "Dump not captured due to a cap.",
80    #           "status": "error"
81    #       }
82
83    # If dump was created normally, return the dump_id number.
84    Run Keyword If  '${resp.status_code}' == '${HTTP_OK}'
85    ...  Run Keyword And Return  Get The Dump Id  ${resp}
86
87    ${json}=  To JSON   ${resp.content}
88    ${exception}=  Set Variable  ${json["message"]}
89    ${at_capacity}=  Set Variable  Dump not captured due to a cap
90    ${too_many_dumps}=  Evaluate  $at_capacity in $exception
91    Printn
92    Rprint Vars   exception  too_many_dumps
93    # If there are too many dumps, return ${EMPTY}, otherwise Fail.
94    ${status}=  Run Keyword If  ${too_many_dumps}  Set Variable  ${EMPTY}
95    ...  ELSE  Fail  msg=${exception}.
96
97    [Return]  ${status}
98
99
100Verify No Dump In Progress
101    [Documentation]  Verify no dump in progress.
102
103    ${dump_progress}  ${stderr}  ${rc}=  BMC Execute Command  ls /tmp
104    Should Not Contain  ${dump_progress}  obmcdump
105
106
107Check Dump Existence
108    [Documentation]  Verify if given dump exist.
109    [Arguments]  ${dump_id}
110
111    # Description of Argument(s):
112    # dump_id  An integer value that identifies a particular dump
113    #          object(e.g. 1, 3, 5).
114
115    ${resp}=  OpenBMC Get Request  ${DUMP_URI}
116    Run Keyword If  '${resp.status_code}' == '${HTTP_NOT_FOUND}'
117    ...  Set Global Variable  ${DUMP_ENTRY_URI}  /xyz/openbmc_project/dump/entry/
118
119    ${resp}=  OpenBMC Get Request  ${DUMP_ENTRY_URI}${dump_id}
120    Should Be Equal As Strings  ${resp.status_code}  ${HTTP_OK}
121
122
123Delete BMC Dump
124    [Documentation]  Deletes a given bmc dump.
125    [Arguments]  ${dump_id}
126
127    # Description of Argument(s):
128    # dump_id  An integer value that identifies a particular dump (e.g. 1, 3).
129
130    ${resp}=  OpenBMC Get Request  ${DUMP_URI}
131    Run Keyword If  '${resp.status_code}' == '${HTTP_NOT_FOUND}'
132    ...  Set Global Variable  ${DUMP_ENTRY_URI}  /xyz/openbmc_project/dump/entry/
133
134    ${data}=  Create Dictionary  data=@{EMPTY}
135    ${resp}=  OpenBMC Post Request
136    ...  ${DUMP_ENTRY_URI}${dump_id}/action/Delete  data=${data}
137
138    Should Be Equal As Strings  ${resp.status_code}  ${HTTP_OK}
139
140Delete All Dumps
141    [Documentation]  Delete all dumps.
142
143    ${resp}=  OpenBMC Get Request  ${DUMP_URI}
144    Run Keyword If  '${resp.status_code}' == '${HTTP_NOT_FOUND}'
145    ...  Set Global Variable  ${DUMP_ENTRY_URI}  /xyz/openbmc_project/dump/entry/
146
147    # Check if dump entries exist, if not return.
148    ${resp}=  OpenBMC Get Request  ${DUMP_ENTRY_URI}list  quiet=${1}
149    Return From Keyword If  ${resp.status_code} == ${HTTP_NOT_FOUND}
150
151    # Get the list of dump entries and delete them all.
152    ${dump_entries}=  Get URL List  ${DUMP_ENTRY_URI}
153    FOR  ${entry}  IN  @{dump_entries}
154        ${dump_id}=  Fetch From Right  ${entry}  /
155        Delete BMC Dump  ${dump_id}
156    END
157
158
159Redfish Delete BMC Dump
160    [Documentation]  Deletes a given BMC dump via Redfish..
161    [Arguments]  ${dump_id}
162
163    # Description of Argument(s):
164    # dump_id  An integer value that identifies a particular dump (e.g. 1, 3).
165
166    Redfish.Delete  /redfish/v1/Managers/bmc/LogServices/Dump/Entries/${dump_id}
167
168
169Redfish Delete All BMC Dumps
170    [Documentation]  Delete all BMC dumps via Redfish.
171
172    # Check if dump entries exist, if not return.
173    ${resp}=  Redfish.Get  /redfish/v1/Managers/bmc/LogServices/Dump/Entries
174    Return From Keyword If  ${resp.dict["Members@odata.count"]} == ${0}
175
176    Redfish.Post  /redfish/v1/Managers/bmc/LogServices/Dump/Actions/LogService.ClearLog
177
178
179Delete All BMC Dump
180    [Documentation]  Delete all BMC dump entries using "DeleteAll" interface.
181
182    ${resp}=  OpenBMC Get Request  ${DUMP_URI}
183    Run Keyword If  '${resp.status_code}' == '${HTTP_NOT_FOUND}'
184    ...  Set Global Variable  ${DUMP_URI}  /xyz/openbmc_project/dump/
185
186    ${data}=  Create Dictionary  data=@{EMPTY}
187    ${resp}=  Openbmc Post Request  ${DUMP_URI}action/DeleteAll  data=${data}
188    Should Be Equal As Strings  ${resp.status_code}  ${HTTP_OK}
189
190Dump Should Not Exist
191    [Documentation]  Verify that BMC dumps do not exist.
192
193    ${resp}=  OpenBMC Get Request  ${DUMP_URI}
194    Run Keyword If  '${resp.status_code}' == '${HTTP_NOT_FOUND}'
195    ...  Set Global Variable  ${DUMP_ENTRY_URI}  /xyz/openbmc_project/dump/entry/
196
197    ${resp}=  OpenBMC Get Request  ${DUMP_ENTRY_URI}list  quiet=${1}
198    Should Be Equal As Strings  ${resp.status_code}  ${HTTP_NOT_FOUND}
199
200Check Existence Of BMC Dump File
201    [Documentation]  Verify existence of BMC dump file.
202    [Arguments]  ${dump_id}
203
204    # Description of argument(s):
205    # dump_id  BMC dump identifier
206
207    ${dump_check_cmd}=  Set Variable
208    ...  ls /var/lib/phosphor-debug-collector/dumps
209
210    # Output of sample BMC Execute command with '2' as dump id is as follows
211    # ls /var/lib/phosphor-debug-collector/dumps/2
212    # obmcdump_2_XXXXXXXXXX.tar.xz
213    ${file_there}  ${stderr}  ${rc}=  BMC Execute Command
214    ...  ${dump_check_cmd}/${dump_id}
215    Should End With  ${file_there}  tar.xz  msg=BMC dump file not found.
216
217Get Dump Entries
218    [Documentation]  Return dump entries list.
219
220    ${resp}=  OpenBMC Get Request  ${DUMP_URI}
221    Run Keyword If  '${resp.status_code}' == '${HTTP_NOT_FOUND}'
222    ...  Set Global Variable  ${DUMP_ENTRY_URI}  /xyz/openbmc_project/dump/entry/
223
224    ${dump_entries}=  Get URL List  ${DUMP_ENTRY_URI}
225    [Return]  ${dump_entries}
226
227Trigger Core Dump
228    [Documentation]  Trigger core dump.
229
230    # Find the pid of the active ipmid and kill it.
231    ${cmd_buf}=  Catenate  kill -s SEGV $(ps | egrep ' ipmid$' |
232    ...  egrep -v grep | \ cut -c1-6)
233
234    ${cmd_output}  ${stderr}  ${rc}=  BMC Execute Command  ${cmd_buf}
235    Should Be Empty  ${stderr}  msg=BMC execute command error.
236    Should Be Equal As Integers  ${rc}  ${0}
237    ...  msg=BMC execute command return code is not zero.
238
239Create User Initiated BMC Dump Using Redfish
240    [Documentation]  Trigger user initiated BMC dump via Redfish and return task id.
241
242    ${payload}=  Create Dictionary  DiagnosticDataType=Manager
243    ${resp}=  Redfish.Post
244    ...  /redfish/v1/Managers/bmc/LogServices/Dump/Actions/LogService.CollectDiagnosticData
245    ...  body=${payload}  valid_status_codes=[${HTTP_ACCEPTED}, ${HTTP_OK}]
246
247    # Example of response from above Redfish POST request.
248    # "@odata.id": "/redfish/v1/TaskService/Tasks/0",
249    # "@odata.type": "#Task.v1_4_3.Task",
250    # "Id": "0",
251    # "TaskState": "Running",
252    # "TaskStatus": "OK"
253
254    ${task_id}=  Set Variable  ${resp.dict['Id']}
255    [Return]  ${task_id}
256
257Auto Generate BMC Dump
258    [Documentation]  Auto generate BMC dump.
259
260    ${stdout}  ${stderr}  ${rc}=
261    ...  BMC Execute Command
262    ...  busctl --verbose call xyz.openbmc_project.Dump.Manager
263    ...  /xyz/openbmc_project/dump/bmc xyz.openbmc_project.Dump.Create CreateDump a{ss} 0
264    [Return]  ${stdout}  ${stderr}  ${rc}
265
266Get Dump Size
267    [Documentation]  Get dump size.
268    [Arguments]  ${dump_uri}
269
270    # Description of argument(s):
271    # dump_uri        Dump URI
272    #                 (Eg. 	/xyz/openbmc_project/dump/bmc/entry/1).
273
274    # Example of Dump entry.
275    # "data": {
276    #   "CompletedTime": 1616760931,
277    #   "Elapsed": 1616760931,
278    #   "OffloadUri": "",
279    #   "Offloaded": false,
280    #   "Password": "",
281    #   "Size": 3056,
282    #   "SourceDumpId": 117440513,
283    #   "StartTime": 1616760931,
284    #   "Status": "xyz.openbmc_project.Common.Progress.OperationStatus.Completed",
285    #   "VSPString": ""
286    #  },
287
288    Log  ${dump_uri}
289    ${dump_data}=  Redfish.Get Properties  ${dump_uri}
290    [Return]  ${dump_data["data"]["Size"]}
291
292Get Dump ID
293    [Documentation]  Return dump ID.
294    [Arguments]   ${task_id}
295
296    # Description of argument(s):
297    # task_id        Task ID.
298
299    # Example of HttpHeaders field of task details.
300    # "Payload": {
301    #   "HttpHeaders": [
302    #     "Host: <BMC_IP>",
303    #      "Accept-Encoding: identity",
304    #      "Connection: Keep-Alive",
305    #      "Accept: */*",
306    #      "Content-Length: 33",
307    #      "Location: /redfish/v1/Managers/bmc/LogServices/Dump/Entries/2"]
308    #    ],
309    #    "HttpOperation": "POST",
310    #    "JsonBody": "{\"DiagnosticDataType\":\"Manager\"}",
311    #     "TargetUri":
312    # "/redfish/v1/Managers/bmc/LogServices/Dump/Actions/LogService.CollectDiagnosticData"
313    # }
314
315    ${task_dict}=  Redfish.Get Properties  /redfish/v1/TaskService/Tasks/${task_id}
316    ${key}  ${value}=  Set Variable  ${task_dict["Payload"]["HttpHeaders"][-1].split(":")}
317    Run Keyword If  '${key}' != 'Location'  Fail
318    [Return]  ${value.split('/')[-1]}
319
320Get Task Status
321    [Documentation]  Return task status.
322    [Arguments]   ${task_id}
323
324    # Description of argument(s):
325    # task_id        Task ID.
326
327    ${resp}=  Redfish.Get Properties  /redfish/v1/TaskService/Tasks/${task_id}
328    [Return]  ${resp['TaskState']}
329
330Check Task Completion
331    [Documentation]  Check if the task is complete.
332    [Arguments]   ${task_id}
333
334    # Description of argument(s):
335    # task_id        Task ID.
336
337    ${status}=  Get Task Status  ${task_id}
338    Run Keyword Unless  '${status}' == 'Cancelled' or '${status}' == 'Completed'
339    ...  Fail  Task is still running.
340    [Return]  ${status}
341
342Get Dump ID And Status
343    [Documentation]  Return dump ID and status.
344    [Arguments]   ${task_id}
345
346    # Description of argument(s):
347    # task_id        Task ID.
348
349    ${task_status}=  Wait Until Keyword Succeeds  10 min  15 sec  Check Task Completion  ${task_id}
350    ${dump_id}=  Run Keyword If  '${task_status}' == 'Completed'  Get Dump ID  ${task_id}
351    ...  ELSE  Set Variable  None
352    [Return]  ${dump_id}  ${task_status}
353