xref: /openbmc/linux/arch/x86/kernel/head_32.S (revision d7a3d85e) 
1/*
2 *
3 *  Copyright (C) 1991, 1992  Linus Torvalds
4 *
5 *  Enhanced CPU detection and feature setting code by Mike Jagdis
6 *  and Martin Mares, November 1997.
7 */
8
9.text
10#include <linux/threads.h>
11#include <linux/init.h>
12#include <linux/linkage.h>
13#include <asm/segment.h>
14#include <asm/page_types.h>
15#include <asm/pgtable_types.h>
16#include <asm/cache.h>
17#include <asm/thread_info.h>
18#include <asm/asm-offsets.h>
19#include <asm/setup.h>
20#include <asm/processor-flags.h>
21#include <asm/msr-index.h>
22#include <asm/cpufeature.h>
23#include <asm/percpu.h>
24#include <asm/nops.h>
25#include <asm/bootparam.h>
26
27/* Physical address */
28#define pa(X) ((X) - __PAGE_OFFSET)
29
30/*
31 * References to members of the new_cpu_data structure.
32 */
33
34#define X86		new_cpu_data+CPUINFO_x86
35#define X86_VENDOR	new_cpu_data+CPUINFO_x86_vendor
36#define X86_MODEL	new_cpu_data+CPUINFO_x86_model
37#define X86_MASK	new_cpu_data+CPUINFO_x86_mask
38#define X86_HARD_MATH	new_cpu_data+CPUINFO_hard_math
39#define X86_CPUID	new_cpu_data+CPUINFO_cpuid_level
40#define X86_CAPABILITY	new_cpu_data+CPUINFO_x86_capability
41#define X86_VENDOR_ID	new_cpu_data+CPUINFO_x86_vendor_id
42
43/*
44 * This is how much memory in addition to the memory covered up to
45 * and including _end we need mapped initially.
46 * We need:
47 *     (KERNEL_IMAGE_SIZE/4096) / 1024 pages (worst case, non PAE)
48 *     (KERNEL_IMAGE_SIZE/4096) / 512 + 4 pages (worst case for PAE)
49 *
50 * Modulo rounding, each megabyte assigned here requires a kilobyte of
51 * memory, which is currently unreclaimed.
52 *
53 * This should be a multiple of a page.
54 *
55 * KERNEL_IMAGE_SIZE should be greater than pa(_end)
56 * and small than max_low_pfn, otherwise will waste some page table entries
57 */
58
59#if PTRS_PER_PMD > 1
60#define PAGE_TABLE_SIZE(pages) (((pages) / PTRS_PER_PMD) + PTRS_PER_PGD)
61#else
62#define PAGE_TABLE_SIZE(pages) ((pages) / PTRS_PER_PGD)
63#endif
64
65/* Number of possible pages in the lowmem region */
66LOWMEM_PAGES = (((1<<32) - __PAGE_OFFSET) >> PAGE_SHIFT)
67
68/* Enough space to fit pagetables for the low memory linear map */
69MAPPING_BEYOND_END = PAGE_TABLE_SIZE(LOWMEM_PAGES) << PAGE_SHIFT
70
71/*
72 * Worst-case size of the kernel mapping we need to make:
73 * a relocatable kernel can live anywhere in lowmem, so we need to be able
74 * to map all of lowmem.
75 */
76KERNEL_PAGES = LOWMEM_PAGES
77
78INIT_MAP_SIZE = PAGE_TABLE_SIZE(KERNEL_PAGES) * PAGE_SIZE
79RESERVE_BRK(pagetables, INIT_MAP_SIZE)
80
81/*
82 * 32-bit kernel entrypoint; only used by the boot CPU.  On entry,
83 * %esi points to the real-mode code as a 32-bit pointer.
84 * CS and DS must be 4 GB flat segments, but we don't depend on
85 * any particular GDT layout, because we load our own as soon as we
86 * can.
87 */
88__HEAD
89ENTRY(startup_32)
90	movl pa(stack_start),%ecx
91
92	/* test KEEP_SEGMENTS flag to see if the bootloader is asking
93		us to not reload segments */
94	testb $KEEP_SEGMENTS, BP_loadflags(%esi)
95	jnz 2f
96
97/*
98 * Set segments to known values.
99 */
100	lgdt pa(boot_gdt_descr)
101	movl $(__BOOT_DS),%eax
102	movl %eax,%ds
103	movl %eax,%es
104	movl %eax,%fs
105	movl %eax,%gs
106	movl %eax,%ss
1072:
108	leal -__PAGE_OFFSET(%ecx),%esp
109
110/*
111 * Clear BSS first so that there are no surprises...
112 */
113	cld
114	xorl %eax,%eax
115	movl $pa(__bss_start),%edi
116	movl $pa(__bss_stop),%ecx
117	subl %edi,%ecx
118	shrl $2,%ecx
119	rep ; stosl
120/*
121 * Copy bootup parameters out of the way.
122 * Note: %esi still has the pointer to the real-mode data.
123 * With the kexec as boot loader, parameter segment might be loaded beyond
124 * kernel image and might not even be addressable by early boot page tables.
125 * (kexec on panic case). Hence copy out the parameters before initializing
126 * page tables.
127 */
128	movl $pa(boot_params),%edi
129	movl $(PARAM_SIZE/4),%ecx
130	cld
131	rep
132	movsl
133	movl pa(boot_params) + NEW_CL_POINTER,%esi
134	andl %esi,%esi
135	jz 1f			# No command line
136	movl $pa(boot_command_line),%edi
137	movl $(COMMAND_LINE_SIZE/4),%ecx
138	rep
139	movsl
1401:
141
142#ifdef CONFIG_OLPC
143	/* save OFW's pgdir table for later use when calling into OFW */
144	movl %cr3, %eax
145	movl %eax, pa(olpc_ofw_pgd)
146#endif
147
148#ifdef CONFIG_MICROCODE_EARLY
149	/* Early load ucode on BSP. */
150	call load_ucode_bsp
151#endif
152
153/*
154 * Initialize page tables.  This creates a PDE and a set of page
155 * tables, which are located immediately beyond __brk_base.  The variable
156 * _brk_end is set up to point to the first "safe" location.
157 * Mappings are created both at virtual address 0 (identity mapping)
158 * and PAGE_OFFSET for up to _end.
159 */
160#ifdef CONFIG_X86_PAE
161
162	/*
163	 * In PAE mode initial_page_table is statically defined to contain
164	 * enough entries to cover the VMSPLIT option (that is the top 1, 2 or 3
165	 * entries). The identity mapping is handled by pointing two PGD entries
166	 * to the first kernel PMD.
167	 *
168	 * Note the upper half of each PMD or PTE are always zero at this stage.
169	 */
170
171#define KPMDS (((-__PAGE_OFFSET) >> 30) & 3) /* Number of kernel PMDs */
172
173	xorl %ebx,%ebx				/* %ebx is kept at zero */
174
175	movl $pa(__brk_base), %edi
176	movl $pa(initial_pg_pmd), %edx
177	movl $PTE_IDENT_ATTR, %eax
17810:
179	leal PDE_IDENT_ATTR(%edi),%ecx		/* Create PMD entry */
180	movl %ecx,(%edx)			/* Store PMD entry */
181						/* Upper half already zero */
182	addl $8,%edx
183	movl $512,%ecx
18411:
185	stosl
186	xchgl %eax,%ebx
187	stosl
188	xchgl %eax,%ebx
189	addl $0x1000,%eax
190	loop 11b
191
192	/*
193	 * End condition: we must map up to the end + MAPPING_BEYOND_END.
194	 */
195	movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
196	cmpl %ebp,%eax
197	jb 10b
1981:
199	addl $__PAGE_OFFSET, %edi
200	movl %edi, pa(_brk_end)
201	shrl $12, %eax
202	movl %eax, pa(max_pfn_mapped)
203
204	/* Do early initialization of the fixmap area */
205	movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
206	movl %eax,pa(initial_pg_pmd+0x1000*KPMDS-8)
207#else	/* Not PAE */
208
209page_pde_offset = (__PAGE_OFFSET >> 20);
210
211	movl $pa(__brk_base), %edi
212	movl $pa(initial_page_table), %edx
213	movl $PTE_IDENT_ATTR, %eax
21410:
215	leal PDE_IDENT_ATTR(%edi),%ecx		/* Create PDE entry */
216	movl %ecx,(%edx)			/* Store identity PDE entry */
217	movl %ecx,page_pde_offset(%edx)		/* Store kernel PDE entry */
218	addl $4,%edx
219	movl $1024, %ecx
22011:
221	stosl
222	addl $0x1000,%eax
223	loop 11b
224	/*
225	 * End condition: we must map up to the end + MAPPING_BEYOND_END.
226	 */
227	movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
228	cmpl %ebp,%eax
229	jb 10b
230	addl $__PAGE_OFFSET, %edi
231	movl %edi, pa(_brk_end)
232	shrl $12, %eax
233	movl %eax, pa(max_pfn_mapped)
234
235	/* Do early initialization of the fixmap area */
236	movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
237	movl %eax,pa(initial_page_table+0xffc)
238#endif
239
240#ifdef CONFIG_PARAVIRT
241	/* This is can only trip for a broken bootloader... */
242	cmpw $0x207, pa(boot_params + BP_version)
243	jb default_entry
244
245	/* Paravirt-compatible boot parameters.  Look to see what architecture
246		we're booting under. */
247	movl pa(boot_params + BP_hardware_subarch), %eax
248	cmpl $num_subarch_entries, %eax
249	jae bad_subarch
250
251	movl pa(subarch_entries)(,%eax,4), %eax
252	subl $__PAGE_OFFSET, %eax
253	jmp *%eax
254
255bad_subarch:
256WEAK(lguest_entry)
257WEAK(xen_entry)
258	/* Unknown implementation; there's really
259	   nothing we can do at this point. */
260	ud2a
261
262	__INITDATA
263
264subarch_entries:
265	.long default_entry		/* normal x86/PC */
266	.long lguest_entry		/* lguest hypervisor */
267	.long xen_entry			/* Xen hypervisor */
268	.long default_entry		/* Moorestown MID */
269num_subarch_entries = (. - subarch_entries) / 4
270.previous
271#else
272	jmp default_entry
273#endif /* CONFIG_PARAVIRT */
274
275#ifdef CONFIG_HOTPLUG_CPU
276/*
277 * Boot CPU0 entry point. It's called from play_dead(). Everything has been set
278 * up already except stack. We just set up stack here. Then call
279 * start_secondary().
280 */
281ENTRY(start_cpu0)
282	movl stack_start, %ecx
283	movl %ecx, %esp
284	jmp  *(initial_code)
285ENDPROC(start_cpu0)
286#endif
287
288/*
289 * Non-boot CPU entry point; entered from trampoline.S
290 * We can't lgdt here, because lgdt itself uses a data segment, but
291 * we know the trampoline has already loaded the boot_gdt for us.
292 *
293 * If cpu hotplug is not supported then this code can go in init section
294 * which will be freed later
295 */
296ENTRY(startup_32_smp)
297	cld
298	movl $(__BOOT_DS),%eax
299	movl %eax,%ds
300	movl %eax,%es
301	movl %eax,%fs
302	movl %eax,%gs
303	movl pa(stack_start),%ecx
304	movl %eax,%ss
305	leal -__PAGE_OFFSET(%ecx),%esp
306
307#ifdef CONFIG_MICROCODE_EARLY
308	/* Early load ucode on AP. */
309	call load_ucode_ap
310#endif
311
312
313default_entry:
314#define CR0_STATE	(X86_CR0_PE | X86_CR0_MP | X86_CR0_ET | \
315			 X86_CR0_NE | X86_CR0_WP | X86_CR0_AM | \
316			 X86_CR0_PG)
317	movl $(CR0_STATE & ~X86_CR0_PG),%eax
318	movl %eax,%cr0
319
320/*
321 * We want to start out with EFLAGS unambiguously cleared. Some BIOSes leave
322 * bits like NT set. This would confuse the debugger if this code is traced. So
323 * initialize them properly now before switching to protected mode. That means
324 * DF in particular (even though we have cleared it earlier after copying the
325 * command line) because GCC expects it.
326 */
327	pushl $0
328	popfl
329
330/*
331 * New page tables may be in 4Mbyte page mode and may be using the global pages.
332 *
333 * NOTE! If we are on a 486 we may have no cr4 at all! Specifically, cr4 exists
334 * if and only if CPUID exists and has flags other than the FPU flag set.
335 */
336	movl $-1,pa(X86_CPUID)		# preset CPUID level
337	movl $X86_EFLAGS_ID,%ecx
338	pushl %ecx
339	popfl				# set EFLAGS=ID
340	pushfl
341	popl %eax			# get EFLAGS
342	testl $X86_EFLAGS_ID,%eax	# did EFLAGS.ID remained set?
343	jz enable_paging		# hw disallowed setting of ID bit
344					# which means no CPUID and no CR4
345
346	xorl %eax,%eax
347	cpuid
348	movl %eax,pa(X86_CPUID)		# save largest std CPUID function
349
350	movl $1,%eax
351	cpuid
352	andl $~1,%edx			# Ignore CPUID.FPU
353	jz enable_paging		# No flags or only CPUID.FPU = no CR4
354
355	movl pa(mmu_cr4_features),%eax
356	movl %eax,%cr4
357
358	testb $X86_CR4_PAE, %al		# check if PAE is enabled
359	jz enable_paging
360
361	/* Check if extended functions are implemented */
362	movl $0x80000000, %eax
363	cpuid
364	/* Value must be in the range 0x80000001 to 0x8000ffff */
365	subl $0x80000001, %eax
366	cmpl $(0x8000ffff-0x80000001), %eax
367	ja enable_paging
368
369	/* Clear bogus XD_DISABLE bits */
370	call verify_cpu
371
372	mov $0x80000001, %eax
373	cpuid
374	/* Execute Disable bit supported? */
375	btl $(X86_FEATURE_NX & 31), %edx
376	jnc enable_paging
377
378	/* Setup EFER (Extended Feature Enable Register) */
379	movl $MSR_EFER, %ecx
380	rdmsr
381
382	btsl $_EFER_NX, %eax
383	/* Make changes effective */
384	wrmsr
385
386enable_paging:
387
388/*
389 * Enable paging
390 */
391	movl $pa(initial_page_table), %eax
392	movl %eax,%cr3		/* set the page table pointer.. */
393	movl $CR0_STATE,%eax
394	movl %eax,%cr0		/* ..and set paging (PG) bit */
395	ljmp $__BOOT_CS,$1f	/* Clear prefetch and normalize %eip */
3961:
397	/* Shift the stack pointer to a virtual address */
398	addl $__PAGE_OFFSET, %esp
399
400/*
401 * start system 32-bit setup. We need to re-do some of the things done
402 * in 16-bit mode for the "real" operations.
403 */
404	movl setup_once_ref,%eax
405	andl %eax,%eax
406	jz 1f				# Did we do this already?
407	call *%eax
4081:
409
410/*
411 * Check if it is 486
412 */
413	movb $4,X86			# at least 486
414	cmpl $-1,X86_CPUID
415	je is486
416
417	/* get vendor info */
418	xorl %eax,%eax			# call CPUID with 0 -> return vendor ID
419	cpuid
420	movl %eax,X86_CPUID		# save CPUID level
421	movl %ebx,X86_VENDOR_ID		# lo 4 chars
422	movl %edx,X86_VENDOR_ID+4	# next 4 chars
423	movl %ecx,X86_VENDOR_ID+8	# last 4 chars
424
425	orl %eax,%eax			# do we have processor info as well?
426	je is486
427
428	movl $1,%eax		# Use the CPUID instruction to get CPU type
429	cpuid
430	movb %al,%cl		# save reg for future use
431	andb $0x0f,%ah		# mask processor family
432	movb %ah,X86
433	andb $0xf0,%al		# mask model
434	shrb $4,%al
435	movb %al,X86_MODEL
436	andb $0x0f,%cl		# mask mask revision
437	movb %cl,X86_MASK
438	movl %edx,X86_CAPABILITY
439
440is486:
441	movl $0x50022,%ecx	# set AM, WP, NE and MP
442	movl %cr0,%eax
443	andl $0x80000011,%eax	# Save PG,PE,ET
444	orl %ecx,%eax
445	movl %eax,%cr0
446
447	lgdt early_gdt_descr
448	lidt idt_descr
449	ljmp $(__KERNEL_CS),$1f
4501:	movl $(__KERNEL_DS),%eax	# reload all the segment registers
451	movl %eax,%ss			# after changing gdt.
452
453	movl $(__USER_DS),%eax		# DS/ES contains default USER segment
454	movl %eax,%ds
455	movl %eax,%es
456
457	movl $(__KERNEL_PERCPU), %eax
458	movl %eax,%fs			# set this cpu's percpu
459
460	movl $(__KERNEL_STACK_CANARY),%eax
461	movl %eax,%gs
462
463	xorl %eax,%eax			# Clear LDT
464	lldt %ax
465
466	pushl $0		# fake return address for unwinder
467	jmp *(initial_code)
468
469#include "verify_cpu.S"
470
471/*
472 *  setup_once
473 *
474 *  The setup work we only want to run on the BSP.
475 *
476 *  Warning: %esi is live across this function.
477 */
478__INIT
479setup_once:
480	/*
481	 * Set up a idt with 256 entries pointing to ignore_int,
482	 * interrupt gates. It doesn't actually load idt - that needs
483	 * to be done on each CPU. Interrupts are enabled elsewhere,
484	 * when we can be relatively sure everything is ok.
485	 */
486
487	movl $idt_table,%edi
488	movl $early_idt_handlers,%eax
489	movl $NUM_EXCEPTION_VECTORS,%ecx
4901:
491	movl %eax,(%edi)
492	movl %eax,4(%edi)
493	/* interrupt gate, dpl=0, present */
494	movl $(0x8E000000 + __KERNEL_CS),2(%edi)
495	addl $9,%eax
496	addl $8,%edi
497	loop 1b
498
499	movl $256 - NUM_EXCEPTION_VECTORS,%ecx
500	movl $ignore_int,%edx
501	movl $(__KERNEL_CS << 16),%eax
502	movw %dx,%ax		/* selector = 0x0010 = cs */
503	movw $0x8E00,%dx	/* interrupt gate - dpl=0, present */
5042:
505	movl %eax,(%edi)
506	movl %edx,4(%edi)
507	addl $8,%edi
508	loop 2b
509
510#ifdef CONFIG_CC_STACKPROTECTOR
511	/*
512	 * Configure the stack canary. The linker can't handle this by
513	 * relocation.  Manually set base address in stack canary
514	 * segment descriptor.
515	 */
516	movl $gdt_page,%eax
517	movl $stack_canary,%ecx
518	movw %cx, 8 * GDT_ENTRY_STACK_CANARY + 2(%eax)
519	shrl $16, %ecx
520	movb %cl, 8 * GDT_ENTRY_STACK_CANARY + 4(%eax)
521	movb %ch, 8 * GDT_ENTRY_STACK_CANARY + 7(%eax)
522#endif
523
524	andl $0,setup_once_ref	/* Once is enough, thanks */
525	ret
526
527ENTRY(early_idt_handlers)
528	# 36(%esp) %eflags
529	# 32(%esp) %cs
530	# 28(%esp) %eip
531	# 24(%rsp) error code
532	i = 0
533	.rept NUM_EXCEPTION_VECTORS
534	.if (EXCEPTION_ERRCODE_MASK >> i) & 1
535	ASM_NOP2
536	.else
537	pushl $0		# Dummy error code, to make stack frame uniform
538	.endif
539	pushl $i		# 20(%esp) Vector number
540	jmp early_idt_handler
541	i = i + 1
542	.endr
543ENDPROC(early_idt_handlers)
544
545	/* This is global to keep gas from relaxing the jumps */
546ENTRY(early_idt_handler)
547	cld
548
549	cmpl $2,(%esp)		# X86_TRAP_NMI
550	je is_nmi		# Ignore NMI
551
552	cmpl $2,%ss:early_recursion_flag
553	je hlt_loop
554	incl %ss:early_recursion_flag
555
556	push %eax		# 16(%esp)
557	push %ecx		# 12(%esp)
558	push %edx		#  8(%esp)
559	push %ds		#  4(%esp)
560	push %es		#  0(%esp)
561	movl $(__KERNEL_DS),%eax
562	movl %eax,%ds
563	movl %eax,%es
564
565	cmpl $(__KERNEL_CS),32(%esp)
566	jne 10f
567
568	leal 28(%esp),%eax	# Pointer to %eip
569	call early_fixup_exception
570	andl %eax,%eax
571	jnz ex_entry		/* found an exception entry */
572
57310:
574#ifdef CONFIG_PRINTK
575	xorl %eax,%eax
576	movw %ax,2(%esp)	/* clean up the segment values on some cpus */
577	movw %ax,6(%esp)
578	movw %ax,34(%esp)
579	leal  40(%esp),%eax
580	pushl %eax		/* %esp before the exception */
581	pushl %ebx
582	pushl %ebp
583	pushl %esi
584	pushl %edi
585	movl %cr2,%eax
586	pushl %eax
587	pushl (20+6*4)(%esp)	/* trapno */
588	pushl $fault_msg
589	call printk
590#endif
591	call dump_stack
592hlt_loop:
593	hlt
594	jmp hlt_loop
595
596ex_entry:
597	pop %es
598	pop %ds
599	pop %edx
600	pop %ecx
601	pop %eax
602	decl %ss:early_recursion_flag
603is_nmi:
604	addl $8,%esp		/* drop vector number and error code */
605	iret
606ENDPROC(early_idt_handler)
607
608/* This is the default interrupt "handler" :-) */
609	ALIGN
610ignore_int:
611	cld
612#ifdef CONFIG_PRINTK
613	pushl %eax
614	pushl %ecx
615	pushl %edx
616	pushl %es
617	pushl %ds
618	movl $(__KERNEL_DS),%eax
619	movl %eax,%ds
620	movl %eax,%es
621	cmpl $2,early_recursion_flag
622	je hlt_loop
623	incl early_recursion_flag
624	pushl 16(%esp)
625	pushl 24(%esp)
626	pushl 32(%esp)
627	pushl 40(%esp)
628	pushl $int_msg
629	call printk
630
631	call dump_stack
632
633	addl $(5*4),%esp
634	popl %ds
635	popl %es
636	popl %edx
637	popl %ecx
638	popl %eax
639#endif
640	iret
641ENDPROC(ignore_int)
642__INITDATA
643	.align 4
644early_recursion_flag:
645	.long 0
646
647__REFDATA
648	.align 4
649ENTRY(initial_code)
650	.long i386_start_kernel
651ENTRY(setup_once_ref)
652	.long setup_once
653
654/*
655 * BSS section
656 */
657__PAGE_ALIGNED_BSS
658	.align PAGE_SIZE
659#ifdef CONFIG_X86_PAE
660initial_pg_pmd:
661	.fill 1024*KPMDS,4,0
662#else
663ENTRY(initial_page_table)
664	.fill 1024,4,0
665#endif
666initial_pg_fixmap:
667	.fill 1024,4,0
668ENTRY(empty_zero_page)
669	.fill 4096,1,0
670ENTRY(swapper_pg_dir)
671	.fill 1024,4,0
672
673/*
674 * This starts the data section.
675 */
676#ifdef CONFIG_X86_PAE
677__PAGE_ALIGNED_DATA
678	/* Page-aligned for the benefit of paravirt? */
679	.align PAGE_SIZE
680ENTRY(initial_page_table)
681	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR),0	/* low identity map */
682# if KPMDS == 3
683	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR),0
684	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
685	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR+0x2000),0
686# elif KPMDS == 2
687	.long	0,0
688	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR),0
689	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
690# elif KPMDS == 1
691	.long	0,0
692	.long	0,0
693	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR),0
694# else
695#  error "Kernel PMDs should be 1, 2 or 3"
696# endif
697	.align PAGE_SIZE		/* needs to be page-sized too */
698#endif
699
700.data
701.balign 4
702ENTRY(stack_start)
703	.long init_thread_union+THREAD_SIZE
704
705__INITRODATA
706int_msg:
707	.asciz "Unknown interrupt or fault at: %p %p %p\n"
708
709fault_msg:
710/* fault info: */
711	.ascii "BUG: Int %d: CR2 %p\n"
712/* regs pushed in early_idt_handler: */
713	.ascii "     EDI %p  ESI %p  EBP %p  EBX %p\n"
714	.ascii "     ESP %p   ES %p   DS %p\n"
715	.ascii "     EDX %p  ECX %p  EAX %p\n"
716/* fault frame: */
717	.ascii "     vec %p  err %p  EIP %p   CS %p  flg %p\n"
718	.ascii "Stack: %p %p %p %p %p %p %p %p\n"
719	.ascii "       %p %p %p %p %p %p %p %p\n"
720	.asciz "       %p %p %p %p %p %p %p %p\n"
721
722#include "../../x86/xen/xen-head.S"
723
724/*
725 * The IDT and GDT 'descriptors' are a strange 48-bit object
726 * only used by the lidt and lgdt instructions. They are not
727 * like usual segment descriptors - they consist of a 16-bit
728 * segment size, and 32-bit linear address value:
729 */
730
731	.data
732.globl boot_gdt_descr
733.globl idt_descr
734
735	ALIGN
736# early boot GDT descriptor (must use 1:1 address mapping)
737	.word 0				# 32 bit align gdt_desc.address
738boot_gdt_descr:
739	.word __BOOT_DS+7
740	.long boot_gdt - __PAGE_OFFSET
741
742	.word 0				# 32-bit align idt_desc.address
743idt_descr:
744	.word IDT_ENTRIES*8-1		# idt contains 256 entries
745	.long idt_table
746
747# boot GDT descriptor (later on used by CPU#0):
748	.word 0				# 32 bit align gdt_desc.address
749ENTRY(early_gdt_descr)
750	.word GDT_ENTRIES*8-1
751	.long gdt_page			/* Overwritten for secondary CPUs */
752
753/*
754 * The boot_gdt must mirror the equivalent in setup.S and is
755 * used only for booting.
756 */
757	.align L1_CACHE_BYTES
758ENTRY(boot_gdt)
759	.fill GDT_ENTRY_BOOT_CS,8,0
760	.quad 0x00cf9a000000ffff	/* kernel 4GB code at 0x00000000 */
761	.quad 0x00cf92000000ffff	/* kernel 4GB data at 0x00000000 */
762