1/* SPDX-License-Identifier: GPL-2.0-only */
2/*
3 *  Copyright (C) 2000 Russell King
4 */
5#include <asm/vmlinux.lds.h>
6
7#ifdef CONFIG_CPU_ENDIAN_BE8
8#define ZIMAGE_MAGIC(x) ( (((x) >> 24) & 0x000000ff) | \
9			  (((x) >>  8) & 0x0000ff00) | \
10			  (((x) <<  8) & 0x00ff0000) | \
11			  (((x) << 24) & 0xff000000) )
12#else
13#define ZIMAGE_MAGIC(x) (x)
14#endif
15
16OUTPUT_ARCH(arm)
17ENTRY(_start)
18SECTIONS
19{
20  /DISCARD/ : {
21    COMMON_DISCARDS
22    *(.ARM.exidx*)
23    *(.ARM.extab*)
24    *(.note.*)
25    *(.rel.*)
26    /*
27     * Discard any r/w data - this produces a link error if we have any,
28     * which is required for PIC decompression.  Local data generates
29     * GOTOFF relocations, which prevents it being relocated independently
30     * of the text/got segments.
31     */
32    *(.data)
33  }
34
35  . = TEXT_START;
36  _text = .;
37
38  .text : {
39    _start = .;
40    *(.start)
41    *(.text)
42    *(.text.*)
43    ARM_STUBS_TEXT
44  }
45  .table : ALIGN(4) {
46    _table_start = .;
47    LONG(ZIMAGE_MAGIC(4))
48    LONG(ZIMAGE_MAGIC(0x5a534c4b))
49    LONG(ZIMAGE_MAGIC(__piggy_size_addr - _start))
50    LONG(ZIMAGE_MAGIC(_kernel_bss_size))
51    LONG(0)
52    _table_end = .;
53  }
54  .rodata : {
55    *(.rodata)
56    *(.rodata.*)
57    *(.data.rel.ro)
58  }
59  .piggydata : {
60    *(.piggydata)
61    __piggy_size_addr = . - 4;
62  }
63
64  . = ALIGN(4);
65  _etext = .;
66
67  .got.plt		: { *(.got.plt) }
68#ifndef CONFIG_EFI_STUB
69  _got_start = .;
70  .got			: { *(.got) }
71  _got_end = .;
72#endif
73
74  /* ensure the zImage file size is always a multiple of 64 bits */
75  /* (without a dummy byte, ld just ignores the empty section) */
76  .pad			: { BYTE(0); . = ALIGN(8); }
77
78#ifdef CONFIG_EFI_STUB
79  .data : ALIGN(4096) {
80    __pecoff_data_start = .;
81    _got_start = .;
82    *(.got)
83    _got_end = .;
84    /*
85     * The EFI stub always executes from RAM, and runs strictly before the
86     * decompressor, so we can make an exception for its r/w data, and keep it
87     */
88    *(.data.efistub .bss.efistub)
89    __pecoff_data_end = .;
90
91    /*
92     * PE/COFF mandates a file size which is a multiple of 512 bytes if the
93     * section size equals or exceeds 4 KB
94     */
95    . = ALIGN(512);
96  }
97  __pecoff_data_rawsize = . - ADDR(.data);
98#endif
99
100  _edata = .;
101
102  /*
103   * The image_end section appears after any additional loadable sections
104   * that the linker may decide to insert in the binary image.  Having
105   * this symbol allows further debug in the near future.
106   */
107  .image_end (NOLOAD) : {
108    /*
109     * EFI requires that the image is aligned to 512 bytes, and appended
110     * DTB requires that we know where the end of the image is.  Ensure
111     * that both are satisfied by ensuring that there are no additional
112     * sections emitted into the decompressor image.
113     */
114    _edata_real = .;
115  }
116
117  _magic_sig = ZIMAGE_MAGIC(0x016f2818);
118  _magic_start = ZIMAGE_MAGIC(_start);
119  _magic_end = ZIMAGE_MAGIC(_edata);
120  _magic_table = ZIMAGE_MAGIC(_table_start - _start);
121
122  . = BSS_START;
123  __bss_start = .;
124  .bss			: { *(.bss) }
125  _end = .;
126
127  . = ALIGN(8);		/* the stack must be 64-bit aligned */
128  .stack		: { *(.stack) }
129
130  PROVIDE(__pecoff_data_size = ALIGN(512) - ADDR(.data));
131  PROVIDE(__pecoff_end = ALIGN(512));
132
133  STABS_DEBUG
134  DWARF_DEBUG
135  ARM_DETAILS
136
137  ARM_ASSERTS
138}
139ASSERT(_edata_real == _edata, "error: zImage file size is incorrect");
140