1*** Settings ***
2Documentation  Main initialization file for the test cases contained in this
3...            directory and setting up the test environment variables.
4
5Resource          lib/resource.robot
6Library           lib/utils_get_version.py
7Suite Setup       Initializing Setup
8Suite Teardown    Init Teardown Steps
9
10*** Keywords ***
11Initializing Setup
12    [Documentation]  Initialize test environment.
13
14    ${software_versions}=  Software Versions
15    Rprint Vars  software_versions
16    Get OpenBMC System Info
17    Launch OpenBMC GUI Browser
18    Login OpenBMC GUI
19    Initial Message
20    LogOut OpenBMC GUI
21
22Initial Message
23    [Documentation]  Display initial info about the test cases.
24
25    Rpvars  EXECDIR
26    Log To Console  OBMC_GUI Testing ==> [IN PROGRESS]
27
28Get OpenBMC System Info
29    [Documentation]  Display open BMC system info like system name and IP.
30
31    ${OPENBMC_HOST_NAME}=  Get Hostname From IP Address  ${OPENBMC_HOST}
32    Rpvars  OPENBMC_HOST  OPENBMC_HOST_NAME
33    ${build_info}  ${stderr}  ${rc}=  BMC Execute Command  cat /etc/os-release
34    ...  print_output=1
35
36Init Teardown Steps
37    [Documentation]  End the test execution by closing browser.
38
39    Log To Console  OBMC_GUI Testing ==> [Finished]
40    Close Browser
41