1*** Settings ***
2Documentation  Validate IPMI sensor IDs using Redfish.
3
4Resource          ../lib/ipmi_client.robot
5Resource          ../lib/openbmc_ffdc.robot
6Library           ../lib/ipmi_utils.py
7Variables         ../data/ipmi_raw_cmd_table.py
8
9Test Setup        Redfish.Login
10Test Teardown     Run Keywords  FFDC On Test Case Fail  AND
11...  Redfish.Logout
12
13
14*** Variables ***
15${allowed_temp_diff}    ${1}
16${allowed_power_diff}   ${10}
17
18
19*** Test Cases ***
20
21Verify IPMI Temperature Readings using Redfish
22    [Documentation]  Verify temperatures from IPMI sensor reading command using Redfish.
23    [Tags]  Verify_IPMI_Temperature_Readings_using_Redfish
24    [Template]  Get Temperature Reading And Verify In Redfish
25
26    # command_type  sensor_id  member_id
27    IPMI            pcie       pcie
28    IPMI            ambient    ambient
29
30
31Verify DCMI Temperature Readings using Redfish
32    [Documentation]  Verify temperatures from DCMI sensor reading command using Redfish.
33    [Tags]  Verify_DCMI_Temperature_Readings_using_Redfish
34    [Template]  Get Temperature Reading And Verify In Redfish
35
36    # command_type  sensor_id  member_id
37    DCMI            pcie       pcie
38    DCMI            ambient    ambient
39
40
41Test Ambient Temperature Via IPMI
42    [Documentation]  Test ambient temperature via IPMI and verify using Redfish.
43    [Tags]  Test_Ambient_Temperature_Via_IPMI
44
45    # Example of IPMI dcmi get_temp_reading output:
46    #        Entity ID                       Entity Instance    Temp. Readings
47    # Inlet air temperature(40h)                      1               +19 C
48    # CPU temperature sensors(41h)                    5               +51 C
49    # CPU temperature sensors(41h)                    6               +50 C
50    # CPU temperature sensors(41h)                    7               +50 C
51    # CPU temperature sensors(41h)                    8               +50 C
52    # CPU temperature sensors(41h)                    9               +50 C
53    # CPU temperature sensors(41h)                    10              +48 C
54    # CPU temperature sensors(41h)                    11              +49 C
55    # CPU temperature sensors(41h)                    12              +47 C
56    # CPU temperature sensors(41h)                    8               +50 C
57    # CPU temperature sensors(41h)                    16              +51 C
58    # CPU temperature sensors(41h)                    24              +50 C
59    # CPU temperature sensors(41h)                    32              +43 C
60    # CPU temperature sensors(41h)                    40              +43 C
61    # Baseboard temperature sensors(42h)              1               +35 C
62
63    ${temp_reading}=  Run IPMI Standard Command  dcmi get_temp_reading -N 10
64    Should Contain  ${temp_reading}  Inlet air temperature
65    ...  msg="Unable to get inlet temperature via DCMI".
66
67    ${ambient_temp_line}=
68    ...  Get Lines Containing String  ${temp_reading}
69    ...  Inlet air temperature  case-insensitive
70
71    ${ambient_temp_ipmi}=  Set Variable  ${ambient_temp_line.split('+')[1].strip(' C')}
72
73    # Example of ambient temperature via Redfish
74
75    #"@odata.id": "/redfish/v1/Chassis/chassis/Thermal#/Temperatures/0",
76    #"@odata.type": "#Thermal.v1_3_0.Temperature",
77    #"LowerThresholdCritical": 0.0,
78    #"LowerThresholdNonCritical": 0.0,
79    #"MaxReadingRangeTemp": 0.0,
80    #"MemberId": "ambient",
81    #"MinReadingRangeTemp": 0.0,
82    #"Name": "ambient",
83    #"ReadingCelsius": 24.987000000000002,
84    #"Status": {
85          #"Health": "OK",
86          #"State": "Enabled"
87    #},
88    #"UpperThresholdCritical": 35.0,
89    #"UpperThresholdNonCritical": 25.0
90
91    ${ambient_temp_redfish}=  Get Temperature Reading From Redfish  ambient
92
93    ${ipmi_redfish_temp_diff}=
94    ...  Evaluate  abs(${ambient_temp_redfish} - ${ambient_temp_ipmi})
95
96    Should Be True  ${ipmi_redfish_temp_diff} <= ${allowed_temp_diff}
97    ...  msg=Ambient temperature above allowed threshold ${allowed_temp_diff}.
98
99
100Test Power Reading Via IPMI With Host Off
101    [Documentation]  Verify power reading via IPMI with host in off state
102    [Tags]  Test_Power_Reading_Via_IPMI_With_Host_Off
103
104    Redfish Power Off  stack_mode=skip
105
106    ${ipmi_reading}=  Get IPMI Power Reading
107
108    Should Be Equal  ${ipmi_reading['instantaneous_power_reading']}  0
109    ...  msg=Power reading not zero when power is off.
110
111
112Test Power Reading Via IPMI With Host Booted
113    [Documentation]  Test power reading via IPMI with host in booted state and
114    ...  verify using Redfish.
115    [Tags]  Test_Power_Reading_Via_IPMI_With_Host_Booted
116
117    IPMI Power On  stack_mode=skip
118
119    Wait Until Keyword Succeeds  2 min  30 sec  Verify Power Reading Using IPMI And Redfish
120
121
122Test Baseboard Temperature Via IPMI
123    [Documentation]  Test baseboard temperature via IPMI and verify using Redfish.
124    [Tags]  Test_Baseboard_Temperature_Via_IPMI
125
126    # Example of IPMI dcmi get_temp_reading output:
127    #        Entity ID                       Entity Instance    Temp. Readings
128    # Inlet air temperature(40h)                      1               +19 C
129    # CPU temperature sensors(41h)                    5               +51 C
130    # CPU temperature sensors(41h)                    6               +50 C
131    # CPU temperature sensors(41h)                    7               +50 C
132    # CPU temperature sensors(41h)                    8               +50 C
133    # CPU temperature sensors(41h)                    9               +50 C
134    # CPU temperature sensors(41h)                    10              +48 C
135    # CPU temperature sensors(41h)                    11              +49 C
136    # CPU temperature sensors(41h)                    12              +47 C
137    # CPU temperature sensors(41h)                    8               +50 C
138    # CPU temperature sensors(41h)                    16              +51 C
139    # CPU temperature sensors(41h)                    24              +50 C
140    # CPU temperature sensors(41h)                    32              +43 C
141    # CPU temperature sensors(41h)                    40              +43 C
142    # Baseboard temperature sensors(42h)              1               +35 C
143
144    ${temp_reading}=  Run IPMI Standard Command  dcmi get_temp_reading -N 10
145    Should Contain  ${temp_reading}  Baseboard temperature sensors
146    ...  msg="Unable to get baseboard temperature via DCMI".
147    ${baseboard_temp_line}=
148    ...  Get Lines Containing String  ${temp_reading}
149    ...  Baseboard temperature  case-insensitive=True
150
151    ${baseboard_temp_ipmi}=  Set Variable  ${baseboard_temp_line.split('+')[1].strip(' C')}
152
153    # Example of Baseboard temperature via Redfish
154
155    #"@odata.id": "/redfish/v1/Chassis/chassis/Thermal#/Temperatures/9",
156    #"@odata.type": "#Thermal.v1_3_0.Temperature",
157    #"LowerThresholdCritical": 0.0,
158    #"LowerThresholdNonCritical": 0.0,
159    #"MaxReadingRangeTemp": 0.0,
160    #"MemberId": "pcie",
161    #"MinReadingRangeTemp": 0.0,
162    #"Name": "pcie",
163    #"ReadingCelsius": 28.687,
164    #"Status": {
165          #"Health": "OK",
166          #"State": "Enabled"
167    #},
168    #"UpperThresholdCritical": 70.0,
169    #"UpperThresholdNonCritical": 60.0
170
171    ${baseboard_temp_redfish}=  Get Temperature Reading From Redfish  pcie
172
173    Should Be True
174    ...  ${baseboard_temp_redfish} - ${baseboard_temp_ipmi} <= ${allowed_temp_diff}
175    ...  msg=Baseboard temperature above allowed threshold ${allowed_temp_diff}.
176
177
178Test Power Reading Via IPMI Raw Command
179    [Documentation]  Test power reading via IPMI raw command and verify
180    ...  using Redfish.
181    [Tags]  Test_Power_Reading_Via_IPMI_Raw_Command
182
183    IPMI Power On  stack_mode=skip
184
185    Wait Until Keyword Succeeds  2 min  30 sec  Verify Power Reading Via Raw Command
186
187
188*** Keywords ***
189
190Get Temperature Reading And Verify In Redfish
191    [Documentation]  Get IPMI or DCMI sensor reading and verify in Redfish.
192    [Arguments]  ${command_type}  ${sensor_id}  ${member_id}
193
194    # Description of argument(s):
195    # command_type  Type of command used to get sensor data (eg. IPMI, DCMI).
196    # sensor_id     Sensor id used to get reading in IPMI or DCMI.
197    # member_id     Member id of sensor data in Redfish.
198
199    ${ipmi_value}=  Run Keyword If  '${command_type}' == 'IPMI'  Get IPMI Sensor Reading  ${sensor_id}
200    ...  ELSE  Get DCMI Sensor Reading  ${sensor_id}
201
202    ${redfish_value}=  Get Temperature Reading From Redfish  ${member_id}
203
204    Valid Range  ${ipmi_value}  ${redfish_value-1.000}  ${redfish_value+1.000}
205
206
207Get IPMI Sensor Reading
208    [Documentation]  Get reading from IPMI sensor reading command.
209    [Arguments]  ${sensor_id}
210
211    # Description of argument(s):
212    # sensor_id     Sensor id used to get reading in IPMI.
213
214    ${data}=  Run IPMI Standard Command  sensor reading ${sensor_id}
215
216    # Example reading:
217    # pcie             | 28.500
218
219    ${sensor_value}=  Set Variable  ${data.split('| ')[1].strip()}
220    [Return]  ${sensor_value}
221
222
223Get DCMI Sensor Reading
224    [Documentation]  Get reading from DCMI sensors command.
225    [Arguments]  ${sensor_id}
226
227    # Description of argument(s):
228    # sensor_id     Sensor id used to get reading in DCMI.
229
230    ${data}=  Run IPMI Standard Command  dcmi sensors
231    ${sensor_data}=  Get Lines Containing String  ${data}  ${sensor_id}
232
233    # Example reading:
234    # Record ID 0x00fd: pcie             | 28.50 degrees C   | ok
235
236    ${sensor_value}=  Set Variable  ${sensor_data.split(' | ')[1].strip('degrees C').strip()}
237    [Return]  ${sensor_value}
238
239
240Get Temperature Reading From Redfish
241    [Documentation]  Get temperature reading from Redfish.
242    [Arguments]  ${member_id}
243
244    # Description of argument(s):
245    # member_id    Member id of temperature.
246
247    @{redfish_readings}=  Redfish.Get Attribute  /redfish/v1/Chassis/chassis/Thermal  Temperatures
248    FOR  ${data}  IN  @{redfish_readings}
249        ${redfish_value}=  Set Variable If  '&{data}[MemberId]' == '${member_id}'
250        ...  &{data}[ReadingCelsius]
251        Exit For Loop If  '&{data}[MemberId]' == '${member_id}'
252    END
253    [Return]  ${redfish_value}
254
255
256Verify Power Reading Using IPMI And Redfish
257    [Documentation]  Verify power reading using IPMI and Redfish.
258
259    # Example of power reading command output via IPMI.
260    # Instantaneous power reading:                   235 Watts
261    # Minimum during sampling period:                235 Watts
262    # Maximum during sampling period:                235 Watts
263    # Average power reading over sample period:      235 Watts
264    # IPMI timestamp:                                Thu Jan  1 00:00:00 1970
265    # Sampling period:                               00000000 Seconds.
266    # Power reading state is:                        deactivated
267
268    ${ipmi_reading}=  Get IPMI Power Reading
269
270    ${power}=  Redfish.Get Properties  /redfish/v1/Chassis/chassis/Power
271    ${redfish_reading}=  Set Variable  ${power['PowerControl'][0]['PowerConsumedWatts']}
272
273    ${ipmi_redfish_power_diff}=
274    ...  Evaluate  abs(${redfish_reading} - ${ipmi_reading['instantaneous_power_reading']})
275
276    Should Be True  ${ipmi_redfish_power_diff} <= ${allowed_power_diff}
277    ...  msg=Power reading above allowed threshold ${allowed_power_diff}.
278
279
280Verify Power Reading Via Raw Command
281    [Documentation]  Get dcmi power reading via IPMI raw command.
282
283    ${ipmi_raw_output}=  Run IPMI Standard Command
284    ...  raw ${IPMI_RAW_CMD['power_reading']['Get'][0]}
285
286    ${power_reading_ipmi}=  Set Variable  ${ipmi_raw_output.split()[1]}
287    ${power_reading_ipmi}=
288    ...  Convert To Integer  0x${power_reading_ipmi}
289
290    #  Example of power reading via Redfish
291    #  "@odata.id": "/redfish/v1/Chassis/chassis/Power#/PowerControl/0",
292    #  "@odata.type": "#Power.v1_0_0.PowerControl",
293    #  "MemberId": "0",
294    #  "Name": "Chassis Power Control",
295    #  "PowerConsumedWatts": 145.0,
296
297    ${power}=  Redfish.Get Properties  /redfish/v1/Chassis/chassis/Power
298    ${redfish_reading}=  Set Variable  ${power['PowerControl'][0]['PowerConsumedWatts']}
299
300    ${ipmi_redfish_power_diff}=
301    ...  Evaluate  abs(${redfish_reading} - ${power_reading_ipmi})
302
303    Should Be True  ${ipmi_redfish_power_diff} <= ${allowed_power_diff}
304    ...  msg=Power reading above allowed threshold ${allowed_power_diff}.