xref: /openbmc/linux/scripts/checkstack.pl (revision d2ba09c1) 
1#!/usr/bin/env perl
2# SPDX-License-Identifier: GPL-2.0
3
4#	Check the stack usage of functions
5#
6#	Copyright Joern Engel <joern@lazybastard.org>
7#	Inspired by Linus Torvalds
8#	Original idea maybe from Keith Owens
9#	s390 port and big speedup by Arnd Bergmann <arnd@bergmann-dalldorf.de>
10#	Mips port by Juan Quintela <quintela@mandrakesoft.com>
11#	IA64 port via Andreas Dilger
12#	Arm port by Holger Schurig
13#	sh64 port by Paul Mundt
14#	Random bits by Matt Mackall <mpm@selenic.com>
15#	M68k port by Geert Uytterhoeven and Andreas Schwab
16#	AArch64, PARISC ports by Kyle McMartin
17#	sparc port by Martin Habets <errandir_news@mph.eclipse.co.uk>
18#
19#	Usage:
20#	objdump -d vmlinux | scripts/checkstack.pl [arch]
21#
22#	TODO :	Port to all architectures (one regex per arch)
23
24use strict;
25
26# check for arch
27#
28# $re is used for two matches:
29# $& (whole re) matches the complete objdump line with the stack growth
30# $1 (first bracket) matches the size of the stack growth
31#
32# $dre is similar, but for dynamic stack redutions:
33# $& (whole re) matches the complete objdump line with the stack growth
34# $1 (first bracket) matches the dynamic amount of the stack growth
35#
36# use anything else and feel the pain ;)
37my (@stack, $re, $dre, $x, $xs, $funcre);
38{
39	my $arch = shift;
40	if ($arch eq "") {
41		$arch = `uname -m`;
42		chomp($arch);
43	}
44
45	$x	= "[0-9a-f]";	# hex character
46	$xs	= "[0-9a-f ]";	# hex character or space
47	$funcre = qr/^$x* <(.*)>:$/;
48	if ($arch eq 'aarch64') {
49		#ffffffc0006325cc:       a9bb7bfd        stp     x29, x30, [sp,#-80]!
50		$re = qr/^.*stp.*sp,\#-([0-9]{1,8})\]\!/o;
51	} elsif ($arch eq 'arm') {
52		#c0008ffc:	e24dd064	sub	sp, sp, #100	; 0x64
53		$re = qr/.*sub.*sp, sp, #(([0-9]{2}|[3-9])[0-9]{2})/o;
54	} elsif ($arch =~ /^x86(_64)?$/ || $arch =~ /^i[3456]86$/) {
55		#c0105234:       81 ec ac 05 00 00       sub    $0x5ac,%esp
56		# or
57		#    2f60:    48 81 ec e8 05 00 00       sub    $0x5e8,%rsp
58		$re = qr/^.*[as][du][db]    \$(0x$x{1,8}),\%(e|r)sp$/o;
59		$dre = qr/^.*[as][du][db]    (%.*),\%(e|r)sp$/o;
60	} elsif ($arch eq 'ia64') {
61		#e0000000044011fc:       01 0f fc 8c     adds r12=-384,r12
62		$re = qr/.*adds.*r12=-(([0-9]{2}|[3-9])[0-9]{2}),r12/o;
63	} elsif ($arch eq 'm68k') {
64		#    2b6c:       4e56 fb70       linkw %fp,#-1168
65		#  1df770:       defc ffe4       addaw #-28,%sp
66		$re = qr/.*(?:linkw %fp,|addaw )#-([0-9]{1,4})(?:,%sp)?$/o;
67	} elsif ($arch eq 'mips64') {
68		#8800402c:       67bdfff0        daddiu  sp,sp,-16
69		$re = qr/.*daddiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
70	} elsif ($arch eq 'mips') {
71		#88003254:       27bdffe0        addiu   sp,sp,-32
72		$re = qr/.*addiu.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
73	} elsif ($arch eq 'nios2') {
74		#25a8:	defffb04 	addi	sp,sp,-20
75		$re = qr/.*addi.*sp,sp,-(([0-9]{2}|[3-9])[0-9]{2})/o;
76	} elsif ($arch eq 'openrisc') {
77		# c000043c:       9c 21 fe f0     l.addi r1,r1,-272
78		$re = qr/.*l\.addi.*r1,r1,-(([0-9]{2}|[3-9])[0-9]{2})/o;
79	} elsif ($arch eq 'parisc' || $arch eq 'parisc64') {
80		$re = qr/.*ldo ($x{1,8})\(sp\),sp/o;
81	} elsif ($arch eq 'ppc') {
82		#c00029f4:       94 21 ff 30     stwu    r1,-208(r1)
83		$re = qr/.*stwu.*r1,-($x{1,8})\(r1\)/o;
84	} elsif ($arch eq 'ppc64') {
85		#XXX
86		$re = qr/.*stdu.*r1,-($x{1,8})\(r1\)/o;
87	} elsif ($arch eq 'powerpc') {
88		$re = qr/.*st[dw]u.*r1,-($x{1,8})\(r1\)/o;
89	} elsif ($arch =~ /^s390x?$/) {
90		#   11160:       a7 fb ff 60             aghi   %r15,-160
91		# or
92		#  100092:	 e3 f0 ff c8 ff 71	 lay	 %r15,-56(%r15)
93		$re = qr/.*(?:lay|ag?hi).*\%r15,-(([0-9]{2}|[3-9])[0-9]{2})
94		      (?:\(\%r15\))?$/ox;
95	} elsif ($arch =~ /^sh64$/) {
96		#XXX: we only check for the immediate case presently,
97		#     though we will want to check for the movi/sub
98		#     pair for larger users. -- PFM.
99		#a00048e0:       d4fc40f0        addi.l  r15,-240,r15
100		$re = qr/.*addi\.l.*r15,-(([0-9]{2}|[3-9])[0-9]{2}),r15/o;
101	} elsif ($arch eq 'sparc' || $arch eq 'sparc64') {
102		# f0019d10:       9d e3 bf 90     save  %sp, -112, %sp
103		$re = qr/.*save.*%sp, -(([0-9]{2}|[3-9])[0-9]{2}), %sp/o;
104	} else {
105		print("wrong or unknown architecture \"$arch\"\n");
106		exit
107	}
108}
109
110#
111# main()
112#
113my ($func, $file, $lastslash);
114
115while (my $line = <STDIN>) {
116	if ($line =~ m/$funcre/) {
117		$func = $1;
118	}
119	elsif ($line =~ m/(.*):\s*file format/) {
120		$file = $1;
121		$file =~ s/\.ko//;
122		$lastslash = rindex($file, "/");
123		if ($lastslash != -1) {
124			$file = substr($file, $lastslash + 1);
125		}
126	}
127	elsif ($line =~ m/$re/) {
128		my $size = $1;
129		$size = hex($size) if ($size =~ /^0x/);
130
131		if ($size > 0xf0000000) {
132			$size = - $size;
133			$size += 0x80000000;
134			$size += 0x80000000;
135		}
136		next if ($size > 0x10000000);
137
138		next if $line !~ m/^($xs*)/;
139		my $addr = $1;
140		$addr =~ s/ /0/g;
141		$addr = "0x$addr";
142
143		my $intro = "$addr $func [$file]:";
144		my $padlen = 56 - length($intro);
145		while ($padlen > 0) {
146			$intro .= '	';
147			$padlen -= 8;
148		}
149		next if ($size < 100);
150		push @stack, "$intro$size\n";
151	}
152	elsif (defined $dre && $line =~ m/$dre/) {
153		my $size = "Dynamic ($1)";
154
155		next if $line !~ m/^($xs*)/;
156		my $addr = $1;
157		$addr =~ s/ /0/g;
158		$addr = "0x$addr";
159
160		my $intro = "$addr $func [$file]:";
161		my $padlen = 56 - length($intro);
162		while ($padlen > 0) {
163			$intro .= '	';
164			$padlen -= 8;
165		}
166		push @stack, "$intro$size\n";
167	}
168}
169
170# Sort output by size (last field)
171print sort { ($b =~ /:\t*(\d+)$/)[0] <=> ($a =~ /:\t*(\d+)$/)[0] } @stack;
172