xref: /openbmc/obmc-console/meson.build (revision d6e8b64a) 
1project('obmc-console', 'c',
2    default_options: [
3      'buildtype=debugoptimized',
4      'warning_level=3',
5      'werror=true',
6      'c_std=gnu17',
7      'tests=' + (meson.is_subproject() ? 'false' : 'true'),
8    ],
9    version: '1.1.0',
10    meson_version: '>=1.1.0',
11)
12
13add_project_arguments('-D_GNU_SOURCE', language: 'c')
14
15systemdsystemunitdir = dependency('systemd').get_variable('systemdsystemunitdir')
16install_data('conf/obmc-console@.service.in',
17             'conf/obmc-console@.socket.in',
18             rename: [
19               'obmc-console@.service',
20               'obmc-console@.socket',
21             ],
22             install_dir: systemdsystemunitdir,
23           )
24if get_option('ssh').allowed()
25  install_data('conf/obmc-console-ssh@.service.in',
26            rename: [
27              'obmc-console-ssh@.service'
28            ],
29            install_dir: systemdsystemunitdir,
30          )
31endif
32
33if get_option('concurrent-servers')
34  install_data('conf/client.2200.conf.in',
35               rename: [ 'client.2200.conf' ],
36               install_dir: systemdsystemunitdir)
37else
38  if get_option('ssh').allowed()
39    install_data('conf/obmc-console-ssh.socket.in',
40                rename: [ 'obmc-console-ssh.socket' ],
41                install_dir: systemdsystemunitdir)
42    install_data('conf/obmc-console-ssh@.service.d/use-socket.conf.in',
43                rename: [ 'use-socket.conf' ],
44                install_dir: systemdsystemunitdir / 'obmc-console-ssh@.service.d')
45  endif
46endif
47
48udev = dependency('udev', required: get_option('udev'))
49if udev.found()
50  install_data('conf/80-obmc-console-uart.rules.in',
51               rename: [ '80-obmc-console-uart.rules' ],
52               install_dir: udev.get_variable('udevdir') / 'rules.d')
53endif
54
55executable('obmc-console-server',
56           'config.c',
57           'console-dbus.c',
58           'console-server.c',
59           'console-socket.c',
60           'log-handler.c',
61           'ringbuffer.c',
62           'socket-handler.c',
63           'tty-handler.c',
64           'util.c',
65           c_args: [
66             '-DLOCALSTATEDIR="@0@"'.format(get_option('localstatedir')),
67             '-DSYSCONFDIR="@0@"'.format(get_option('sysconfdir'))
68           ],
69           dependencies: [
70             dependency('libsystemd'),
71             meson.get_compiler('c').find_library('rt')
72           ],
73           install_dir: get_option('sbindir'),
74           install: true)
75
76executable('obmc-console-client',
77           'config.c',
78           'console-client.c',
79           'console-socket.c',
80           'util.c',
81           c_args: [
82             '-DSYSCONFDIR="@0@"'.format(get_option('sysconfdir'))
83           ],
84           install: true)
85
86subdir('test')
87