xref: /openbmc/linux/scripts/genksyms/parse.y (revision f7018c21) 
1 /* C global declaration parser for genksyms.
2    Copyright 1996, 1997 Linux International.
3 
4    New implementation contributed by Richard Henderson <rth@tamu.edu>
5    Based on original work by Bjorn Ekwall <bj0rn@blox.se>
6 
7    This file is part of the Linux modutils.
8 
9    This program is free software; you can redistribute it and/or modify it
10    under the terms of the GNU General Public License as published by the
11    Free Software Foundation; either version 2 of the License, or (at your
12    option) any later version.
13 
14    This program is distributed in the hope that it will be useful, but
15    WITHOUT ANY WARRANTY; without even the implied warranty of
16    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
17    General Public License for more details.
18 
19    You should have received a copy of the GNU General Public License
20    along with this program; if not, write to the Free Software Foundation,
21    Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.  */
22 
23 
24 %{
25 
26 #include <assert.h>
27 #include <stdlib.h>
28 #include <string.h>
29 #include "genksyms.h"
30 
31 static int is_typedef;
32 static int is_extern;
33 static char *current_name;
34 static struct string_list *decl_spec;
35 
36 static void yyerror(const char *);
37 
38 static inline void
39 remove_node(struct string_list **p)
40 {
41   struct string_list *node = *p;
42   *p = node->next;
43   free_node(node);
44 }
45 
46 static inline void
47 remove_list(struct string_list **pb, struct string_list **pe)
48 {
49   struct string_list *b = *pb, *e = *pe;
50   *pb = e;
51   free_list(b, e);
52 }
53 
54 /* Record definition of a struct/union/enum */
55 static void record_compound(struct string_list **keyw,
56 		       struct string_list **ident,
57 		       struct string_list **body,
58 		       enum symbol_type type)
59 {
60 	struct string_list *b = *body, *i = *ident, *r;
61 
62 	if (i->in_source_file) {
63 		remove_node(keyw);
64 		(*ident)->tag = type;
65 		remove_list(body, ident);
66 		return;
67 	}
68 	r = copy_node(i); r->tag = type;
69 	r->next = (*keyw)->next; *body = r; (*keyw)->next = NULL;
70 	add_symbol(i->string, type, b, is_extern);
71 }
72 
73 %}
74 
75 %token ASM_KEYW
76 %token ATTRIBUTE_KEYW
77 %token AUTO_KEYW
78 %token BOOL_KEYW
79 %token CHAR_KEYW
80 %token CONST_KEYW
81 %token DOUBLE_KEYW
82 %token ENUM_KEYW
83 %token EXTERN_KEYW
84 %token EXTENSION_KEYW
85 %token FLOAT_KEYW
86 %token INLINE_KEYW
87 %token INT_KEYW
88 %token LONG_KEYW
89 %token REGISTER_KEYW
90 %token RESTRICT_KEYW
91 %token SHORT_KEYW
92 %token SIGNED_KEYW
93 %token STATIC_KEYW
94 %token STRUCT_KEYW
95 %token TYPEDEF_KEYW
96 %token UNION_KEYW
97 %token UNSIGNED_KEYW
98 %token VOID_KEYW
99 %token VOLATILE_KEYW
100 %token TYPEOF_KEYW
101 
102 %token EXPORT_SYMBOL_KEYW
103 
104 %token ASM_PHRASE
105 %token ATTRIBUTE_PHRASE
106 %token TYPEOF_PHRASE
107 %token BRACE_PHRASE
108 %token BRACKET_PHRASE
109 %token EXPRESSION_PHRASE
110 
111 %token CHAR
112 %token DOTS
113 %token IDENT
114 %token INT
115 %token REAL
116 %token STRING
117 %token TYPE
118 %token OTHER
119 %token FILENAME
120 
121 %%
122 
123 declaration_seq:
124 	declaration
125 	| declaration_seq declaration
126 	;
127 
128 declaration:
129 	{ is_typedef = 0; is_extern = 0; current_name = NULL; decl_spec = NULL; }
130 	declaration1
131 	{ free_list(*$2, NULL); *$2 = NULL; }
132 	;
133 
134 declaration1:
135 	EXTENSION_KEYW TYPEDEF_KEYW { is_typedef = 1; } simple_declaration
136 		{ $$ = $4; }
137 	| TYPEDEF_KEYW { is_typedef = 1; } simple_declaration
138 		{ $$ = $3; }
139 	| simple_declaration
140 	| function_definition
141 	| asm_definition
142 	| export_definition
143 	| error ';'				{ $$ = $2; }
144 	| error '}'				{ $$ = $2; }
145 	;
146 
147 simple_declaration:
148 	decl_specifier_seq_opt init_declarator_list_opt ';'
149 		{ if (current_name) {
150 		    struct string_list *decl = (*$3)->next;
151 		    (*$3)->next = NULL;
152 		    add_symbol(current_name,
153 			       is_typedef ? SYM_TYPEDEF : SYM_NORMAL,
154 			       decl, is_extern);
155 		    current_name = NULL;
156 		  }
157 		  $$ = $3;
158 		}
159 	;
160 
161 init_declarator_list_opt:
162 	/* empty */				{ $$ = NULL; }
163 	| init_declarator_list
164 	;
165 
166 init_declarator_list:
167 	init_declarator
168 		{ struct string_list *decl = *$1;
169 		  *$1 = NULL;
170 		  add_symbol(current_name,
171 			     is_typedef ? SYM_TYPEDEF : SYM_NORMAL, decl, is_extern);
172 		  current_name = NULL;
173 		  $$ = $1;
174 		}
175 	| init_declarator_list ',' init_declarator
176 		{ struct string_list *decl = *$3;
177 		  *$3 = NULL;
178 		  free_list(*$2, NULL);
179 		  *$2 = decl_spec;
180 		  add_symbol(current_name,
181 			     is_typedef ? SYM_TYPEDEF : SYM_NORMAL, decl, is_extern);
182 		  current_name = NULL;
183 		  $$ = $3;
184 		}
185 	;
186 
187 init_declarator:
188 	declarator asm_phrase_opt attribute_opt initializer_opt
189 		{ $$ = $4 ? $4 : $3 ? $3 : $2 ? $2 : $1; }
190 	;
191 
192 /* Hang on to the specifiers so that we can reuse them.  */
193 decl_specifier_seq_opt:
194 	/* empty */				{ decl_spec = NULL; }
195 	| decl_specifier_seq
196 	;
197 
198 decl_specifier_seq:
199 	decl_specifier				{ decl_spec = *$1; }
200 	| decl_specifier_seq decl_specifier	{ decl_spec = *$2; }
201 	;
202 
203 decl_specifier:
204 	storage_class_specifier
205 		{ /* Version 2 checksumming ignores storage class, as that
206 		     is really irrelevant to the linkage.  */
207 		  remove_node($1);
208 		  $$ = $1;
209 		}
210 	| type_specifier
211 	;
212 
213 storage_class_specifier:
214 	AUTO_KEYW
215 	| REGISTER_KEYW
216 	| STATIC_KEYW
217 	| EXTERN_KEYW	{ is_extern = 1; $$ = $1; }
218 	| INLINE_KEYW	{ is_extern = 0; $$ = $1; }
219 	;
220 
221 type_specifier:
222 	simple_type_specifier
223 	| cvar_qualifier
224 	| TYPEOF_KEYW '(' parameter_declaration ')'
225 	| TYPEOF_PHRASE
226 
227 	/* References to s/u/e's defined elsewhere.  Rearrange things
228 	   so that it is easier to expand the definition fully later.  */
229 	| STRUCT_KEYW IDENT
230 		{ remove_node($1); (*$2)->tag = SYM_STRUCT; $$ = $2; }
231 	| UNION_KEYW IDENT
232 		{ remove_node($1); (*$2)->tag = SYM_UNION; $$ = $2; }
233 	| ENUM_KEYW IDENT
234 		{ remove_node($1); (*$2)->tag = SYM_ENUM; $$ = $2; }
235 
236 	/* Full definitions of an s/u/e.  Record it.  */
237 	| STRUCT_KEYW IDENT class_body
238 		{ record_compound($1, $2, $3, SYM_STRUCT); $$ = $3; }
239 	| UNION_KEYW IDENT class_body
240 		{ record_compound($1, $2, $3, SYM_UNION); $$ = $3; }
241 	| ENUM_KEYW IDENT enum_body
242 		{ record_compound($1, $2, $3, SYM_ENUM); $$ = $3; }
243 	/*
244 	 * Anonymous enum definition. Tell add_symbol() to restart its counter.
245 	 */
246 	| ENUM_KEYW enum_body
247 		{ add_symbol(NULL, SYM_ENUM, NULL, 0); $$ = $2; }
248 	/* Anonymous s/u definitions.  Nothing needs doing.  */
249 	| STRUCT_KEYW class_body			{ $$ = $2; }
250 	| UNION_KEYW class_body				{ $$ = $2; }
251 	;
252 
253 simple_type_specifier:
254 	CHAR_KEYW
255 	| SHORT_KEYW
256 	| INT_KEYW
257 	| LONG_KEYW
258 	| SIGNED_KEYW
259 	| UNSIGNED_KEYW
260 	| FLOAT_KEYW
261 	| DOUBLE_KEYW
262 	| VOID_KEYW
263 	| BOOL_KEYW
264 	| TYPE			{ (*$1)->tag = SYM_TYPEDEF; $$ = $1; }
265 	;
266 
267 ptr_operator:
268 	'*' cvar_qualifier_seq_opt
269 		{ $$ = $2 ? $2 : $1; }
270 	;
271 
272 cvar_qualifier_seq_opt:
273 	/* empty */					{ $$ = NULL; }
274 	| cvar_qualifier_seq
275 	;
276 
277 cvar_qualifier_seq:
278 	cvar_qualifier
279 	| cvar_qualifier_seq cvar_qualifier		{ $$ = $2; }
280 	;
281 
282 cvar_qualifier:
283 	CONST_KEYW | VOLATILE_KEYW | ATTRIBUTE_PHRASE
284 	| RESTRICT_KEYW
285 		{ /* restrict has no effect in prototypes so ignore it */
286 		  remove_node($1);
287 		  $$ = $1;
288 		}
289 	;
290 
291 declarator:
292 	ptr_operator declarator			{ $$ = $2; }
293 	| direct_declarator
294 	;
295 
296 direct_declarator:
297 	IDENT
298 		{ if (current_name != NULL) {
299 		    error_with_pos("unexpected second declaration name");
300 		    YYERROR;
301 		  } else {
302 		    current_name = (*$1)->string;
303 		    $$ = $1;
304 		  }
305 		}
306 	| direct_declarator '(' parameter_declaration_clause ')'
307 		{ $$ = $4; }
308 	| direct_declarator '(' error ')'
309 		{ $$ = $4; }
310 	| direct_declarator BRACKET_PHRASE
311 		{ $$ = $2; }
312 	| '(' declarator ')'
313 		{ $$ = $3; }
314 	| '(' error ')'
315 		{ $$ = $3; }
316 	;
317 
318 /* Nested declarators differ from regular declarators in that they do
319    not record the symbols they find in the global symbol table.  */
320 nested_declarator:
321 	ptr_operator nested_declarator		{ $$ = $2; }
322 	| direct_nested_declarator
323 	;
324 
325 direct_nested_declarator:
326 	IDENT
327 	| TYPE
328 	| direct_nested_declarator '(' parameter_declaration_clause ')'
329 		{ $$ = $4; }
330 	| direct_nested_declarator '(' error ')'
331 		{ $$ = $4; }
332 	| direct_nested_declarator BRACKET_PHRASE
333 		{ $$ = $2; }
334 	| '(' nested_declarator ')'
335 		{ $$ = $3; }
336 	| '(' error ')'
337 		{ $$ = $3; }
338 	;
339 
340 parameter_declaration_clause:
341 	parameter_declaration_list_opt DOTS		{ $$ = $2; }
342 	| parameter_declaration_list_opt
343 	| parameter_declaration_list ',' DOTS		{ $$ = $3; }
344 	;
345 
346 parameter_declaration_list_opt:
347 	/* empty */					{ $$ = NULL; }
348 	| parameter_declaration_list
349 	;
350 
351 parameter_declaration_list:
352 	parameter_declaration
353 	| parameter_declaration_list ',' parameter_declaration
354 		{ $$ = $3; }
355 	;
356 
357 parameter_declaration:
358 	decl_specifier_seq m_abstract_declarator
359 		{ $$ = $2 ? $2 : $1; }
360 	;
361 
362 m_abstract_declarator:
363 	ptr_operator m_abstract_declarator
364 		{ $$ = $2 ? $2 : $1; }
365 	| direct_m_abstract_declarator
366 	;
367 
368 direct_m_abstract_declarator:
369 	/* empty */					{ $$ = NULL; }
370 	| IDENT
371 		{ /* For version 2 checksums, we don't want to remember
372 		     private parameter names.  */
373 		  remove_node($1);
374 		  $$ = $1;
375 		}
376 	/* This wasn't really a typedef name but an identifier that
377 	   shadows one.  */
378 	| TYPE
379 		{ remove_node($1);
380 		  $$ = $1;
381 		}
382 	| direct_m_abstract_declarator '(' parameter_declaration_clause ')'
383 		{ $$ = $4; }
384 	| direct_m_abstract_declarator '(' error ')'
385 		{ $$ = $4; }
386 	| direct_m_abstract_declarator BRACKET_PHRASE
387 		{ $$ = $2; }
388 	| '(' m_abstract_declarator ')'
389 		{ $$ = $3; }
390 	| '(' error ')'
391 		{ $$ = $3; }
392 	;
393 
394 function_definition:
395 	decl_specifier_seq_opt declarator BRACE_PHRASE
396 		{ struct string_list *decl = *$2;
397 		  *$2 = NULL;
398 		  add_symbol(current_name, SYM_NORMAL, decl, is_extern);
399 		  $$ = $3;
400 		}
401 	;
402 
403 initializer_opt:
404 	/* empty */					{ $$ = NULL; }
405 	| initializer
406 	;
407 
408 /* We never care about the contents of an initializer.  */
409 initializer:
410 	'=' EXPRESSION_PHRASE
411 		{ remove_list($2, &(*$1)->next); $$ = $2; }
412 	;
413 
414 class_body:
415 	'{' member_specification_opt '}'		{ $$ = $3; }
416 	| '{' error '}'					{ $$ = $3; }
417 	;
418 
419 member_specification_opt:
420 	/* empty */					{ $$ = NULL; }
421 	| member_specification
422 	;
423 
424 member_specification:
425 	member_declaration
426 	| member_specification member_declaration	{ $$ = $2; }
427 	;
428 
429 member_declaration:
430 	decl_specifier_seq_opt member_declarator_list_opt ';'
431 		{ $$ = $3; }
432 	| error ';'
433 		{ $$ = $2; }
434 	;
435 
436 member_declarator_list_opt:
437 	/* empty */					{ $$ = NULL; }
438 	| member_declarator_list
439 	;
440 
441 member_declarator_list:
442 	member_declarator
443 	| member_declarator_list ',' member_declarator	{ $$ = $3; }
444 	;
445 
446 member_declarator:
447 	nested_declarator attribute_opt			{ $$ = $2 ? $2 : $1; }
448 	| IDENT member_bitfield_declarator		{ $$ = $2; }
449 	| member_bitfield_declarator
450 	;
451 
452 member_bitfield_declarator:
453 	':' EXPRESSION_PHRASE				{ $$ = $2; }
454 	;
455 
456 attribute_opt:
457 	/* empty */					{ $$ = NULL; }
458 	| attribute_opt ATTRIBUTE_PHRASE
459 	;
460 
461 enum_body:
462 	'{' enumerator_list '}'				{ $$ = $3; }
463 	| '{' enumerator_list ',' '}'			{ $$ = $4; }
464 	 ;
465 
466 enumerator_list:
467 	enumerator
468 	| enumerator_list ',' enumerator
469 
470 enumerator:
471 	IDENT
472 		{
473 			const char *name = strdup((*$1)->string);
474 			add_symbol(name, SYM_ENUM_CONST, NULL, 0);
475 		}
476 	| IDENT '=' EXPRESSION_PHRASE
477 		{
478 			const char *name = strdup((*$1)->string);
479 			struct string_list *expr = copy_list_range(*$3, *$2);
480 			add_symbol(name, SYM_ENUM_CONST, expr, 0);
481 		}
482 
483 asm_definition:
484 	ASM_PHRASE ';'					{ $$ = $2; }
485 	;
486 
487 asm_phrase_opt:
488 	/* empty */					{ $$ = NULL; }
489 	| ASM_PHRASE
490 	;
491 
492 export_definition:
493 	EXPORT_SYMBOL_KEYW '(' IDENT ')' ';'
494 		{ export_symbol((*$3)->string); $$ = $5; }
495 	;
496 
497 
498 %%
499 
500 static void
501 yyerror(const char *e)
502 {
503   error_with_pos("%s", e);
504 }
505