xref: /openbmc/linux/arch/arm64/kernel/entry-ftrace.S (revision 6726d552) 
1/* SPDX-License-Identifier: GPL-2.0-only */
2/*
3 * arch/arm64/kernel/entry-ftrace.S
4 *
5 * Copyright (C) 2013 Linaro Limited
6 * Author: AKASHI Takahiro <takahiro.akashi@linaro.org>
7 */
8
9#include <linux/linkage.h>
10#include <asm/asm-offsets.h>
11#include <asm/assembler.h>
12#include <asm/ftrace.h>
13#include <asm/insn.h>
14
15#ifdef CONFIG_DYNAMIC_FTRACE_WITH_REGS
16/*
17 * Due to -fpatchable-function-entry=2, the compiler has placed two NOPs before
18 * the regular function prologue. For an enabled callsite, ftrace_init_nop() and
19 * ftrace_make_call() have patched those NOPs to:
20 *
21 * 	MOV	X9, LR
22 * 	BL	<entry>
23 *
24 * ... where <entry> is either ftrace_caller or ftrace_regs_caller.
25 *
26 * Each instrumented function follows the AAPCS, so here x0-x8 and x18-x30 are
27 * live (x18 holds the Shadow Call Stack pointer), and x9-x17 are safe to
28 * clobber.
29 *
30 * We save the callsite's context into a pt_regs before invoking any ftrace
31 * callbacks. So that we can get a sensible backtrace, we create a stack record
32 * for the callsite and the ftrace entry assembly. This is not sufficient for
33 * reliable stacktrace: until we create the callsite stack record, its caller
34 * is missing from the LR and existing chain of frame records.
35 */
36	.macro  ftrace_regs_entry, allregs=0
37	/* Make room for pt_regs, plus a callee frame */
38	sub	sp, sp, #(PT_REGS_SIZE + 16)
39
40	/* Save function arguments (and x9 for simplicity) */
41	stp	x0, x1, [sp, #S_X0]
42	stp	x2, x3, [sp, #S_X2]
43	stp	x4, x5, [sp, #S_X4]
44	stp	x6, x7, [sp, #S_X6]
45	stp	x8, x9, [sp, #S_X8]
46
47	/* Optionally save the callee-saved registers, always save the FP */
48	.if \allregs == 1
49	stp	x10, x11, [sp, #S_X10]
50	stp	x12, x13, [sp, #S_X12]
51	stp	x14, x15, [sp, #S_X14]
52	stp	x16, x17, [sp, #S_X16]
53	stp	x18, x19, [sp, #S_X18]
54	stp	x20, x21, [sp, #S_X20]
55	stp	x22, x23, [sp, #S_X22]
56	stp	x24, x25, [sp, #S_X24]
57	stp	x26, x27, [sp, #S_X26]
58	stp	x28, x29, [sp, #S_X28]
59	.else
60	str	x29, [sp, #S_FP]
61	.endif
62
63	/* Save the callsite's SP and LR */
64	add	x10, sp, #(PT_REGS_SIZE + 16)
65	stp	x9, x10, [sp, #S_LR]
66
67	/* Save the PC after the ftrace callsite */
68	str	x30, [sp, #S_PC]
69
70	/* Create a frame record for the callsite above pt_regs */
71	stp	x29, x9, [sp, #PT_REGS_SIZE]
72	add	x29, sp, #PT_REGS_SIZE
73
74	/* Create our frame record within pt_regs. */
75	stp	x29, x30, [sp, #S_STACKFRAME]
76	add	x29, sp, #S_STACKFRAME
77	.endm
78
79SYM_CODE_START(ftrace_regs_caller)
80	bti	c
81	ftrace_regs_entry	1
82	b	ftrace_common
83SYM_CODE_END(ftrace_regs_caller)
84
85SYM_CODE_START(ftrace_caller)
86	bti	c
87	ftrace_regs_entry	0
88	b	ftrace_common
89SYM_CODE_END(ftrace_caller)
90
91SYM_CODE_START(ftrace_common)
92	sub	x0, x30, #AARCH64_INSN_SIZE	// ip (callsite's BL insn)
93	mov	x1, x9				// parent_ip (callsite's LR)
94	ldr_l	x2, function_trace_op		// op
95	mov	x3, sp				// regs
96
97SYM_INNER_LABEL(ftrace_call, SYM_L_GLOBAL)
98	bl	ftrace_stub
99
100/*
101 * At the callsite x0-x8 and x19-x30 were live. Any C code will have preserved
102 * x19-x29 per the AAPCS, and we created frame records upon entry, so we need
103 * to restore x0-x8, x29, and x30.
104 */
105	/* Restore function arguments */
106	ldp	x0, x1, [sp]
107	ldp	x2, x3, [sp, #S_X2]
108	ldp	x4, x5, [sp, #S_X4]
109	ldp	x6, x7, [sp, #S_X6]
110	ldr	x8, [sp, #S_X8]
111
112	/* Restore the callsite's FP, LR, PC */
113	ldr	x29, [sp, #S_FP]
114	ldr	x30, [sp, #S_LR]
115	ldr	x9, [sp, #S_PC]
116
117	/* Restore the callsite's SP */
118	add	sp, sp, #PT_REGS_SIZE + 16
119
120	ret	x9
121SYM_CODE_END(ftrace_common)
122
123#else /* CONFIG_DYNAMIC_FTRACE_WITH_REGS */
124
125/*
126 * Gcc with -pg will put the following code in the beginning of each function:
127 *      mov x0, x30
128 *      bl _mcount
129 *	[function's body ...]
130 * "bl _mcount" may be replaced to "bl ftrace_caller" or NOP if dynamic
131 * ftrace is enabled.
132 *
133 * Please note that x0 as an argument will not be used here because we can
134 * get lr(x30) of instrumented function at any time by winding up call stack
135 * as long as the kernel is compiled without -fomit-frame-pointer.
136 * (or CONFIG_FRAME_POINTER, this is forced on arm64)
137 *
138 * stack layout after mcount_enter in _mcount():
139 *
140 * current sp/fp =>  0:+-----+
141 * in _mcount()        | x29 | -> instrumented function's fp
142 *                     +-----+
143 *                     | x30 | -> _mcount()'s lr (= instrumented function's pc)
144 * old sp       => +16:+-----+
145 * when instrumented   |     |
146 * function calls      | ... |
147 * _mcount()           |     |
148 *                     |     |
149 * instrumented => +xx:+-----+
150 * function's fp       | x29 | -> parent's fp
151 *                     +-----+
152 *                     | x30 | -> instrumented function's lr (= parent's pc)
153 *                     +-----+
154 *                     | ... |
155 */
156
157	.macro mcount_enter
158	stp	x29, x30, [sp, #-16]!
159	mov	x29, sp
160	.endm
161
162	.macro mcount_exit
163	ldp	x29, x30, [sp], #16
164	ret
165	.endm
166
167	.macro mcount_adjust_addr rd, rn
168	sub	\rd, \rn, #AARCH64_INSN_SIZE
169	.endm
170
171	/* for instrumented function's parent */
172	.macro mcount_get_parent_fp reg
173	ldr	\reg, [x29]
174	ldr	\reg, [\reg]
175	.endm
176
177	/* for instrumented function */
178	.macro mcount_get_pc0 reg
179	mcount_adjust_addr	\reg, x30
180	.endm
181
182	.macro mcount_get_pc reg
183	ldr	\reg, [x29, #8]
184	mcount_adjust_addr	\reg, \reg
185	.endm
186
187	.macro mcount_get_lr reg
188	ldr	\reg, [x29]
189	ldr	\reg, [\reg, #8]
190	.endm
191
192	.macro mcount_get_lr_addr reg
193	ldr	\reg, [x29]
194	add	\reg, \reg, #8
195	.endm
196
197#ifndef CONFIG_DYNAMIC_FTRACE
198/*
199 * void _mcount(unsigned long return_address)
200 * @return_address: return address to instrumented function
201 *
202 * This function makes calls, if enabled, to:
203 *     - tracer function to probe instrumented function's entry,
204 *     - ftrace_graph_caller to set up an exit hook
205 */
206SYM_FUNC_START(_mcount)
207	mcount_enter
208
209	ldr_l	x2, ftrace_trace_function
210	adr	x0, ftrace_stub
211	cmp	x0, x2			// if (ftrace_trace_function
212	b.eq	skip_ftrace_call	//     != ftrace_stub) {
213
214	mcount_get_pc	x0		//       function's pc
215	mcount_get_lr	x1		//       function's lr (= parent's pc)
216	blr	x2			//   (*ftrace_trace_function)(pc, lr);
217
218skip_ftrace_call:			// }
219#ifdef CONFIG_FUNCTION_GRAPH_TRACER
220	ldr_l	x2, ftrace_graph_return
221	cmp	x0, x2			//   if ((ftrace_graph_return
222	b.ne	ftrace_graph_caller	//        != ftrace_stub)
223
224	ldr_l	x2, ftrace_graph_entry	//     || (ftrace_graph_entry
225	adr_l	x0, ftrace_graph_entry_stub //     != ftrace_graph_entry_stub))
226	cmp	x0, x2
227	b.ne	ftrace_graph_caller	//     ftrace_graph_caller();
228#endif /* CONFIG_FUNCTION_GRAPH_TRACER */
229	mcount_exit
230SYM_FUNC_END(_mcount)
231EXPORT_SYMBOL(_mcount)
232NOKPROBE(_mcount)
233
234#else /* CONFIG_DYNAMIC_FTRACE */
235/*
236 * _mcount() is used to build the kernel with -pg option, but all the branch
237 * instructions to _mcount() are replaced to NOP initially at kernel start up,
238 * and later on, NOP to branch to ftrace_caller() when enabled or branch to
239 * NOP when disabled per-function base.
240 */
241SYM_FUNC_START(_mcount)
242	ret
243SYM_FUNC_END(_mcount)
244EXPORT_SYMBOL(_mcount)
245NOKPROBE(_mcount)
246
247/*
248 * void ftrace_caller(unsigned long return_address)
249 * @return_address: return address to instrumented function
250 *
251 * This function is a counterpart of _mcount() in 'static' ftrace, and
252 * makes calls to:
253 *     - tracer function to probe instrumented function's entry,
254 *     - ftrace_graph_caller to set up an exit hook
255 */
256SYM_FUNC_START(ftrace_caller)
257	mcount_enter
258
259	mcount_get_pc0	x0		//     function's pc
260	mcount_get_lr	x1		//     function's lr
261
262SYM_INNER_LABEL(ftrace_call, SYM_L_GLOBAL)	// tracer(pc, lr);
263	nop				// This will be replaced with "bl xxx"
264					// where xxx can be any kind of tracer.
265
266#ifdef CONFIG_FUNCTION_GRAPH_TRACER
267SYM_INNER_LABEL(ftrace_graph_call, SYM_L_GLOBAL) // ftrace_graph_caller();
268	nop				// If enabled, this will be replaced
269					// "b ftrace_graph_caller"
270#endif
271
272	mcount_exit
273SYM_FUNC_END(ftrace_caller)
274#endif /* CONFIG_DYNAMIC_FTRACE */
275
276#ifdef CONFIG_FUNCTION_GRAPH_TRACER
277/*
278 * void ftrace_graph_caller(void)
279 *
280 * Called from _mcount() or ftrace_caller() when function_graph tracer is
281 * selected.
282 * This function w/ prepare_ftrace_return() fakes link register's value on
283 * the call stack in order to intercept instrumented function's return path
284 * and run return_to_handler() later on its exit.
285 */
286SYM_FUNC_START(ftrace_graph_caller)
287	mcount_get_pc		  x0	//     function's pc
288	mcount_get_lr_addr	  x1	//     pointer to function's saved lr
289	mcount_get_parent_fp	  x2	//     parent's fp
290	bl	prepare_ftrace_return	// prepare_ftrace_return(pc, &lr, fp)
291
292	mcount_exit
293SYM_FUNC_END(ftrace_graph_caller)
294#endif /* CONFIG_FUNCTION_GRAPH_TRACER */
295#endif /* CONFIG_DYNAMIC_FTRACE_WITH_REGS */
296
297SYM_FUNC_START(ftrace_stub)
298	ret
299SYM_FUNC_END(ftrace_stub)
300
301#ifdef CONFIG_FUNCTION_GRAPH_TRACER
302/*
303 * void return_to_handler(void)
304 *
305 * Run ftrace_return_to_handler() before going back to parent.
306 * @fp is checked against the value passed by ftrace_graph_caller().
307 */
308SYM_CODE_START(return_to_handler)
309	/* save return value regs */
310	sub sp, sp, #64
311	stp x0, x1, [sp]
312	stp x2, x3, [sp, #16]
313	stp x4, x5, [sp, #32]
314	stp x6, x7, [sp, #48]
315
316	mov	x0, x29			//     parent's fp
317	bl	ftrace_return_to_handler// addr = ftrace_return_to_hander(fp);
318	mov	x30, x0			// restore the original return address
319
320	/* restore return value regs */
321	ldp x0, x1, [sp]
322	ldp x2, x3, [sp, #16]
323	ldp x4, x5, [sp, #32]
324	ldp x6, x7, [sp, #48]
325	add sp, sp, #64
326
327	ret
328SYM_CODE_END(return_to_handler)
329#endif /* CONFIG_FUNCTION_GRAPH_TRACER */
330