xref: /openbmc/linux/arch/powerpc/kernel/vmlinux.lds.S (revision a0ae2562c6c4b2721d9fddba63b7286c13517d9f) 
1/* SPDX-License-Identifier: GPL-2.0 */
2#ifdef CONFIG_PPC64
3#define PROVIDE32(x)	PROVIDE(__unused__##x)
4#else
5#define PROVIDE32(x)	PROVIDE(x)
6#endif
7#include <asm/page.h>
8#include <asm-generic/vmlinux.lds.h>
9#include <asm/cache.h>
10#include <asm/thread_info.h>
11
12#if defined(CONFIG_STRICT_KERNEL_RWX) && !defined(CONFIG_PPC32)
13#define STRICT_ALIGN_SIZE	(1 << 24)
14#else
15#define STRICT_ALIGN_SIZE	PAGE_SIZE
16#endif
17
18ENTRY(_stext)
19
20PHDRS {
21	kernel PT_LOAD FLAGS(7); /* RWX */
22	notes PT_NOTE FLAGS(0);
23	dummy PT_NOTE FLAGS(0);
24
25	/* binutils < 2.18 has a bug that makes it misbehave when taking an
26	   ELF file with all segments at load address 0 as input.  This
27	   happens when running "strip" on vmlinux, because of the AT() magic
28	   in this linker script.  People using GCC >= 4.2 won't run into
29	   this problem, because the "build-id" support will put some data
30	   into the "notes" segment (at a non-zero load address).
31
32	   To work around this, we force some data into both the "dummy"
33	   segment and the kernel segment, so the dummy segment will get a
34	   non-zero load address.  It's not enough to always create the
35	   "notes" segment, since if nothing gets assigned to it, its load
36	   address will be zero.  */
37}
38
39#ifdef CONFIG_PPC64
40OUTPUT_ARCH(powerpc:common64)
41jiffies = jiffies_64;
42#else
43OUTPUT_ARCH(powerpc:common)
44jiffies = jiffies_64 + 4;
45#endif
46SECTIONS
47{
48	. = KERNELBASE;
49
50/*
51 * Text, read only data and other permanent read-only sections
52 */
53
54	_text = .;
55	_stext = .;
56
57	/*
58	 * Head text.
59	 * This needs to be in its own output section to avoid ld placing
60	 * branch trampoline stubs randomly throughout the fixed sections,
61	 * which it will do (even if the branch comes from another section)
62	 * in order to optimize stub generation.
63	 */
64	.head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
65#ifdef CONFIG_PPC64
66		KEEP(*(.head.text.first_256B));
67#ifdef CONFIG_PPC_BOOK3E
68#else
69		KEEP(*(.head.text.real_vectors));
70		*(.head.text.real_trampolines);
71		KEEP(*(.head.text.virt_vectors));
72		*(.head.text.virt_trampolines);
73# if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
74		KEEP(*(.head.data.fwnmi_page));
75# endif
76#endif
77#else /* !CONFIG_PPC64 */
78		HEAD_TEXT
79#endif
80	} :kernel
81
82	__head_end = .;
83
84#ifdef CONFIG_PPC64
85	/*
86	 * BLOCK(0) overrides the default output section alignment because
87	 * this needs to start right after .head.text in order for fixed
88	 * section placement to work.
89	 */
90	.text BLOCK(0) : AT(ADDR(.text) - LOAD_OFFSET) {
91#ifdef CONFIG_LD_HEAD_STUB_CATCH
92		KEEP(*(.linker_stub_catch));
93		. = . ;
94#endif
95
96#else
97	.text : AT(ADDR(.text) - LOAD_OFFSET) {
98		ALIGN_FUNCTION();
99#endif
100		/* careful! __ftr_alt_* sections need to be close to .text */
101		*(.text.hot TEXT_MAIN .text.fixup .text.unlikely .fixup __ftr_alt_* .ref.text);
102		SCHED_TEXT
103		CPUIDLE_TEXT
104		LOCK_TEXT
105		KPROBES_TEXT
106		IRQENTRY_TEXT
107		SOFTIRQENTRY_TEXT
108		/*
109		 * -Os builds call FP save/restore functions. The powerpc64
110		 * linker generates those on demand in the .sfpr section.
111		 * .sfpr gets placed at the beginning of a group of input
112		 * sections, which can break start-of-text offset if it is
113		 * included with the main text sections, so put it by itself.
114		 */
115		*(.sfpr);
116		MEM_KEEP(init.text)
117		MEM_KEEP(exit.text)
118
119#ifdef CONFIG_PPC32
120		*(.got1)
121		__got2_start = .;
122		*(.got2)
123		__got2_end = .;
124#endif /* CONFIG_PPC32 */
125
126	} :kernel
127
128	. = ALIGN(PAGE_SIZE);
129	_etext = .;
130	PROVIDE32 (etext = .);
131
132	/* Read-only data */
133	RO_DATA(PAGE_SIZE)
134
135#ifdef CONFIG_PPC64
136	. = ALIGN(8);
137	__stf_entry_barrier_fixup : AT(ADDR(__stf_entry_barrier_fixup) - LOAD_OFFSET) {
138		__start___stf_entry_barrier_fixup = .;
139		*(__stf_entry_barrier_fixup)
140		__stop___stf_entry_barrier_fixup = .;
141	}
142
143	. = ALIGN(8);
144	__stf_exit_barrier_fixup : AT(ADDR(__stf_exit_barrier_fixup) - LOAD_OFFSET) {
145		__start___stf_exit_barrier_fixup = .;
146		*(__stf_exit_barrier_fixup)
147		__stop___stf_exit_barrier_fixup = .;
148	}
149
150	. = ALIGN(8);
151	__rfi_flush_fixup : AT(ADDR(__rfi_flush_fixup) - LOAD_OFFSET) {
152		__start___rfi_flush_fixup = .;
153		*(__rfi_flush_fixup)
154		__stop___rfi_flush_fixup = .;
155	}
156
157	. = ALIGN(8);
158	__spec_barrier_fixup : AT(ADDR(__spec_barrier_fixup) - LOAD_OFFSET) {
159		__start___barrier_nospec_fixup = .;
160		*(__barrier_nospec_fixup)
161		__stop___barrier_nospec_fixup = .;
162	}
163#endif
164
165	EXCEPTION_TABLE(0)
166
167	NOTES :kernel :notes
168
169	/* The dummy segment contents for the bug workaround mentioned above
170	   near PHDRS.  */
171	.dummy : AT(ADDR(.dummy) - LOAD_OFFSET) {
172		LONG(0)
173		LONG(0)
174		LONG(0)
175	} :kernel :dummy
176
177/*
178 * Init sections discarded at runtime
179 */
180	. = ALIGN(STRICT_ALIGN_SIZE);
181	__init_begin = .;
182	INIT_TEXT_SECTION(PAGE_SIZE) :kernel
183
184	/* .exit.text is discarded at runtime, not link time,
185	 * to deal with references from __bug_table
186	 */
187	.exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
188		EXIT_TEXT
189	}
190
191	.init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
192		INIT_DATA
193		__vtop_table_begin = .;
194		KEEP(*(.vtop_fixup));
195		__vtop_table_end = .;
196		__ptov_table_begin = .;
197		KEEP(*(.ptov_fixup));
198		__ptov_table_end = .;
199	}
200
201	.init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
202		INIT_SETUP(16)
203	}
204
205	.initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
206		INIT_CALLS
207	}
208
209	.con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
210		CON_INITCALL
211	}
212
213	SECURITY_INIT
214
215	. = ALIGN(8);
216	__ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
217		__start___ftr_fixup = .;
218		KEEP(*(__ftr_fixup))
219		__stop___ftr_fixup = .;
220	}
221	. = ALIGN(8);
222	__mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
223		__start___mmu_ftr_fixup = .;
224		KEEP(*(__mmu_ftr_fixup))
225		__stop___mmu_ftr_fixup = .;
226	}
227	. = ALIGN(8);
228	__lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
229		__start___lwsync_fixup = .;
230		KEEP(*(__lwsync_fixup))
231		__stop___lwsync_fixup = .;
232	}
233#ifdef CONFIG_PPC64
234	. = ALIGN(8);
235	__fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
236		__start___fw_ftr_fixup = .;
237		KEEP(*(__fw_ftr_fixup))
238		__stop___fw_ftr_fixup = .;
239	}
240#endif
241	.init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
242		INIT_RAM_FS
243	}
244
245	PERCPU_SECTION(L1_CACHE_BYTES)
246
247	. = ALIGN(8);
248	.machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
249		__machine_desc_start = . ;
250		KEEP(*(.machine.desc))
251		__machine_desc_end = . ;
252	}
253#ifdef CONFIG_RELOCATABLE
254	. = ALIGN(8);
255	.dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
256	{
257#ifdef CONFIG_PPC32
258		__dynamic_symtab = .;
259#endif
260		*(.dynsym)
261	}
262	.dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
263	.dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
264	{
265		__dynamic_start = .;
266		*(.dynamic)
267	}
268	.hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
269	.interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
270	.rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
271	{
272		__rela_dyn_start = .;
273		*(.rela*)
274	}
275#endif
276	/* .exit.data is discarded at runtime, not link time,
277	 * to deal with references from .exit.text
278	 */
279	.exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
280		EXIT_DATA
281	}
282
283	/* freed after init ends here */
284	. = ALIGN(PAGE_SIZE);
285	__init_end = .;
286
287/*
288 * And now the various read/write data
289 */
290
291	. = ALIGN(PAGE_SIZE);
292	_sdata = .;
293
294#ifdef CONFIG_PPC32
295	.data : AT(ADDR(.data) - LOAD_OFFSET) {
296		DATA_DATA
297		*(.data.rel*)
298		*(SDATA_MAIN)
299		*(.sdata2)
300		*(.got.plt) *(.got)
301		*(.plt)
302	}
303#else
304	.data : AT(ADDR(.data) - LOAD_OFFSET) {
305		DATA_DATA
306		*(.data.rel*)
307		*(.toc1)
308		*(.branch_lt)
309	}
310
311	.opd : AT(ADDR(.opd) - LOAD_OFFSET) {
312		__start_opd = .;
313		KEEP(*(.opd))
314		__end_opd = .;
315	}
316
317	. = ALIGN(256);
318	.got : AT(ADDR(.got) - LOAD_OFFSET) {
319		__toc_start = .;
320#ifndef CONFIG_RELOCATABLE
321		__prom_init_toc_start = .;
322		arch/powerpc/kernel/prom_init.o*(.toc .got)
323		__prom_init_toc_end = .;
324#endif
325		*(.got)
326		*(.toc)
327	}
328#endif
329
330	/* The initial task and kernel stack */
331	INIT_TASK_DATA_SECTION(THREAD_SIZE)
332
333	.data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
334		PAGE_ALIGNED_DATA(PAGE_SIZE)
335	}
336
337	.data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
338		CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
339	}
340
341	.data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
342		READ_MOSTLY_DATA(L1_CACHE_BYTES)
343	}
344
345	. = ALIGN(PAGE_SIZE);
346	.data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
347		NOSAVE_DATA
348	}
349
350	BUG_TABLE
351
352	. = ALIGN(PAGE_SIZE);
353	_edata  =  .;
354	PROVIDE32 (edata = .);
355
356/*
357 * And finally the bss
358 */
359
360	BSS_SECTION(0, 0, 0)
361
362	. = ALIGN(PAGE_SIZE);
363	_end = . ;
364	PROVIDE32 (end = .);
365
366	STABS_DEBUG
367
368	DWARF_DEBUG
369
370	DISCARDS
371	/DISCARD/ : {
372		*(*.EMB.apuinfo)
373		*(.glink .iplt .plt .rela* .comment)
374		*(.gnu.version*)
375		*(.gnu.attributes)
376		*(.eh_frame)
377	}
378}
379