xref: /openbmc/linux/arch/x86/kernel/head_32.S (revision 54cbac81) 
1/*
2 *
3 *  Copyright (C) 1991, 1992  Linus Torvalds
4 *
5 *  Enhanced CPU detection and feature setting code by Mike Jagdis
6 *  and Martin Mares, November 1997.
7 */
8
9.text
10#include <linux/threads.h>
11#include <linux/init.h>
12#include <linux/linkage.h>
13#include <asm/segment.h>
14#include <asm/page_types.h>
15#include <asm/pgtable_types.h>
16#include <asm/cache.h>
17#include <asm/thread_info.h>
18#include <asm/asm-offsets.h>
19#include <asm/setup.h>
20#include <asm/processor-flags.h>
21#include <asm/msr-index.h>
22#include <asm/cpufeature.h>
23#include <asm/percpu.h>
24#include <asm/nops.h>
25
26/* Physical address */
27#define pa(X) ((X) - __PAGE_OFFSET)
28
29/*
30 * References to members of the new_cpu_data structure.
31 */
32
33#define X86		new_cpu_data+CPUINFO_x86
34#define X86_VENDOR	new_cpu_data+CPUINFO_x86_vendor
35#define X86_MODEL	new_cpu_data+CPUINFO_x86_model
36#define X86_MASK	new_cpu_data+CPUINFO_x86_mask
37#define X86_HARD_MATH	new_cpu_data+CPUINFO_hard_math
38#define X86_CPUID	new_cpu_data+CPUINFO_cpuid_level
39#define X86_CAPABILITY	new_cpu_data+CPUINFO_x86_capability
40#define X86_VENDOR_ID	new_cpu_data+CPUINFO_x86_vendor_id
41
42/*
43 * This is how much memory in addition to the memory covered up to
44 * and including _end we need mapped initially.
45 * We need:
46 *     (KERNEL_IMAGE_SIZE/4096) / 1024 pages (worst case, non PAE)
47 *     (KERNEL_IMAGE_SIZE/4096) / 512 + 4 pages (worst case for PAE)
48 *
49 * Modulo rounding, each megabyte assigned here requires a kilobyte of
50 * memory, which is currently unreclaimed.
51 *
52 * This should be a multiple of a page.
53 *
54 * KERNEL_IMAGE_SIZE should be greater than pa(_end)
55 * and small than max_low_pfn, otherwise will waste some page table entries
56 */
57
58#if PTRS_PER_PMD > 1
59#define PAGE_TABLE_SIZE(pages) (((pages) / PTRS_PER_PMD) + PTRS_PER_PGD)
60#else
61#define PAGE_TABLE_SIZE(pages) ((pages) / PTRS_PER_PGD)
62#endif
63
64/* Number of possible pages in the lowmem region */
65LOWMEM_PAGES = (((1<<32) - __PAGE_OFFSET) >> PAGE_SHIFT)
66
67/* Enough space to fit pagetables for the low memory linear map */
68MAPPING_BEYOND_END = PAGE_TABLE_SIZE(LOWMEM_PAGES) << PAGE_SHIFT
69
70/*
71 * Worst-case size of the kernel mapping we need to make:
72 * a relocatable kernel can live anywhere in lowmem, so we need to be able
73 * to map all of lowmem.
74 */
75KERNEL_PAGES = LOWMEM_PAGES
76
77INIT_MAP_SIZE = PAGE_TABLE_SIZE(KERNEL_PAGES) * PAGE_SIZE
78RESERVE_BRK(pagetables, INIT_MAP_SIZE)
79
80/*
81 * 32-bit kernel entrypoint; only used by the boot CPU.  On entry,
82 * %esi points to the real-mode code as a 32-bit pointer.
83 * CS and DS must be 4 GB flat segments, but we don't depend on
84 * any particular GDT layout, because we load our own as soon as we
85 * can.
86 */
87__HEAD
88ENTRY(startup_32)
89	movl pa(stack_start),%ecx
90
91	/* test KEEP_SEGMENTS flag to see if the bootloader is asking
92		us to not reload segments */
93	testb $(1<<6), BP_loadflags(%esi)
94	jnz 2f
95
96/*
97 * Set segments to known values.
98 */
99	lgdt pa(boot_gdt_descr)
100	movl $(__BOOT_DS),%eax
101	movl %eax,%ds
102	movl %eax,%es
103	movl %eax,%fs
104	movl %eax,%gs
105	movl %eax,%ss
1062:
107	leal -__PAGE_OFFSET(%ecx),%esp
108
109/*
110 * Clear BSS first so that there are no surprises...
111 */
112	cld
113	xorl %eax,%eax
114	movl $pa(__bss_start),%edi
115	movl $pa(__bss_stop),%ecx
116	subl %edi,%ecx
117	shrl $2,%ecx
118	rep ; stosl
119/*
120 * Copy bootup parameters out of the way.
121 * Note: %esi still has the pointer to the real-mode data.
122 * With the kexec as boot loader, parameter segment might be loaded beyond
123 * kernel image and might not even be addressable by early boot page tables.
124 * (kexec on panic case). Hence copy out the parameters before initializing
125 * page tables.
126 */
127	movl $pa(boot_params),%edi
128	movl $(PARAM_SIZE/4),%ecx
129	cld
130	rep
131	movsl
132	movl pa(boot_params) + NEW_CL_POINTER,%esi
133	andl %esi,%esi
134	jz 1f			# No command line
135	movl $pa(boot_command_line),%edi
136	movl $(COMMAND_LINE_SIZE/4),%ecx
137	rep
138	movsl
1391:
140
141#ifdef CONFIG_OLPC
142	/* save OFW's pgdir table for later use when calling into OFW */
143	movl %cr3, %eax
144	movl %eax, pa(olpc_ofw_pgd)
145#endif
146
147/*
148 * Initialize page tables.  This creates a PDE and a set of page
149 * tables, which are located immediately beyond __brk_base.  The variable
150 * _brk_end is set up to point to the first "safe" location.
151 * Mappings are created both at virtual address 0 (identity mapping)
152 * and PAGE_OFFSET for up to _end.
153 */
154#ifdef CONFIG_X86_PAE
155
156	/*
157	 * In PAE mode initial_page_table is statically defined to contain
158	 * enough entries to cover the VMSPLIT option (that is the top 1, 2 or 3
159	 * entries). The identity mapping is handled by pointing two PGD entries
160	 * to the first kernel PMD.
161	 *
162	 * Note the upper half of each PMD or PTE are always zero at this stage.
163	 */
164
165#define KPMDS (((-__PAGE_OFFSET) >> 30) & 3) /* Number of kernel PMDs */
166
167	xorl %ebx,%ebx				/* %ebx is kept at zero */
168
169	movl $pa(__brk_base), %edi
170	movl $pa(initial_pg_pmd), %edx
171	movl $PTE_IDENT_ATTR, %eax
17210:
173	leal PDE_IDENT_ATTR(%edi),%ecx		/* Create PMD entry */
174	movl %ecx,(%edx)			/* Store PMD entry */
175						/* Upper half already zero */
176	addl $8,%edx
177	movl $512,%ecx
17811:
179	stosl
180	xchgl %eax,%ebx
181	stosl
182	xchgl %eax,%ebx
183	addl $0x1000,%eax
184	loop 11b
185
186	/*
187	 * End condition: we must map up to the end + MAPPING_BEYOND_END.
188	 */
189	movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
190	cmpl %ebp,%eax
191	jb 10b
1921:
193	addl $__PAGE_OFFSET, %edi
194	movl %edi, pa(_brk_end)
195	shrl $12, %eax
196	movl %eax, pa(max_pfn_mapped)
197
198	/* Do early initialization of the fixmap area */
199	movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
200	movl %eax,pa(initial_pg_pmd+0x1000*KPMDS-8)
201#else	/* Not PAE */
202
203page_pde_offset = (__PAGE_OFFSET >> 20);
204
205	movl $pa(__brk_base), %edi
206	movl $pa(initial_page_table), %edx
207	movl $PTE_IDENT_ATTR, %eax
20810:
209	leal PDE_IDENT_ATTR(%edi),%ecx		/* Create PDE entry */
210	movl %ecx,(%edx)			/* Store identity PDE entry */
211	movl %ecx,page_pde_offset(%edx)		/* Store kernel PDE entry */
212	addl $4,%edx
213	movl $1024, %ecx
21411:
215	stosl
216	addl $0x1000,%eax
217	loop 11b
218	/*
219	 * End condition: we must map up to the end + MAPPING_BEYOND_END.
220	 */
221	movl $pa(_end) + MAPPING_BEYOND_END + PTE_IDENT_ATTR, %ebp
222	cmpl %ebp,%eax
223	jb 10b
224	addl $__PAGE_OFFSET, %edi
225	movl %edi, pa(_brk_end)
226	shrl $12, %eax
227	movl %eax, pa(max_pfn_mapped)
228
229	/* Do early initialization of the fixmap area */
230	movl $pa(initial_pg_fixmap)+PDE_IDENT_ATTR,%eax
231	movl %eax,pa(initial_page_table+0xffc)
232#endif
233
234#ifdef CONFIG_PARAVIRT
235	/* This is can only trip for a broken bootloader... */
236	cmpw $0x207, pa(boot_params + BP_version)
237	jb default_entry
238
239	/* Paravirt-compatible boot parameters.  Look to see what architecture
240		we're booting under. */
241	movl pa(boot_params + BP_hardware_subarch), %eax
242	cmpl $num_subarch_entries, %eax
243	jae bad_subarch
244
245	movl pa(subarch_entries)(,%eax,4), %eax
246	subl $__PAGE_OFFSET, %eax
247	jmp *%eax
248
249bad_subarch:
250WEAK(lguest_entry)
251WEAK(xen_entry)
252	/* Unknown implementation; there's really
253	   nothing we can do at this point. */
254	ud2a
255
256	__INITDATA
257
258subarch_entries:
259	.long default_entry		/* normal x86/PC */
260	.long lguest_entry		/* lguest hypervisor */
261	.long xen_entry			/* Xen hypervisor */
262	.long default_entry		/* Moorestown MID */
263num_subarch_entries = (. - subarch_entries) / 4
264.previous
265#else
266	jmp default_entry
267#endif /* CONFIG_PARAVIRT */
268
269#ifdef CONFIG_HOTPLUG_CPU
270/*
271 * Boot CPU0 entry point. It's called from play_dead(). Everything has been set
272 * up already except stack. We just set up stack here. Then call
273 * start_secondary().
274 */
275ENTRY(start_cpu0)
276	movl stack_start, %ecx
277	movl %ecx, %esp
278	jmp  *(initial_code)
279ENDPROC(start_cpu0)
280#endif
281
282/*
283 * Non-boot CPU entry point; entered from trampoline.S
284 * We can't lgdt here, because lgdt itself uses a data segment, but
285 * we know the trampoline has already loaded the boot_gdt for us.
286 *
287 * If cpu hotplug is not supported then this code can go in init section
288 * which will be freed later
289 */
290__CPUINIT
291ENTRY(startup_32_smp)
292	cld
293	movl $(__BOOT_DS),%eax
294	movl %eax,%ds
295	movl %eax,%es
296	movl %eax,%fs
297	movl %eax,%gs
298	movl pa(stack_start),%ecx
299	movl %eax,%ss
300	leal -__PAGE_OFFSET(%ecx),%esp
301
302default_entry:
303/*
304 *	New page tables may be in 4Mbyte page mode and may
305 *	be using the global pages.
306 *
307 *	NOTE! If we are on a 486 we may have no cr4 at all!
308 *	Specifically, cr4 exists if and only if CPUID exists
309 *	and has flags other than the FPU flag set.
310 */
311	movl $X86_EFLAGS_ID,%ecx
312	pushl %ecx
313	popfl
314	pushfl
315	popl %eax
316	pushl $0
317	popfl
318	pushfl
319	popl %edx
320	xorl %edx,%eax
321	testl %ecx,%eax
322	jz 6f			# No ID flag = no CPUID = no CR4
323
324	movl $1,%eax
325	cpuid
326	andl $~1,%edx		# Ignore CPUID.FPU
327	jz 6f			# No flags or only CPUID.FPU = no CR4
328
329	movl pa(mmu_cr4_features),%eax
330	movl %eax,%cr4
331
332	testb $X86_CR4_PAE, %al		# check if PAE is enabled
333	jz 6f
334
335	/* Check if extended functions are implemented */
336	movl $0x80000000, %eax
337	cpuid
338	/* Value must be in the range 0x80000001 to 0x8000ffff */
339	subl $0x80000001, %eax
340	cmpl $(0x8000ffff-0x80000001), %eax
341	ja 6f
342
343	/* Clear bogus XD_DISABLE bits */
344	call verify_cpu
345
346	mov $0x80000001, %eax
347	cpuid
348	/* Execute Disable bit supported? */
349	btl $(X86_FEATURE_NX & 31), %edx
350	jnc 6f
351
352	/* Setup EFER (Extended Feature Enable Register) */
353	movl $MSR_EFER, %ecx
354	rdmsr
355
356	btsl $_EFER_NX, %eax
357	/* Make changes effective */
358	wrmsr
359
3606:
361
362/*
363 * Enable paging
364 */
365	movl $pa(initial_page_table), %eax
366	movl %eax,%cr3		/* set the page table pointer.. */
367	movl %cr0,%eax
368	orl  $X86_CR0_PG,%eax
369	movl %eax,%cr0		/* ..and set paging (PG) bit */
370	ljmp $__BOOT_CS,$1f	/* Clear prefetch and normalize %eip */
3711:
372	/* Shift the stack pointer to a virtual address */
373	addl $__PAGE_OFFSET, %esp
374
375/*
376 * Initialize eflags.  Some BIOS's leave bits like NT set.  This would
377 * confuse the debugger if this code is traced.
378 * XXX - best to initialize before switching to protected mode.
379 */
380	pushl $0
381	popfl
382
383/*
384 * start system 32-bit setup. We need to re-do some of the things done
385 * in 16-bit mode for the "real" operations.
386 */
387	movl setup_once_ref,%eax
388	andl %eax,%eax
389	jz 1f				# Did we do this already?
390	call *%eax
3911:
392
393/* check if it is 486 or 386. */
394/*
395 * XXX - this does a lot of unnecessary setup.  Alignment checks don't
396 * apply at our cpl of 0 and the stack ought to be aligned already, and
397 * we don't need to preserve eflags.
398 */
399	movl $-1,X86_CPUID	# -1 for no CPUID initially
400	movb $3,X86		# at least 386
401	pushfl			# push EFLAGS
402	popl %eax		# get EFLAGS
403	movl %eax,%ecx		# save original EFLAGS
404	xorl $0x240000,%eax	# flip AC and ID bits in EFLAGS
405	pushl %eax		# copy to EFLAGS
406	popfl			# set EFLAGS
407	pushfl			# get new EFLAGS
408	popl %eax		# put it in eax
409	xorl %ecx,%eax		# change in flags
410	pushl %ecx		# restore original EFLAGS
411	popfl
412	testl $0x40000,%eax	# check if AC bit changed
413	je is386
414
415	movb $4,X86		# at least 486
416	testl $0x200000,%eax	# check if ID bit changed
417	je is486
418
419	/* get vendor info */
420	xorl %eax,%eax			# call CPUID with 0 -> return vendor ID
421	cpuid
422	movl %eax,X86_CPUID		# save CPUID level
423	movl %ebx,X86_VENDOR_ID		# lo 4 chars
424	movl %edx,X86_VENDOR_ID+4	# next 4 chars
425	movl %ecx,X86_VENDOR_ID+8	# last 4 chars
426
427	orl %eax,%eax			# do we have processor info as well?
428	je is486
429
430	movl $1,%eax		# Use the CPUID instruction to get CPU type
431	cpuid
432	movb %al,%cl		# save reg for future use
433	andb $0x0f,%ah		# mask processor family
434	movb %ah,X86
435	andb $0xf0,%al		# mask model
436	shrb $4,%al
437	movb %al,X86_MODEL
438	andb $0x0f,%cl		# mask mask revision
439	movb %cl,X86_MASK
440	movl %edx,X86_CAPABILITY
441
442is486:	movl $0x50022,%ecx	# set AM, WP, NE and MP
443	jmp 2f
444
445is386:	movl $2,%ecx		# set MP
4462:	movl %cr0,%eax
447	andl $0x80000011,%eax	# Save PG,PE,ET
448	orl %ecx,%eax
449	movl %eax,%cr0
450
451	call check_x87
452	lgdt early_gdt_descr
453	lidt idt_descr
454	ljmp $(__KERNEL_CS),$1f
4551:	movl $(__KERNEL_DS),%eax	# reload all the segment registers
456	movl %eax,%ss			# after changing gdt.
457
458	movl $(__USER_DS),%eax		# DS/ES contains default USER segment
459	movl %eax,%ds
460	movl %eax,%es
461
462	movl $(__KERNEL_PERCPU), %eax
463	movl %eax,%fs			# set this cpu's percpu
464
465	movl $(__KERNEL_STACK_CANARY),%eax
466	movl %eax,%gs
467
468	xorl %eax,%eax			# Clear LDT
469	lldt %ax
470
471	cld			# gcc2 wants the direction flag cleared at all times
472	pushl $0		# fake return address for unwinder
473	jmp *(initial_code)
474
475/*
476 * We depend on ET to be correct. This checks for 287/387.
477 */
478check_x87:
479	movb $0,X86_HARD_MATH
480	clts
481	fninit
482	fstsw %ax
483	cmpb $0,%al
484	je 1f
485	movl %cr0,%eax		/* no coprocessor: have to set bits */
486	xorl $4,%eax		/* set EM */
487	movl %eax,%cr0
488	ret
489	ALIGN
4901:	movb $1,X86_HARD_MATH
491	.byte 0xDB,0xE4		/* fsetpm for 287, ignored by 387 */
492	ret
493
494
495#include "verify_cpu.S"
496
497/*
498 *  setup_once
499 *
500 *  The setup work we only want to run on the BSP.
501 *
502 *  Warning: %esi is live across this function.
503 */
504__INIT
505setup_once:
506	/*
507	 * Set up a idt with 256 entries pointing to ignore_int,
508	 * interrupt gates. It doesn't actually load idt - that needs
509	 * to be done on each CPU. Interrupts are enabled elsewhere,
510	 * when we can be relatively sure everything is ok.
511	 */
512
513	movl $idt_table,%edi
514	movl $early_idt_handlers,%eax
515	movl $NUM_EXCEPTION_VECTORS,%ecx
5161:
517	movl %eax,(%edi)
518	movl %eax,4(%edi)
519	/* interrupt gate, dpl=0, present */
520	movl $(0x8E000000 + __KERNEL_CS),2(%edi)
521	addl $9,%eax
522	addl $8,%edi
523	loop 1b
524
525	movl $256 - NUM_EXCEPTION_VECTORS,%ecx
526	movl $ignore_int,%edx
527	movl $(__KERNEL_CS << 16),%eax
528	movw %dx,%ax		/* selector = 0x0010 = cs */
529	movw $0x8E00,%dx	/* interrupt gate - dpl=0, present */
5302:
531	movl %eax,(%edi)
532	movl %edx,4(%edi)
533	addl $8,%edi
534	loop 2b
535
536#ifdef CONFIG_CC_STACKPROTECTOR
537	/*
538	 * Configure the stack canary. The linker can't handle this by
539	 * relocation.  Manually set base address in stack canary
540	 * segment descriptor.
541	 */
542	movl $gdt_page,%eax
543	movl $stack_canary,%ecx
544	movw %cx, 8 * GDT_ENTRY_STACK_CANARY + 2(%eax)
545	shrl $16, %ecx
546	movb %cl, 8 * GDT_ENTRY_STACK_CANARY + 4(%eax)
547	movb %ch, 8 * GDT_ENTRY_STACK_CANARY + 7(%eax)
548#endif
549
550	andl $0,setup_once_ref	/* Once is enough, thanks */
551	ret
552
553ENTRY(early_idt_handlers)
554	# 36(%esp) %eflags
555	# 32(%esp) %cs
556	# 28(%esp) %eip
557	# 24(%rsp) error code
558	i = 0
559	.rept NUM_EXCEPTION_VECTORS
560	.if (EXCEPTION_ERRCODE_MASK >> i) & 1
561	ASM_NOP2
562	.else
563	pushl $0		# Dummy error code, to make stack frame uniform
564	.endif
565	pushl $i		# 20(%esp) Vector number
566	jmp early_idt_handler
567	i = i + 1
568	.endr
569ENDPROC(early_idt_handlers)
570
571	/* This is global to keep gas from relaxing the jumps */
572ENTRY(early_idt_handler)
573	cld
574	cmpl $2,%ss:early_recursion_flag
575	je hlt_loop
576	incl %ss:early_recursion_flag
577
578	push %eax		# 16(%esp)
579	push %ecx		# 12(%esp)
580	push %edx		#  8(%esp)
581	push %ds		#  4(%esp)
582	push %es		#  0(%esp)
583	movl $(__KERNEL_DS),%eax
584	movl %eax,%ds
585	movl %eax,%es
586
587	cmpl $(__KERNEL_CS),32(%esp)
588	jne 10f
589
590	leal 28(%esp),%eax	# Pointer to %eip
591	call early_fixup_exception
592	andl %eax,%eax
593	jnz ex_entry		/* found an exception entry */
594
59510:
596#ifdef CONFIG_PRINTK
597	xorl %eax,%eax
598	movw %ax,2(%esp)	/* clean up the segment values on some cpus */
599	movw %ax,6(%esp)
600	movw %ax,34(%esp)
601	leal  40(%esp),%eax
602	pushl %eax		/* %esp before the exception */
603	pushl %ebx
604	pushl %ebp
605	pushl %esi
606	pushl %edi
607	movl %cr2,%eax
608	pushl %eax
609	pushl (20+6*4)(%esp)	/* trapno */
610	pushl $fault_msg
611	call printk
612#endif
613	call dump_stack
614hlt_loop:
615	hlt
616	jmp hlt_loop
617
618ex_entry:
619	pop %es
620	pop %ds
621	pop %edx
622	pop %ecx
623	pop %eax
624	addl $8,%esp		/* drop vector number and error code */
625	decl %ss:early_recursion_flag
626	iret
627ENDPROC(early_idt_handler)
628
629/* This is the default interrupt "handler" :-) */
630	ALIGN
631ignore_int:
632	cld
633#ifdef CONFIG_PRINTK
634	pushl %eax
635	pushl %ecx
636	pushl %edx
637	pushl %es
638	pushl %ds
639	movl $(__KERNEL_DS),%eax
640	movl %eax,%ds
641	movl %eax,%es
642	cmpl $2,early_recursion_flag
643	je hlt_loop
644	incl early_recursion_flag
645	pushl 16(%esp)
646	pushl 24(%esp)
647	pushl 32(%esp)
648	pushl 40(%esp)
649	pushl $int_msg
650	call printk
651
652	call dump_stack
653
654	addl $(5*4),%esp
655	popl %ds
656	popl %es
657	popl %edx
658	popl %ecx
659	popl %eax
660#endif
661	iret
662ENDPROC(ignore_int)
663__INITDATA
664	.align 4
665early_recursion_flag:
666	.long 0
667
668__REFDATA
669	.align 4
670ENTRY(initial_code)
671	.long i386_start_kernel
672ENTRY(setup_once_ref)
673	.long setup_once
674
675/*
676 * BSS section
677 */
678__PAGE_ALIGNED_BSS
679	.align PAGE_SIZE
680#ifdef CONFIG_X86_PAE
681initial_pg_pmd:
682	.fill 1024*KPMDS,4,0
683#else
684ENTRY(initial_page_table)
685	.fill 1024,4,0
686#endif
687initial_pg_fixmap:
688	.fill 1024,4,0
689ENTRY(empty_zero_page)
690	.fill 4096,1,0
691ENTRY(swapper_pg_dir)
692	.fill 1024,4,0
693
694/*
695 * This starts the data section.
696 */
697#ifdef CONFIG_X86_PAE
698__PAGE_ALIGNED_DATA
699	/* Page-aligned for the benefit of paravirt? */
700	.align PAGE_SIZE
701ENTRY(initial_page_table)
702	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR),0	/* low identity map */
703# if KPMDS == 3
704	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR),0
705	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
706	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR+0x2000),0
707# elif KPMDS == 2
708	.long	0,0
709	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR),0
710	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR+0x1000),0
711# elif KPMDS == 1
712	.long	0,0
713	.long	0,0
714	.long	pa(initial_pg_pmd+PGD_IDENT_ATTR),0
715# else
716#  error "Kernel PMDs should be 1, 2 or 3"
717# endif
718	.align PAGE_SIZE		/* needs to be page-sized too */
719#endif
720
721.data
722.balign 4
723ENTRY(stack_start)
724	.long init_thread_union+THREAD_SIZE
725
726__INITRODATA
727int_msg:
728	.asciz "Unknown interrupt or fault at: %p %p %p\n"
729
730fault_msg:
731/* fault info: */
732	.ascii "BUG: Int %d: CR2 %p\n"
733/* regs pushed in early_idt_handler: */
734	.ascii "     EDI %p  ESI %p  EBP %p  EBX %p\n"
735	.ascii "     ESP %p   ES %p   DS %p\n"
736	.ascii "     EDX %p  ECX %p  EAX %p\n"
737/* fault frame: */
738	.ascii "     vec %p  err %p  EIP %p   CS %p  flg %p\n"
739	.ascii "Stack: %p %p %p %p %p %p %p %p\n"
740	.ascii "       %p %p %p %p %p %p %p %p\n"
741	.asciz "       %p %p %p %p %p %p %p %p\n"
742
743#include "../../x86/xen/xen-head.S"
744
745/*
746 * The IDT and GDT 'descriptors' are a strange 48-bit object
747 * only used by the lidt and lgdt instructions. They are not
748 * like usual segment descriptors - they consist of a 16-bit
749 * segment size, and 32-bit linear address value:
750 */
751
752	.data
753.globl boot_gdt_descr
754.globl idt_descr
755
756	ALIGN
757# early boot GDT descriptor (must use 1:1 address mapping)
758	.word 0				# 32 bit align gdt_desc.address
759boot_gdt_descr:
760	.word __BOOT_DS+7
761	.long boot_gdt - __PAGE_OFFSET
762
763	.word 0				# 32-bit align idt_desc.address
764idt_descr:
765	.word IDT_ENTRIES*8-1		# idt contains 256 entries
766	.long idt_table
767
768# boot GDT descriptor (later on used by CPU#0):
769	.word 0				# 32 bit align gdt_desc.address
770ENTRY(early_gdt_descr)
771	.word GDT_ENTRIES*8-1
772	.long gdt_page			/* Overwritten for secondary CPUs */
773
774/*
775 * The boot_gdt must mirror the equivalent in setup.S and is
776 * used only for booting.
777 */
778	.align L1_CACHE_BYTES
779ENTRY(boot_gdt)
780	.fill GDT_ENTRY_BOOT_CS,8,0
781	.quad 0x00cf9a000000ffff	/* kernel 4GB code at 0x00000000 */
782	.quad 0x00cf92000000ffff	/* kernel 4GB data at 0x00000000 */
783