xref: /openbmc/linux/arch/arm64/mm/proc.S (revision 2891f2d5) 
1/*
2 * Based on arch/arm/mm/proc.S
3 *
4 * Copyright (C) 2001 Deep Blue Solutions Ltd.
5 * Copyright (C) 2012 ARM Ltd.
6 * Author: Catalin Marinas <catalin.marinas@arm.com>
7 *
8 * This program is free software; you can redistribute it and/or modify
9 * it under the terms of the GNU General Public License version 2 as
10 * published by the Free Software Foundation.
11 *
12 * This program is distributed in the hope that it will be useful,
13 * but WITHOUT ANY WARRANTY; without even the implied warranty of
14 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15 * GNU General Public License for more details.
16 *
17 * You should have received a copy of the GNU General Public License
18 * along with this program.  If not, see <http://www.gnu.org/licenses/>.
19 */
20
21#include <linux/init.h>
22#include <linux/linkage.h>
23#include <asm/assembler.h>
24#include <asm/asm-offsets.h>
25#include <asm/hwcap.h>
26#include <asm/pgtable.h>
27#include <asm/pgtable-hwdef.h>
28#include <asm/cpufeature.h>
29#include <asm/alternative.h>
30
31#ifdef CONFIG_ARM64_64K_PAGES
32#define TCR_TG_FLAGS	TCR_TG0_64K | TCR_TG1_64K
33#elif defined(CONFIG_ARM64_16K_PAGES)
34#define TCR_TG_FLAGS	TCR_TG0_16K | TCR_TG1_16K
35#else /* CONFIG_ARM64_4K_PAGES */
36#define TCR_TG_FLAGS	TCR_TG0_4K | TCR_TG1_4K
37#endif
38
39#define TCR_SMP_FLAGS	TCR_SHARED
40
41/* PTWs cacheable, inner/outer WBWA */
42#define TCR_CACHE_FLAGS	TCR_IRGN_WBWA | TCR_ORGN_WBWA
43
44#define MAIR(attr, mt)	((attr) << ((mt) * 8))
45
46/*
47 *	cpu_do_idle()
48 *
49 *	Idle the processor (wait for interrupt).
50 */
51ENTRY(cpu_do_idle)
52	dsb	sy				// WFI may enter a low-power mode
53	wfi
54	ret
55ENDPROC(cpu_do_idle)
56
57#ifdef CONFIG_CPU_PM
58/**
59 * cpu_do_suspend - save CPU registers context
60 *
61 * x0: virtual address of context pointer
62 */
63ENTRY(cpu_do_suspend)
64	mrs	x2, tpidr_el0
65	mrs	x3, tpidrro_el0
66	mrs	x4, contextidr_el1
67	mrs	x5, cpacr_el1
68	mrs	x6, tcr_el1
69	mrs	x7, vbar_el1
70	mrs	x8, mdscr_el1
71	mrs	x9, oslsr_el1
72	mrs	x10, sctlr_el1
73	mrs	x11, tpidr_el1
74	mrs	x12, sp_el0
75	stp	x2, x3, [x0]
76	stp	x4, xzr, [x0, #16]
77	stp	x5, x6, [x0, #32]
78	stp	x7, x8, [x0, #48]
79	stp	x9, x10, [x0, #64]
80	stp	x11, x12, [x0, #80]
81	ret
82ENDPROC(cpu_do_suspend)
83
84/**
85 * cpu_do_resume - restore CPU register context
86 *
87 * x0: Address of context pointer
88 */
89	.pushsection ".idmap.text", "ax"
90ENTRY(cpu_do_resume)
91	ldp	x2, x3, [x0]
92	ldp	x4, x5, [x0, #16]
93	ldp	x6, x8, [x0, #32]
94	ldp	x9, x10, [x0, #48]
95	ldp	x11, x12, [x0, #64]
96	ldp	x13, x14, [x0, #80]
97	msr	tpidr_el0, x2
98	msr	tpidrro_el0, x3
99	msr	contextidr_el1, x4
100	msr	cpacr_el1, x6
101
102	/* Don't change t0sz here, mask those bits when restoring */
103	mrs	x5, tcr_el1
104	bfi	x8, x5, TCR_T0SZ_OFFSET, TCR_TxSZ_WIDTH
105
106	msr	tcr_el1, x8
107	msr	vbar_el1, x9
108
109	/*
110	 * __cpu_setup() cleared MDSCR_EL1.MDE and friends, before unmasking
111	 * debug exceptions. By restoring MDSCR_EL1 here, we may take a debug
112	 * exception. Mask them until local_dbg_restore() in cpu_suspend()
113	 * resets them.
114	 */
115	disable_dbg
116	msr	mdscr_el1, x10
117
118	msr	sctlr_el1, x12
119	msr	tpidr_el1, x13
120	msr	sp_el0, x14
121	/*
122	 * Restore oslsr_el1 by writing oslar_el1
123	 */
124	ubfx	x11, x11, #1, #1
125	msr	oslar_el1, x11
126	reset_pmuserenr_el0 x0			// Disable PMU access from EL0
127	isb
128	ret
129ENDPROC(cpu_do_resume)
130	.popsection
131#endif
132
133/*
134 *	cpu_do_switch_mm(pgd_phys, tsk)
135 *
136 *	Set the translation table base pointer to be pgd_phys.
137 *
138 *	- pgd_phys - physical address of new TTB
139 */
140ENTRY(cpu_do_switch_mm)
141	pre_ttbr0_update_workaround x0, x2, x3
142	mmid	x1, x1				// get mm->context.id
143	bfi	x0, x1, #48, #16		// set the ASID
144	msr	ttbr0_el1, x0			// set TTBR0
145	isb
146	post_ttbr0_update_workaround
147	ret
148ENDPROC(cpu_do_switch_mm)
149
150	.pushsection ".idmap.text", "ax"
151/*
152 * void idmap_cpu_replace_ttbr1(phys_addr_t new_pgd)
153 *
154 * This is the low-level counterpart to cpu_replace_ttbr1, and should not be
155 * called by anything else. It can only be executed from a TTBR0 mapping.
156 */
157ENTRY(idmap_cpu_replace_ttbr1)
158	mrs	x2, daif
159	msr	daifset, #0xf
160
161	adrp	x1, empty_zero_page
162	msr	ttbr1_el1, x1
163	isb
164
165	tlbi	vmalle1
166	dsb	nsh
167	isb
168
169	msr	ttbr1_el1, x0
170	isb
171
172	msr	daif, x2
173
174	ret
175ENDPROC(idmap_cpu_replace_ttbr1)
176	.popsection
177
178/*
179 *	__cpu_setup
180 *
181 *	Initialise the processor for turning the MMU on.  Return in x0 the
182 *	value of the SCTLR_EL1 register.
183 */
184	.pushsection ".idmap.text", "ax"
185ENTRY(__cpu_setup)
186	tlbi	vmalle1				// Invalidate local TLB
187	dsb	nsh
188
189	mov	x0, #3 << 20
190	msr	cpacr_el1, x0			// Enable FP/ASIMD
191	mov	x0, #1 << 12			// Reset mdscr_el1 and disable
192	msr	mdscr_el1, x0			// access to the DCC from EL0
193	isb					// Unmask debug exceptions now,
194	enable_dbg				// since this is per-cpu
195	reset_pmuserenr_el0 x0			// Disable PMU access from EL0
196	/*
197	 * Memory region attributes for LPAE:
198	 *
199	 *   n = AttrIndx[2:0]
200	 *			n	MAIR
201	 *   DEVICE_nGnRnE	000	00000000
202	 *   DEVICE_nGnRE	001	00000100
203	 *   DEVICE_GRE		010	00001100
204	 *   NORMAL_NC		011	01000100
205	 *   NORMAL		100	11111111
206	 *   NORMAL_WT		101	10111011
207	 */
208	ldr	x5, =MAIR(0x00, MT_DEVICE_nGnRnE) | \
209		     MAIR(0x04, MT_DEVICE_nGnRE) | \
210		     MAIR(0x0c, MT_DEVICE_GRE) | \
211		     MAIR(0x44, MT_NORMAL_NC) | \
212		     MAIR(0xff, MT_NORMAL) | \
213		     MAIR(0xbb, MT_NORMAL_WT)
214	msr	mair_el1, x5
215	/*
216	 * Prepare SCTLR
217	 */
218	adr	x5, crval
219	ldp	w5, w6, [x5]
220	mrs	x0, sctlr_el1
221	bic	x0, x0, x5			// clear bits
222	orr	x0, x0, x6			// set bits
223	/*
224	 * Set/prepare TCR and TTBR. We use 512GB (39-bit) address range for
225	 * both user and kernel.
226	 */
227	ldr	x10, =TCR_TxSZ(VA_BITS) | TCR_CACHE_FLAGS | TCR_SMP_FLAGS | \
228			TCR_TG_FLAGS | TCR_ASID16 | TCR_TBI0
229	tcr_set_idmap_t0sz	x10, x9
230
231	/*
232	 * Read the PARange bits from ID_AA64MMFR0_EL1 and set the IPS bits in
233	 * TCR_EL1.
234	 */
235	mrs	x9, ID_AA64MMFR0_EL1
236	bfi	x10, x9, #32, #3
237#ifdef CONFIG_ARM64_HW_AFDBM
238	/*
239	 * Hardware update of the Access and Dirty bits.
240	 */
241	mrs	x9, ID_AA64MMFR1_EL1
242	and	x9, x9, #0xf
243	cbz	x9, 2f
244	cmp	x9, #2
245	b.lt	1f
246	orr	x10, x10, #TCR_HD		// hardware Dirty flag update
2471:	orr	x10, x10, #TCR_HA		// hardware Access flag update
2482:
249#endif	/* CONFIG_ARM64_HW_AFDBM */
250	msr	tcr_el1, x10
251	ret					// return to head.S
252ENDPROC(__cpu_setup)
253
254	/*
255	 * We set the desired value explicitly, including those of the
256	 * reserved bits. The values of bits EE & E0E were set early in
257	 * el2_setup, which are left untouched below.
258	 *
259	 *                 n n            T
260	 *       U E      WT T UD     US IHBS
261	 *       CE0      XWHW CZ     ME TEEA S
262	 * .... .IEE .... NEAI TE.I ..AD DEN0 ACAM
263	 * 0011 0... 1101 ..0. ..0. 10.. .0.. .... < hardware reserved
264	 * .... .1.. .... 01.1 11.1 ..01 0.01 1101 < software settings
265	 */
266	.type	crval, #object
267crval:
268	.word	0xfcffffff			// clear
269	.word	0x34d5d91d			// set
270	.popsection
271