xref: /openbmc/linux/arch/x86/kernel/vmlinux.lds.S (revision 75f25bd3) 
1/*
2 * ld script for the x86 kernel
3 *
4 * Historic 32-bit version written by Martin Mares <mj@atrey.karlin.mff.cuni.cz>
5 *
6 * Modernisation, unification and other changes and fixes:
7 *   Copyright (C) 2007-2009  Sam Ravnborg <sam@ravnborg.org>
8 *
9 *
10 * Don't define absolute symbols until and unless you know that symbol
11 * value is should remain constant even if kernel image is relocated
12 * at run time. Absolute symbols are not relocated. If symbol value should
13 * change if kernel is relocated, make the symbol section relative and
14 * put it inside the section definition.
15 */
16
17#ifdef CONFIG_X86_32
18#define LOAD_OFFSET __PAGE_OFFSET
19#else
20#define LOAD_OFFSET __START_KERNEL_map
21#endif
22
23#include <asm-generic/vmlinux.lds.h>
24#include <asm/asm-offsets.h>
25#include <asm/thread_info.h>
26#include <asm/page_types.h>
27#include <asm/cache.h>
28#include <asm/boot.h>
29
30#undef i386     /* in case the preprocessor is a 32bit one */
31
32OUTPUT_FORMAT(CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT, CONFIG_OUTPUT_FORMAT)
33
34#ifdef CONFIG_X86_32
35OUTPUT_ARCH(i386)
36ENTRY(phys_startup_32)
37jiffies = jiffies_64;
38#else
39OUTPUT_ARCH(i386:x86-64)
40ENTRY(phys_startup_64)
41jiffies_64 = jiffies;
42#endif
43
44#if defined(CONFIG_X86_64) && defined(CONFIG_DEBUG_RODATA)
45/*
46 * On 64-bit, align RODATA to 2MB so that even with CONFIG_DEBUG_RODATA
47 * we retain large page mappings for boundaries spanning kernel text, rodata
48 * and data sections.
49 *
50 * However, kernel identity mappings will have different RWX permissions
51 * to the pages mapping to text and to the pages padding (which are freed) the
52 * text section. Hence kernel identity mappings will be broken to smaller
53 * pages. For 64-bit, kernel text and kernel identity mappings are different,
54 * so we can enable protection checks that come with CONFIG_DEBUG_RODATA,
55 * as well as retain 2MB large page mappings for kernel text.
56 */
57#define X64_ALIGN_DEBUG_RODATA_BEGIN	. = ALIGN(HPAGE_SIZE);
58
59#define X64_ALIGN_DEBUG_RODATA_END				\
60		. = ALIGN(HPAGE_SIZE);				\
61		__end_rodata_hpage_align = .;
62
63#else
64
65#define X64_ALIGN_DEBUG_RODATA_BEGIN
66#define X64_ALIGN_DEBUG_RODATA_END
67
68#endif
69
70PHDRS {
71	text PT_LOAD FLAGS(5);          /* R_E */
72	data PT_LOAD FLAGS(6);          /* RW_ */
73#ifdef CONFIG_X86_64
74	user PT_LOAD FLAGS(5);          /* R_E */
75#ifdef CONFIG_SMP
76	percpu PT_LOAD FLAGS(6);        /* RW_ */
77#endif
78	init PT_LOAD FLAGS(7);          /* RWE */
79#endif
80	note PT_NOTE FLAGS(0);          /* ___ */
81}
82
83SECTIONS
84{
85#ifdef CONFIG_X86_32
86        . = LOAD_OFFSET + LOAD_PHYSICAL_ADDR;
87        phys_startup_32 = startup_32 - LOAD_OFFSET;
88#else
89        . = __START_KERNEL;
90        phys_startup_64 = startup_64 - LOAD_OFFSET;
91#endif
92
93	/* Text and read-only data */
94	.text :  AT(ADDR(.text) - LOAD_OFFSET) {
95		_text = .;
96		/* bootstrapping code */
97		HEAD_TEXT
98#ifdef CONFIG_X86_32
99		. = ALIGN(PAGE_SIZE);
100		*(.text..page_aligned)
101#endif
102		. = ALIGN(8);
103		_stext = .;
104		TEXT_TEXT
105		SCHED_TEXT
106		LOCK_TEXT
107		KPROBES_TEXT
108		ENTRY_TEXT
109		IRQENTRY_TEXT
110		*(.fixup)
111		*(.gnu.warning)
112		/* End of text section */
113		_etext = .;
114	} :text = 0x9090
115
116	NOTES :text :note
117
118	EXCEPTION_TABLE(16) :text = 0x9090
119
120#if defined(CONFIG_DEBUG_RODATA)
121	/* .text should occupy whole number of pages */
122	. = ALIGN(PAGE_SIZE);
123#endif
124	X64_ALIGN_DEBUG_RODATA_BEGIN
125	RO_DATA(PAGE_SIZE)
126	X64_ALIGN_DEBUG_RODATA_END
127
128	/* Data */
129	.data : AT(ADDR(.data) - LOAD_OFFSET) {
130		/* Start of data section */
131		_sdata = .;
132
133		/* init_task */
134		INIT_TASK_DATA(THREAD_SIZE)
135
136#ifdef CONFIG_X86_32
137		/* 32 bit has nosave before _edata */
138		NOSAVE_DATA
139#endif
140
141		PAGE_ALIGNED_DATA(PAGE_SIZE)
142
143		CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
144
145		DATA_DATA
146		CONSTRUCTORS
147
148		/* rarely changed data like cpu maps */
149		READ_MOSTLY_DATA(INTERNODE_CACHE_BYTES)
150
151		/* End of data section */
152		_edata = .;
153	} :data
154
155#ifdef CONFIG_X86_64
156
157#define VSYSCALL_ADDR (-10*1024*1024)
158
159#define VLOAD_OFFSET (VSYSCALL_ADDR - __vsyscall_0 + LOAD_OFFSET)
160#define VLOAD(x) (ADDR(x) - VLOAD_OFFSET)
161
162#define VVIRT_OFFSET (VSYSCALL_ADDR - __vsyscall_0)
163#define VVIRT(x) (ADDR(x) - VVIRT_OFFSET)
164
165	. = ALIGN(4096);
166	__vsyscall_0 = .;
167
168	. = VSYSCALL_ADDR;
169	.vsyscall : AT(VLOAD(.vsyscall)) {
170		*(.vsyscall_0)
171
172		. = 1024;
173		*(.vsyscall_1)
174
175		. = 2048;
176		*(.vsyscall_2)
177
178		. = 4096;  /* Pad the whole page. */
179	} :user =0xcc
180	. = ALIGN(__vsyscall_0 + PAGE_SIZE, PAGE_SIZE);
181
182#undef VSYSCALL_ADDR
183#undef VLOAD_OFFSET
184#undef VLOAD
185#undef VVIRT_OFFSET
186#undef VVIRT
187
188	__vvar_page = .;
189
190	.vvar : AT(ADDR(.vvar) - LOAD_OFFSET) {
191
192	      /* Place all vvars at the offsets in asm/vvar.h. */
193#define EMIT_VVAR(name, offset) 		\
194		. = offset;		\
195		*(.vvar_ ## name)
196#define __VVAR_KERNEL_LDS
197#include <asm/vvar.h>
198#undef __VVAR_KERNEL_LDS
199#undef EMIT_VVAR
200
201	} :data
202
203       . = ALIGN(__vvar_page + PAGE_SIZE, PAGE_SIZE);
204
205#endif /* CONFIG_X86_64 */
206
207	/* Init code and data - will be freed after init */
208	. = ALIGN(PAGE_SIZE);
209	.init.begin : AT(ADDR(.init.begin) - LOAD_OFFSET) {
210		__init_begin = .; /* paired with __init_end */
211	}
212
213#if defined(CONFIG_X86_64) && defined(CONFIG_SMP)
214	/*
215	 * percpu offsets are zero-based on SMP.  PERCPU_VADDR() changes the
216	 * output PHDR, so the next output section - .init.text - should
217	 * start another segment - init.
218	 */
219	PERCPU_VADDR(INTERNODE_CACHE_BYTES, 0, :percpu)
220#endif
221
222	INIT_TEXT_SECTION(PAGE_SIZE)
223#ifdef CONFIG_X86_64
224	:init
225#endif
226
227	INIT_DATA_SECTION(16)
228
229	/*
230	 * Code and data for a variety of lowlevel trampolines, to be
231	 * copied into base memory (< 1 MiB) during initialization.
232	 * Since it is copied early, the main copy can be discarded
233	 * afterwards.
234	 */
235	 .x86_trampoline : AT(ADDR(.x86_trampoline) - LOAD_OFFSET) {
236		x86_trampoline_start = .;
237		*(.x86_trampoline)
238		x86_trampoline_end = .;
239	}
240
241	.x86_cpu_dev.init : AT(ADDR(.x86_cpu_dev.init) - LOAD_OFFSET) {
242		__x86_cpu_dev_start = .;
243		*(.x86_cpu_dev.init)
244		__x86_cpu_dev_end = .;
245	}
246
247	/*
248	 * start address and size of operations which during runtime
249	 * can be patched with virtualization friendly instructions or
250	 * baremetal native ones. Think page table operations.
251	 * Details in paravirt_types.h
252	 */
253	. = ALIGN(8);
254	.parainstructions : AT(ADDR(.parainstructions) - LOAD_OFFSET) {
255		__parainstructions = .;
256		*(.parainstructions)
257		__parainstructions_end = .;
258	}
259
260	/*
261	 * struct alt_inst entries. From the header (alternative.h):
262	 * "Alternative instructions for different CPU types or capabilities"
263	 * Think locking instructions on spinlocks.
264	 */
265	. = ALIGN(8);
266	.altinstructions : AT(ADDR(.altinstructions) - LOAD_OFFSET) {
267		__alt_instructions = .;
268		*(.altinstructions)
269		__alt_instructions_end = .;
270	}
271
272	/*
273	 * And here are the replacement instructions. The linker sticks
274	 * them as binary blobs. The .altinstructions has enough data to
275	 * get the address and the length of them to patch the kernel safely.
276	 */
277	.altinstr_replacement : AT(ADDR(.altinstr_replacement) - LOAD_OFFSET) {
278		*(.altinstr_replacement)
279	}
280
281	/*
282	 * struct iommu_table_entry entries are injected in this section.
283	 * It is an array of IOMMUs which during run time gets sorted depending
284	 * on its dependency order. After rootfs_initcall is complete
285	 * this section can be safely removed.
286	 */
287	.iommu_table : AT(ADDR(.iommu_table) - LOAD_OFFSET) {
288		__iommu_table = .;
289		*(.iommu_table)
290		__iommu_table_end = .;
291	}
292
293	. = ALIGN(8);
294	.apicdrivers : AT(ADDR(.apicdrivers) - LOAD_OFFSET) {
295		__apicdrivers = .;
296		*(.apicdrivers);
297		__apicdrivers_end = .;
298	}
299
300	. = ALIGN(8);
301	/*
302	 * .exit.text is discard at runtime, not link time, to deal with
303	 *  references from .altinstructions and .eh_frame
304	 */
305	.exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
306		EXIT_TEXT
307	}
308
309	.exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
310		EXIT_DATA
311	}
312
313#if !defined(CONFIG_X86_64) || !defined(CONFIG_SMP)
314	PERCPU_SECTION(INTERNODE_CACHE_BYTES)
315#endif
316
317	. = ALIGN(PAGE_SIZE);
318
319	/* freed after init ends here */
320	.init.end : AT(ADDR(.init.end) - LOAD_OFFSET) {
321		__init_end = .;
322	}
323
324	/*
325	 * smp_locks might be freed after init
326	 * start/end must be page aligned
327	 */
328	. = ALIGN(PAGE_SIZE);
329	.smp_locks : AT(ADDR(.smp_locks) - LOAD_OFFSET) {
330		__smp_locks = .;
331		*(.smp_locks)
332		. = ALIGN(PAGE_SIZE);
333		__smp_locks_end = .;
334	}
335
336#ifdef CONFIG_X86_64
337	.data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
338		NOSAVE_DATA
339	}
340#endif
341
342	/* BSS */
343	. = ALIGN(PAGE_SIZE);
344	.bss : AT(ADDR(.bss) - LOAD_OFFSET) {
345		__bss_start = .;
346		*(.bss..page_aligned)
347		*(.bss)
348		. = ALIGN(PAGE_SIZE);
349		__bss_stop = .;
350	}
351
352	. = ALIGN(PAGE_SIZE);
353	.brk : AT(ADDR(.brk) - LOAD_OFFSET) {
354		__brk_base = .;
355		. += 64 * 1024;		/* 64k alignment slop space */
356		*(.brk_reservation)	/* areas brk users have reserved */
357		__brk_limit = .;
358	}
359
360	_end = .;
361
362        STABS_DEBUG
363        DWARF_DEBUG
364
365	/* Sections to be discarded */
366	DISCARDS
367	/DISCARD/ : { *(.eh_frame) }
368}
369
370
371#ifdef CONFIG_X86_32
372/*
373 * The ASSERT() sink to . is intentional, for binutils 2.14 compatibility:
374 */
375. = ASSERT((_end - LOAD_OFFSET <= KERNEL_IMAGE_SIZE),
376	   "kernel image bigger than KERNEL_IMAGE_SIZE");
377#else
378/*
379 * Per-cpu symbols which need to be offset from __per_cpu_load
380 * for the boot processor.
381 */
382#define INIT_PER_CPU(x) init_per_cpu__##x = x + __per_cpu_load
383INIT_PER_CPU(gdt_page);
384INIT_PER_CPU(irq_stack_union);
385
386/*
387 * Build-time check on the image size:
388 */
389. = ASSERT((_end - _text <= KERNEL_IMAGE_SIZE),
390	   "kernel image bigger than KERNEL_IMAGE_SIZE");
391
392#ifdef CONFIG_SMP
393. = ASSERT((irq_stack_union == 0),
394           "irq_stack_union is not at start of per-cpu area");
395#endif
396
397#endif /* CONFIG_X86_32 */
398
399#ifdef CONFIG_KEXEC
400#include <asm/kexec.h>
401
402. = ASSERT(kexec_control_code_size <= KEXEC_CONTROL_CODE_MAX_SIZE,
403           "kexec control code size is too big");
404#endif
405
406