1/* SPDX-License-Identifier: GPL-2.0-only */
2/*
3 * Copyright (c) 2021 Western Digital Corporation or its affiliates.
4 * Copyright (c) 2022 Ventana Micro Systems Inc.
5 */
6
7#include <linux/linkage.h>
8#include <asm/asm.h>
9#include <asm/asm-offsets.h>
10#include <asm/assembler.h>
11#include <asm/csr.h>
12#include <asm/xip_fixup.h>
13
14	.text
15	.altmacro
16	.option norelax
17
18ENTRY(__cpu_suspend_enter)
19	/* Save registers (except A0 and T0-T6) */
20	REG_S	ra, (SUSPEND_CONTEXT_REGS + PT_RA)(a0)
21	REG_S	sp, (SUSPEND_CONTEXT_REGS + PT_SP)(a0)
22	REG_S	gp, (SUSPEND_CONTEXT_REGS + PT_GP)(a0)
23	REG_S	tp, (SUSPEND_CONTEXT_REGS + PT_TP)(a0)
24	REG_S	s0, (SUSPEND_CONTEXT_REGS + PT_S0)(a0)
25	REG_S	s1, (SUSPEND_CONTEXT_REGS + PT_S1)(a0)
26	REG_S	a1, (SUSPEND_CONTEXT_REGS + PT_A1)(a0)
27	REG_S	a2, (SUSPEND_CONTEXT_REGS + PT_A2)(a0)
28	REG_S	a3, (SUSPEND_CONTEXT_REGS + PT_A3)(a0)
29	REG_S	a4, (SUSPEND_CONTEXT_REGS + PT_A4)(a0)
30	REG_S	a5, (SUSPEND_CONTEXT_REGS + PT_A5)(a0)
31	REG_S	a6, (SUSPEND_CONTEXT_REGS + PT_A6)(a0)
32	REG_S	a7, (SUSPEND_CONTEXT_REGS + PT_A7)(a0)
33	REG_S	s2, (SUSPEND_CONTEXT_REGS + PT_S2)(a0)
34	REG_S	s3, (SUSPEND_CONTEXT_REGS + PT_S3)(a0)
35	REG_S	s4, (SUSPEND_CONTEXT_REGS + PT_S4)(a0)
36	REG_S	s5, (SUSPEND_CONTEXT_REGS + PT_S5)(a0)
37	REG_S	s6, (SUSPEND_CONTEXT_REGS + PT_S6)(a0)
38	REG_S	s7, (SUSPEND_CONTEXT_REGS + PT_S7)(a0)
39	REG_S	s8, (SUSPEND_CONTEXT_REGS + PT_S8)(a0)
40	REG_S	s9, (SUSPEND_CONTEXT_REGS + PT_S9)(a0)
41	REG_S	s10, (SUSPEND_CONTEXT_REGS + PT_S10)(a0)
42	REG_S	s11, (SUSPEND_CONTEXT_REGS + PT_S11)(a0)
43
44	/* Save CSRs */
45	csrr	t0, CSR_EPC
46	REG_S	t0, (SUSPEND_CONTEXT_REGS + PT_EPC)(a0)
47	csrr	t0, CSR_STATUS
48	REG_S	t0, (SUSPEND_CONTEXT_REGS + PT_STATUS)(a0)
49	csrr	t0, CSR_TVAL
50	REG_S	t0, (SUSPEND_CONTEXT_REGS + PT_BADADDR)(a0)
51	csrr	t0, CSR_CAUSE
52	REG_S	t0, (SUSPEND_CONTEXT_REGS + PT_CAUSE)(a0)
53
54	/* Return non-zero value */
55	li	a0, 1
56
57	/* Return to C code */
58	ret
59END(__cpu_suspend_enter)
60
61ENTRY(__cpu_resume_enter)
62	/* Load the global pointer */
63	.option push
64	.option norelax
65		la gp, __global_pointer$
66	.option pop
67
68#ifdef CONFIG_MMU
69	/* Save A0 and A1 */
70	add	t0, a0, zero
71	add	t1, a1, zero
72
73	/* Enable MMU */
74	la	a0, swapper_pg_dir
75	XIP_FIXUP_OFFSET a0
76	call	relocate_enable_mmu
77
78	/* Restore A0 and A1 */
79	add	a0, t0, zero
80	add	a1, t1, zero
81#endif
82
83	/* Make A0 point to suspend context */
84	add	a0, a1, zero
85
86	/* Restore CSRs */
87	suspend_restore_csrs
88
89	/* Restore registers (except A0 and T0-T6) */
90	suspend_restore_regs
91
92	/* Return zero value */
93	add	a0, zero, zero
94
95	/* Return to C code */
96	ret
97END(__cpu_resume_enter)
98