1#ifdef CONFIG_PPC64
2#define PROVIDE32(x)	PROVIDE(__unused__##x)
3#else
4#define PROVIDE32(x)	PROVIDE(x)
5#endif
6#include <asm/page.h>
7#include <asm-generic/vmlinux.lds.h>
8#include <asm/cache.h>
9#include <asm/thread_info.h>
10
11ENTRY(_stext)
12
13PHDRS {
14	kernel PT_LOAD FLAGS(7); /* RWX */
15	notes PT_NOTE FLAGS(0);
16	dummy PT_NOTE FLAGS(0);
17
18	/* binutils < 2.18 has a bug that makes it misbehave when taking an
19	   ELF file with all segments at load address 0 as input.  This
20	   happens when running "strip" on vmlinux, because of the AT() magic
21	   in this linker script.  People using GCC >= 4.2 won't run into
22	   this problem, because the "build-id" support will put some data
23	   into the "notes" segment (at a non-zero load address).
24
25	   To work around this, we force some data into both the "dummy"
26	   segment and the kernel segment, so the dummy segment will get a
27	   non-zero load address.  It's not enough to always create the
28	   "notes" segment, since if nothing gets assigned to it, its load
29	   address will be zero.  */
30}
31
32#ifdef CONFIG_PPC64
33OUTPUT_ARCH(powerpc:common64)
34jiffies = jiffies_64;
35#else
36OUTPUT_ARCH(powerpc:common)
37jiffies = jiffies_64 + 4;
38#endif
39SECTIONS
40{
41	. = KERNELBASE;
42
43/*
44 * Text, read only data and other permanent read-only sections
45 */
46
47	_text = .;
48	_stext = .;
49
50	/*
51	 * Head text.
52	 * This needs to be in its own output section to avoid ld placing
53	 * branch trampoline stubs randomly throughout the fixed sections,
54	 * which it will do (even if the branch comes from another section)
55	 * in order to optimize stub generation.
56	 */
57	.head.text : AT(ADDR(.head.text) - LOAD_OFFSET) {
58#ifdef CONFIG_PPC64
59		KEEP(*(.head.text.first_256B));
60#ifdef CONFIG_PPC_BOOK3E
61# define END_FIXED	0x100
62#else
63		KEEP(*(.head.text.real_vectors));
64		*(.head.text.real_trampolines);
65		KEEP(*(.head.text.virt_vectors));
66		*(.head.text.virt_trampolines);
67# if defined(CONFIG_PPC_PSERIES) || defined(CONFIG_PPC_POWERNV)
68		KEEP(*(.head.data.fwnmi_page));
69#  define END_FIXED	0x8000
70# else
71#  define END_FIXED	0x7000
72# endif
73#endif
74		ASSERT((. == END_FIXED), "vmlinux.lds.S: fixed section overflow error");
75#else /* !CONFIG_PPC64 */
76		HEAD_TEXT
77#endif
78	} :kernel
79
80	__head_end = .;
81
82	/*
83	 * If the build dies here, it's likely code in head_64.S is referencing
84	 * labels it can't reach, and the linker inserting stubs without the
85	 * assembler's knowledge. To debug, remove the above assert and
86	 * rebuild. Look for branch stubs in the fixed section region.
87	 *
88	 * Linker stub generation could be allowed in "trampoline"
89	 * sections if absolutely necessary, but this would require
90	 * some rework of the fixed sections. Before resorting to this,
91	 * consider references that have sufficient addressing range,
92	 * (e.g., hand coded trampolines) so the linker does not have
93	 * to add stubs.
94	 *
95	 * Linker stubs at the top of the main text section are currently not
96	 * detected, and will result in a crash at boot due to offsets being
97	 * wrong.
98	 */
99#ifdef CONFIG_PPC64
100	/*
101	 * BLOCK(0) overrides the default output section alignment because
102	 * this needs to start right after .head.text in order for fixed
103	 * section placement to work.
104	 */
105	.text BLOCK(0) : AT(ADDR(.text) - LOAD_OFFSET) {
106#else
107	.text : AT(ADDR(.text) - LOAD_OFFSET) {
108		ALIGN_FUNCTION();
109#endif
110		/* careful! __ftr_alt_* sections need to be close to .text */
111		*(.text .fixup __ftr_alt_* .ref.text)
112		SCHED_TEXT
113		CPUIDLE_TEXT
114		LOCK_TEXT
115		KPROBES_TEXT
116		IRQENTRY_TEXT
117		SOFTIRQENTRY_TEXT
118		MEM_KEEP(init.text)
119		MEM_KEEP(exit.text)
120
121#ifdef CONFIG_PPC32
122		*(.got1)
123		__got2_start = .;
124		*(.got2)
125		__got2_end = .;
126#endif /* CONFIG_PPC32 */
127
128	} :kernel
129
130	. = ALIGN(PAGE_SIZE);
131	_etext = .;
132	PROVIDE32 (etext = .);
133
134	/* Read-only data */
135	RODATA
136
137	EXCEPTION_TABLE(0)
138
139	NOTES :kernel :notes
140
141	/* The dummy segment contents for the bug workaround mentioned above
142	   near PHDRS.  */
143	.dummy : AT(ADDR(.dummy) - LOAD_OFFSET) {
144		LONG(0)
145		LONG(0)
146		LONG(0)
147	} :kernel :dummy
148
149/*
150 * Init sections discarded at runtime
151 */
152	. = ALIGN(PAGE_SIZE);
153	__init_begin = .;
154	INIT_TEXT_SECTION(PAGE_SIZE) :kernel
155
156	/* .exit.text is discarded at runtime, not link time,
157	 * to deal with references from __bug_table
158	 */
159	.exit.text : AT(ADDR(.exit.text) - LOAD_OFFSET) {
160		EXIT_TEXT
161	}
162
163	.init.data : AT(ADDR(.init.data) - LOAD_OFFSET) {
164		INIT_DATA
165		__vtop_table_begin = .;
166		*(.vtop_fixup);
167		__vtop_table_end = .;
168		__ptov_table_begin = .;
169		*(.ptov_fixup);
170		__ptov_table_end = .;
171	}
172
173	.init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET) {
174		INIT_SETUP(16)
175	}
176
177	.initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET) {
178		INIT_CALLS
179	}
180
181	.con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET) {
182		CON_INITCALL
183	}
184
185	SECURITY_INIT
186
187	. = ALIGN(8);
188	__ftr_fixup : AT(ADDR(__ftr_fixup) - LOAD_OFFSET) {
189		__start___ftr_fixup = .;
190		*(__ftr_fixup)
191		__stop___ftr_fixup = .;
192	}
193	. = ALIGN(8);
194	__mmu_ftr_fixup : AT(ADDR(__mmu_ftr_fixup) - LOAD_OFFSET) {
195		__start___mmu_ftr_fixup = .;
196		*(__mmu_ftr_fixup)
197		__stop___mmu_ftr_fixup = .;
198	}
199	. = ALIGN(8);
200	__lwsync_fixup : AT(ADDR(__lwsync_fixup) - LOAD_OFFSET) {
201		__start___lwsync_fixup = .;
202		*(__lwsync_fixup)
203		__stop___lwsync_fixup = .;
204	}
205#ifdef CONFIG_PPC64
206	. = ALIGN(8);
207	__fw_ftr_fixup : AT(ADDR(__fw_ftr_fixup) - LOAD_OFFSET) {
208		__start___fw_ftr_fixup = .;
209		*(__fw_ftr_fixup)
210		__stop___fw_ftr_fixup = .;
211	}
212#endif
213	.init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET) {
214		INIT_RAM_FS
215	}
216
217	PERCPU_SECTION(L1_CACHE_BYTES)
218
219	. = ALIGN(8);
220	.machine.desc : AT(ADDR(.machine.desc) - LOAD_OFFSET) {
221		__machine_desc_start = . ;
222		*(.machine.desc)
223		__machine_desc_end = . ;
224	}
225#ifdef CONFIG_RELOCATABLE
226	. = ALIGN(8);
227	.dynsym : AT(ADDR(.dynsym) - LOAD_OFFSET)
228	{
229#ifdef CONFIG_PPC32
230		__dynamic_symtab = .;
231#endif
232		*(.dynsym)
233	}
234	.dynstr : AT(ADDR(.dynstr) - LOAD_OFFSET) { *(.dynstr) }
235	.dynamic : AT(ADDR(.dynamic) - LOAD_OFFSET)
236	{
237		__dynamic_start = .;
238		*(.dynamic)
239	}
240	.hash : AT(ADDR(.hash) - LOAD_OFFSET) { *(.hash) }
241	.interp : AT(ADDR(.interp) - LOAD_OFFSET) { *(.interp) }
242	.rela.dyn : AT(ADDR(.rela.dyn) - LOAD_OFFSET)
243	{
244		__rela_dyn_start = .;
245		*(.rela*)
246	}
247#endif
248	/* .exit.data is discarded at runtime, not link time,
249	 * to deal with references from .exit.text
250	 */
251	.exit.data : AT(ADDR(.exit.data) - LOAD_OFFSET) {
252		EXIT_DATA
253	}
254
255	/* freed after init ends here */
256	. = ALIGN(PAGE_SIZE);
257	__init_end = .;
258
259/*
260 * And now the various read/write data
261 */
262
263	. = ALIGN(PAGE_SIZE);
264	_sdata = .;
265
266#ifdef CONFIG_PPC32
267	.data : AT(ADDR(.data) - LOAD_OFFSET) {
268		DATA_DATA
269		*(.sdata)
270		*(.got.plt) *(.got)
271	}
272#else
273	.data : AT(ADDR(.data) - LOAD_OFFSET) {
274		DATA_DATA
275		*(.data.rel*)
276		*(.toc1)
277		*(.branch_lt)
278	}
279
280	.opd : AT(ADDR(.opd) - LOAD_OFFSET) {
281		*(.opd)
282	}
283
284	. = ALIGN(256);
285	.got : AT(ADDR(.got) - LOAD_OFFSET) {
286		__toc_start = .;
287#ifndef CONFIG_RELOCATABLE
288		__prom_init_toc_start = .;
289		arch/powerpc/kernel/prom_init.o*(.toc .got)
290		__prom_init_toc_end = .;
291#endif
292		*(.got)
293		*(.toc)
294	}
295#endif
296
297	/* The initial task and kernel stack */
298	INIT_TASK_DATA_SECTION(THREAD_SIZE)
299
300	.data..page_aligned : AT(ADDR(.data..page_aligned) - LOAD_OFFSET) {
301		PAGE_ALIGNED_DATA(PAGE_SIZE)
302	}
303
304	.data..cacheline_aligned : AT(ADDR(.data..cacheline_aligned) - LOAD_OFFSET) {
305		CACHELINE_ALIGNED_DATA(L1_CACHE_BYTES)
306	}
307
308	.data..read_mostly : AT(ADDR(.data..read_mostly) - LOAD_OFFSET) {
309		READ_MOSTLY_DATA(L1_CACHE_BYTES)
310	}
311
312	. = ALIGN(PAGE_SIZE);
313	.data_nosave : AT(ADDR(.data_nosave) - LOAD_OFFSET) {
314		NOSAVE_DATA
315	}
316
317	BUG_TABLE
318
319	. = ALIGN(PAGE_SIZE);
320	_edata  =  .;
321	PROVIDE32 (edata = .);
322
323/*
324 * And finally the bss
325 */
326
327	BSS_SECTION(0, 0, 0)
328
329	. = ALIGN(PAGE_SIZE);
330	_end = . ;
331	PROVIDE32 (end = .);
332
333	/* Sections to be discarded. */
334	DISCARDS
335}
336