xref: /openbmc/linux/arch/s390/kernel/vmlinux.lds.S (revision bc5aa3a0) 
1/* ld script to make s390 Linux kernel
2 * Written by Martin Schwidefsky (schwidefsky@de.ibm.com)
3 */
4
5#include <asm/thread_info.h>
6#include <asm/page.h>
7
8/*
9 * Put .bss..swapper_pg_dir as the first thing in .bss. This will
10 * make sure it has 16k alignment.
11 */
12#define BSS_FIRST_SECTIONS *(.bss..swapper_pg_dir)
13
14/* Handle ro_after_init data on our own. */
15#define RO_AFTER_INIT_DATA
16
17#include <asm-generic/vmlinux.lds.h>
18
19OUTPUT_FORMAT("elf64-s390", "elf64-s390", "elf64-s390")
20OUTPUT_ARCH(s390:64-bit)
21ENTRY(startup)
22jiffies = jiffies_64;
23
24PHDRS {
25	text PT_LOAD FLAGS(5);	/* R_E */
26	data PT_LOAD FLAGS(7);	/* RWE */
27	note PT_NOTE FLAGS(0);	/* ___ */
28}
29
30SECTIONS
31{
32	. = 0x00000000;
33	.text : {
34	_text = .;		/* Text and read-only data */
35		HEAD_TEXT
36		TEXT_TEXT
37		SCHED_TEXT
38		LOCK_TEXT
39		KPROBES_TEXT
40		IRQENTRY_TEXT
41		SOFTIRQENTRY_TEXT
42		*(.fixup)
43		*(.gnu.warning)
44	} :text = 0x0700
45
46	_etext = .;		/* End of text section */
47
48	NOTES :text :note
49
50	.dummy : { *(.dummy) } :data
51
52	RO_DATA_SECTION(PAGE_SIZE)
53
54#ifdef CONFIG_SHARED_KERNEL
55	. = ALIGN(0x100000);	/* VM shared segments are 1MB aligned */
56#endif
57
58	. = ALIGN(PAGE_SIZE);
59	_eshared = .;		/* End of shareable data */
60	_sdata = .;		/* Start of data section */
61
62	. = ALIGN(PAGE_SIZE);
63	__start_ro_after_init = .;
64	.data..ro_after_init : {
65		 *(.data..ro_after_init)
66	}
67	EXCEPTION_TABLE(16)
68	. = ALIGN(PAGE_SIZE);
69	__end_ro_after_init = .;
70
71	RW_DATA_SECTION(0x100, PAGE_SIZE, THREAD_SIZE)
72
73	_edata = .;		/* End of data section */
74
75	/* will be freed after init */
76	. = ALIGN(PAGE_SIZE);	/* Init code and data */
77	__init_begin = .;
78
79	INIT_TEXT_SECTION(PAGE_SIZE)
80
81	/*
82	 * .exit.text is discarded at runtime, not link time,
83	 * to deal with references from __bug_table
84	*/
85	.exit.text : {
86		EXIT_TEXT
87	}
88
89	.exit.data : {
90		EXIT_DATA
91	}
92
93	/* early.c uses stsi, which requires page aligned data. */
94	. = ALIGN(PAGE_SIZE);
95	INIT_DATA_SECTION(0x100)
96
97	PERCPU_SECTION(0x100)
98	. = ALIGN(PAGE_SIZE);
99	__init_end = .;		/* freed after init ends here */
100
101	BSS_SECTION(PAGE_SIZE, 4 * PAGE_SIZE, PAGE_SIZE)
102
103	_end = . ;
104
105	/* Debugging sections.	*/
106	STABS_DEBUG
107	DWARF_DEBUG
108
109	/* Sections to be discarded */
110	DISCARDS
111}
112